Yoko

All sides of Injection
It is currently 2017-11-22 01:05:56

All times are UTC+02:00




Post new topic  Reply to topic  [ 44 posts ]  Go to page 1 2 3 Next
Author Message
PostPosted: 2005-08-28 21:09:58 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Ну вот я и решил поделиться своими скриптами. По мере того, как я буду делать новые скрипты, я буду дополнять этот топик и выставлять новую ссылку в 1 посте.
Для правильной работы скриптов рекомендуется скачать последнюю версию инжи.



Last edited by Leo on 2006-04-17 00:43:23, edited 15 times in total.

Top
   
 Post subject:
PostPosted: 2005-08-28 21:10:11 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Спирит спик
Каждые 2 минуты кушает. Динамическая задержка.

Code:
var food='0x097B' ##тип еды 
var Timer=UO.Timer()
sub SpiritSpeak()
#¤Leo¤#
UO.DeleteJournal()
   repeat
      UO.Useskill('Spirit Speak')
      UO.DeleteJournal()
         repeat
            wait(10)
         until UO.InJournal("netherworld")
         if UO.Timer()>(Timer+1200) then
            UO.UseType(food)
               wait(100)
         Timer=UO.Timer()
         end if
   until UO.Dead()
end sub


Top
   
 Post subject:
PostPosted: 2005-08-28 21:17:38 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Тейлоринг
Прячется и шьёт боди сэши. Тут же режет на бинты.

Code:
var Cont='0x4037E83B' ##ID сундука с тканью, так же туда будут складыватся бинты
var Creat='0x1541'    ##Тип того, что сшили
sub Tailoring()
#¤Leo¤#
   while NOT UO.Dead()
      ToHide()
      UO.FindType('0x175D','0x0000','backpack')
      if UO.GetQuantity('finditem')<4 then
         UO.UseObject(Cont)
         UO.FindType('0x0E21','0x0000','backpack')
         if UO.GetQuantity('finditem')>0 then
            UO.SetReceivingContainer(Cont)
               wait(1000)
            UO.Grab('all','finditem')
               wait(1000)
            UO.UnSetReceivingContainer()
         Endif
         UO.FindType('0x175D','0x0000',Cont)
            wait(1000)
         UO.Grab('600','finditem')
            wait(1000)
      endif
      CheckLag()
      UO.WaitMenu('Cloth','Misc','Misc','body sash')
      UO.WaitTargetType('0x175D')
      UO.UseType('0x0F9D')
      UO.DeleteJournal()
         wait(1000)
      repeat
         wait(100)
      until UO.InJournal('fail') or UO.InJournal('put')
      UO.DeleteJournal()
         wait(500)
      UO.WaitTargetType(Creat)
      UO.UseType('0x0F9E')
      CheckLag()
         wait(500)   
   wend
endsub

Sub ToHide()
   while NOT UO.Hidden()
      UO.DeleteJournal()
      UO.Exec('warmode 0')
      UO.UseSkill('Stealth')
         repeat
            wait(50)
         until UO.InJournal('You have hidden') OR UO.InJournal('seem to hide') OR UO.InJournal('preoccupied')
   wend
end sub

Sub CheckLag()
   UO.DeleteJournal()
   UO.Click('backpack')
   repeat
      wait(50)
   until UO.InJournal('backpack')
end sub


Top
   
 Post subject:
PostPosted: 2005-08-28 21:50:06 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Арчери
На чаре, которому качаем арчери запускаем процедуру Archery, на чаре кукле запускаем процедуру Start.
Рекомендуется поставить чаров на дистанцию 1 клетки друг от друга, рядом поставить сундук. В пак кладём побольше бинтов, блюдце для их мытья, побольше луков.
Лечит основной чар, чар кукла подбирает стрелы с пола и кладёт их в сундук.
За основу взят скрипт на спарринг. Автора не знаю.

Code:
var Doll = '0x0010F829' ##ID чара в которого стреляем
var Cont = '0x40070C35' ##ID контейнера где лежат стрелы
var Arrow = '0x0F3F'    ##тип стрел
var Bow = '0x13B1'      ##тип лука
sub Archery()
#¤Leo¤#
while 1
   UO.UseType(Bow)
   UO.Attack(Doll)
   Repeat
      wait (500)
   if UO.InJournal('destroyed') then
   UO.UseType(Bow)
   UO.DeleteJournal()
   endif
   Until UO.GetHP(Doll)<100
   repeat
   wait (500)
   UO.WarMode(0)
      if UO.FindCount('0x0E21')<30 then
         UO.WaitTargetType('0x1008')
         UO.UseType('0x0E20')
         CheckLag()
      endif
      UO.Usetype('0x0E21')
      UO.WaitTargetObject(Doll)
      wait(3500)
   Until UO.InJournal('need you')
      If UO.Count(Arrow) < 100 Then
         UO.Findtype(Arrow, '-1',Cont)
         If UO.FindCount() > 0 Then
            UO.Grab('500','finditem')
            wait(1000)
            CheckLag()
         Endif
      Endif
      UO.DeleteJournal()
wend
end sub

sub Start()
   repeat
   UO.Findtype(Arrow)
   If UO.FindCount() > 0 Then
      UO.MoveItem('finditem','0',Cont)
         wait(1000)
   Endif
   UO.Findtype(Arrow, '-1', '1' )
   If UO.FindCount() > 0 Then
      UO.MoveItem('finditem','0',Cont)
         wait(1000)
   Endif
      wait(10000)
   until UO.Dead()
endsub

Sub CheckLag()
   UO.DeleteJournal( 'backpack' )
   UO.Click( 'backpack' )
   repeat
      wait(100)
   until UO.InJournal( 'backpack' )
endsub


Last edited by Leo on 2005-09-14 13:05:56, edited 1 time in total.

Top
   
 Post subject:
PostPosted: 2005-08-28 22:52:31 
Offline
Junior Expert
User avatar

Joined: 2004-06-24 22:08:56
Posts: 3211
Leo wrote:
Поиск денег, упавших под пол
Кинул однажды деньги на пол и не мог их достать, достал только тогда, когда инжу более или менее освоил. :D Решил выложить, многим пригодится.

Code:
sub FindMoney()
#¤Leo¤#
UO.Set('finddistance','3')
UO.FindType('0x0DCA','-1','ground')
wait(100)
while UO.FindCount()>0
UO.MoveItem('finditem','-1','backpack')
wait(500)
wend
end sub

Интересно, а какой смысл один раз искать и много раз дергать? :)
while uo.findcount() - будет работать так же как и твоя конструкция, просто короче. Вобщем несколько бред )


Top
   
 Post subject:
PostPosted: 2005-08-29 06:05:17 
Offline
Sphere expert
User avatar

Joined: 2004-10-01 08:27:38
Posts: 1165
Location: Уфа
Destruction wrote:
Leo wrote:
Поиск денег, упавших под пол
Кинул однажды деньги на пол и не мог их достать, достал только тогда, когда инжу более или менее освоил. :D Решил выложить, многим пригодится.

Code:
sub FindMoney()
#¤Leo¤#
UO.Set('finddistance','3')
UO.FindType('0x0DCA','-1','ground')
wait(100)
while UO.FindCount()>0
UO.MoveItem('finditem','-1','backpack')
wait(500)
wend
end sub

Интересно, а какой смысл один раз искать и много раз дергать? :)
while uo.findcount() - будет работать так же как и твоя конструкция, просто короче. Вобщем несколько бред )

Не ворчи. Человек дело делает. Я вот каждый раз когда ГП кидаю на пол этот скрипт по новой пишу. ))))

_________________
Сделал дело - флуди смело !!!


Top
   
 Post subject:
PostPosted: 2005-08-29 11:10:21 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Destruction wrote:
Интересно, а какой смысл один раз искать и много раз дергать? :)
while uo.findcount() - будет работать так же как и твоя конструкция, просто короче. Вобщем несколько бред )


Я же Junior Expert, учусь только :D
Буду знать :wink:


Top
   
 Post subject:
PostPosted: 2005-08-29 14:49:58 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Анти парализ
Решил сделать скрипт на автоматическое сбивание каста (в данном случае парализа). Сначала вносите свой ID и ID 5 своих друзей. Так же при запуске скрипта предлагается выбрать 3 "временных" друзей.
В боях мне этот скрипт частенько помогал.
По умолчанию он не сбивает касты синих и зелёных (согильдцев). Если вам надо сбивать и касты синих, то просто удалите
[ OR Color==1]
(не забудьте про пробел).

Code:
var SerialSelf   = '0x0010F829' ## ID вашего чара
var FirstFriend  = '0x0010F829' ## ID 1 друга
var SecondFriend = '0x0010F829' ## ID 2 друга
var ThirdFriend  = '0x0010F829' ## ID 3 друга
var FourthFriend = '0x0010F829' ## ID 4 друга
var FifthFriend  = '0x0010F829' ## ID 5 друга
var Cast         = 'Weaken'     ## Каким заклинанием будем сбивать

Var Enemy, Color, FirstTempFriend, SecondTempFriend, ThirdTempFriend, FirstTemp, SecondTemp, ThirdTemp

sub AntiParaliz()
#¤Leo¤#
uo.Print('Выбери 1 временного друга: ')
uo.Exec('addobject FirstTemp')
   while uo.Targeting()
      wait(100)
   wend
FirstTempFriend=UO.GetSerial("FirstTemp")

uo.Print('Выбери 2 временного друга: ')
uo.Exec('addobject SecondTemp')
   while uo.Targeting()
      wait(100)
   wend
SecondTempFriend=UO.GetSerial("SecondTemp")

uo.Print('Выбери 3 временного друга: ')
uo.Exec('addobject ThirdTemp')
   while uo.Targeting()
      wait(100)
   wend
ThirdTempFriend=UO.GetSerial("ThirdTemp")

   while not UO.Dead()
      if UO.InJournal("An Ex Por") then
         Enemy=UO.GetSerial(UO.JournalSerial(0))
         Color=UO.GetNotoriety(Enemy)
            if Enemy==SerialSelf OR Enemy==FirstFriend OR Enemy==SecondFriend OR Enemy==ThirdFriend OR Enemy==FourthFriend OR Enemy==FifthFriend OR Enemy==FirstTempFriend OR Enemy==SecondTempFriend OR Enemy==ThirdTempFriend OR Color==2 OR Color==1 then
                wait(100)
                UO.DeleteJournal()
            else
                UO.Cast(Cast,Enemy)
                UO.DeleteJournal()
            end if
                wait(500)
      else
         wait(1000)
      end if
   wend
end sub


Last edited by Leo on 2005-09-03 23:06:13, edited 2 times in total.

Top
   
 Post subject:
PostPosted: 2005-08-29 16:42:36 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Ламберждекинг
Собственно это скрипт Ветерана, переделанный мной.
Скрипт без каких-либо реколлов, просто рубит в лесу, потом подходит к сундуку, кушает и опять в лес.
Очень хорошо подходит для каторги.
Возможна прокачка спирит спика.

Code:
 ############################################ 
### Lumberjacking / Рубка деревьев       ###
############################################
### Шард Dragon World / www.drw.ru       ###
############################################
### Реавтор этого скрипта: BETEPAH       ###
############################################
##################
### Переменные ###
##################
###################################################################################################
var f=file("C:\trees3.dat") ## - Путь к файлу в котором будут хранится координаты деревьев.
###
var TryHiding=1 ## 1 - Перед тем как рубить дерево, будет пытаться уйти в хайд, 0 - не будет .
###
var LogsQty=400 ## - Количество логов, добыв которое надо реколиться домой.
###
var GetFromFile=1 ## 1 - Координаты деревьев будут считыватся из файла, 0 - собиратся из клиента
### (сначала соберите а потом считывайте из файла).
###
var EatingFood=1 ## 1 - Будем есть, 0 - нет. 
###
var SSpeak=1 ## 1 - Будем качать и спирит спик, 0 - не будем.
###
var TypeFood='0x097B' ## - Тип еды которую будем кушать.(сейчас фиштейки)
###
var Chest='0x401A442D' ## - ID сундука куда будут выгружаться логи.
###
var Trytodrop=1 ## Будем пытатся подходить к сундуку или нет.
###
var ContX=1234 ##Координаты X у сундука
###
var ContY=1234 ##Координаты Y у сундука
###
var oldX,oldY,time ## - Для рекола.
###
###########
### Код ###
###########
sub Lumberjacking()
var i=0,j=0,k=0,r=0,q=0,ii,jj
var TopX=324,TopY=65
dim TreeX[5000], TreeY[5000],TreeT[5000]
dim TreeTile[29]
var flag=0,treeCount=0,clicks=0,flag2=0
########################
### Графика деревьев ###
########################
TreeTile[0]=3277
TreeTile[1]=3280
TreeTile[2]=3283
TreeTile[3]=3286
TreeTile[4]=3289
TreeTile[5]=3291
TreeTile[6]=3294
TreeTile[7]=3296
TreeTile[8]=3299
TreeTile[9]=3302
TreeTile[10]=3393
TreeTile[11]=3394
TreeTile[12]=3395
TreeTile[13]=3396
TreeTile[14]=3415
TreeTile[15]=3416
TreeTile[16]=3417
TreeTile[17]=3418
TreeTile[18]=3419
TreeTile[19]=3438
TreeTile[20]=3439
TreeTile[21]=3440
TreeTile[22]=3441
TreeTile[23]=3442
TreeTile[24]=3460
TreeTile[25]=3461
TreeTile[26]=3462
TreeTile[27]=3290
TreeTile[28]=3288

uo.Exec("filterspeech on")
uo.Exec("filterspeech add 'Where do you want to use the pickaxe?'")

uo.Print('Выбери Топор: ')
uo.Exec('addobject Axe')
while uo.Targeting()
wait(100)
wend

#####################################
### Загружаем координаты из файла ###
#####################################
if GetFromFile==1 then
uo.Print('Загружаем координаты из файла...')
f.open()
treeCount=safe call f.ReadNumber()
for i=1 to treeCount
TreeT[i]=safe call f.ReadNumber()
TreeX[i]=safe call f.ReadNumber()
TreeY[i]=safe call f.ReadNumber()
next
f.close()
else
######################################
### Собираем координаты из клиента ###
######################################
uo.Print('Выбери Кирку: ')
uo.Exec('addobject Pickaxe')
while uo.Targeting()
wait(100)
wend
uo.Print('Собираем координаты деревьев в округе...')
repeat
clicks=0
flag=0
uo.DeleteJournal()
#######################
### Кликаем на тайл ###
#######################
uo.UseObject('Pickaxe')
waitForTarget()
uo.DeleteJournal()
WaitForTryRock()
###############################
### Проверяем дерево ли это ###
###############################
flag=0
for k=0 to 28
if uo.LastTile(0)==TreeTile[k]+1 then
flag=2
end if
next
if flag==0 then
for k=0 to 28
if uo.LastTile(0)==TreeTile[k] then
flag=1
end if
next
end if
if uo.Lasttile(1)==uo.getX() and uo.Lasttile(2)==uo.gety() then
flag=3
end if
#########################
### Кликнули на ствол ###
#########################
if flag==1 then
flag2=0
if treeCount>0 then
for ii=1 to treeCount
if TreeX[ii]==uo.LastTile(1) and TreeY[ii]==uo.LastTile(2) then
flag2=1
end if
next
end if
if flag2==0 then
treeCount=treeCount+1
TreeX[treeCount]=uo.LastTile(1)
TreeY[treeCount]=uo.LastTile(2)
TreeT[treeCount]=uo.LastTile(0)
uo.Print('Найдено дерево '+str(treeCount)+' : x='+str(uo.Lasttile(1))+' y='+str(uo.LastTile(2))+' '+str(treeCount))
end if
end if
##########################
### Кликнули по листве ###
##########################
if flag==2 then
flag2=0
if treeCount>0 then
for ii=1 to treeCount
if TreeX[ii]==uo.LastTile(1) and TreeY[ii]==uo.LastTile(2) then
flag2=1
end if
next
end if
if flag2==0 then
treeCount=treeCount+1
TreeX[treeCount]=uo.LastTile(1)
TreeY[treeCount]=uo.LastTile(2)
TreeT[treeCount]=uo.LastTile(0)-1
uo.print('Найдено дерево '+str(treeCount)+' : x='+str(uo.Lasttile(1))+' y='+str(uo.LastTile(2)))
end if
end if
until (Flag==3) or (treeCount==500)
uo.Exec("filterspeech off")
uo.Print('Анализ закончен, координаты деревьев записаны в файл C:\trees3.dat')
SaveToFile(treeCount,TreeX,TreeY,TreeT)
end if
uo.Print('Деревьев найдено: '+str(treeCount))
wait(2000)
######################################
### Ходим по собранным координатам ###
######################################
while 1==1
if treeCount>0 then
for i=1 to treeCount
end if
if Trytodrop==1 and uo.Count('ZLK')>=LogsQty then
GotoXY(uo.getx(Chest),uo.gety(Chest))
DropLogs()
end if
uo.Print('Идем к дереву '+str(i)+': x='+str(TreeX[i])+' y='+str(TreeY[i]))
InfoLogs()
flag=GotoXY(TreeX[i],TreeY[i])
if flag==1 then
if TryHiding==1 then
ToHide()
end if
GetTree(str(TreeT[i]),str(TreeX[i]),str(TreeY[i]),str(uo.GetZ()))
end if
next
end if
wend
end sub

Sub GetTree(Type,X,Y,Z)
var i
uo.Print('Начинаем рубку дерева...')
for i=0 to 15
if uo.Warmode()==1 then
return 0
end if
wait(200)
uo.DeleteJournal()
uo.WaitTargetTile(Type,X,Y,Z)
uo.UseObject('Axe')
if WaitForChange()==1 then
return 1
end if
next
return 0
end sub

Sub ToHide()
if SSpeak==1 then
UO.Useskill('Spirit Speak')   
wait(3000)
endif
while not uo.Hidden()
uo.Print('Пытаемся уйти в хайд...')
uo.DeleteJournal()
uo.UseSkill('Stealth')
wait(3000)
wend
wait(100)
end sub


Sub WaitForHide()
var Text1=uo.GetName()+": You have hidden yourself well"
var Text2=uo.GetName()+": You can't seem to hide here."
var mess
for var i=0 to 200
mess=uo.Journal(0)
if uo.Journal(0)==Text1 then
return 1
end if
if uo.Journal(0)==Text2 then
return 0
end if
wait(50)
next
return 0
end sub

Sub WaitForChange()
var Text1=uo.GetName()+': You hack at the tree for a while, but fail to produce any useable wood.'
var Text2='There are no logs here to chop.'
var Text3="You can't reach this."
var Text4="That is too far away."
var Text5="You can't do much in your current state."
var mess
for var i=0 to 200
mess=uo.Journal(0)
if uo.Journal(0)==Text2 or uo.Journal(0)==Text3 or uo.Journal(0)==Text4 then
return 1
end if
if uo.Journal(0)==Text1 then
return 0
end if
if mess[0]=='Y' and mess[1]=='o' and mess[2]=='u' and mess[4]=='p' and mess[5]=='u' and mess[6]=='t' then
return 0
end if
wait(50)
next
return 0
end sub

Sub WaitForTryRock()
var Text1="That is too far away."
var Text2="Try mining in rock."
var Text3="There is no ore here to mine."
var Text4="You have no line of sight to that location"
var Text5="You can't see the target"
for var i=0 to 50
if uo.Journal(0)==Text1 or uo.Journal(0)==Text2 or uo.Journal(0)==Text3 or uo.Journal(0)==Text4 or uo.Journal(0)==Text5 then
return 1
end if
wait(200)
next
return 0
end sub

Sub WaitForTarget()
for var i=0 to 50
if uo.Targeting()==1 then
return 1
end if
wait(200)
next
return 0
end sub

Sub WaitForChangeXY(myX,myY,lastX,lastY)
for var i=1 to 50
if lastX<>myX or lastY<>myY then
return 1
end if
wait(200)
next
return 0
end sub

Sub GotoXY(x,y)
var myX,myY,lastX=0,lastY=0,i,halt=0,z,r=0
for i=1 to 60
myX=uo.getX();
myY=uo.getY();
if LastX==myX and LastY==myY then
halt=halt+1
else
halt=0
end if
if halt>=10 then
if uo.GetDir()==1 then
for z=0 to 8
uo.Press(40)
next
end if
if uo.GetDir()==3 then
for z=0 to 8
uo.Press(37)
next
end if
if uo.GetDir()==5 then
for z=0 to 8
uo.Press(38)
next
end if
if uo.GetDir()==7 then
for z=0 to 8
uo.Press(39)
next
end if
halt=15
end if
if Numb(x-myX)<=1 and Numb(y-myY)<=2 then
return 1
end if
if x<=myX then
if y<=myY then
for z=0 to 3
uo.Press(38)
next
else
for z=0 to 3
uo.Press(37)
next
end if
else
if y<=myY then
for z=0 to 3
uo.Press(39)
next
else
for z=0 to 3
uo.Press(40)
next
end if
end if
lastX=myX
lastY=myY
wait(200)
next
return 0
end sub

Sub Numb(num)
if num>=0 then
return num
else
return num*(-1)
end if
end sub

Sub SaveToFile(treeCount,TreeX,TreeY,TreeT)
var f=file("C:\trees3.dat")
var s=0,i=0
f.open()
f.create()
s=safe call f.writeln(treeCount)
for i=1 to treeCount
s=safe call f.writeln(str(TreeT[i])+' '+str(TreeX[i])+' '+str(TreeY[i]))
next
f.close()
end sub

sub DropLogs()
uo.say("Выкладываю логи !!! Не беспокоить !!!")
if uo.Waiting() then
uo.CancelTarget()
end if
var a,Exit
dim Logs[1]
Logs[0]=0x1BDD
uo.Print('Выкладываем Логи.')
uo.SetReceivingContainer(Chest)
wait(500)
for a=0 to 0
Exit=0
repeat
uo.FindType(Logs[a])
if uo.GetQuantity('finditem')>0 then
uo.Grab('0','finditem')
wait(1500)
GotoXY(ContX,ContY)
else
Exit=1
end if
until Exit==1
next
if EatingFood==1 then
EatingFood()
end if
uo.UnSetReceivingContainer(Chest)
uo.Print('Логи Выложены.')
end sub


Sub InfoLogs()
uo.Print('У вас всего '+str(uo.Count('0x1BDD'))+' логов в сумке')
uo.Print('Из них '+str(uo.Count('0x1BDD','0x0000'))+' простых и ' +str(uo.Count('0x1BDD')-uo.Count('0x1BDD','0x0000'))+' цветных')
end sub

Sub Open(Container)
uo.DeleteJournal()
uo.UseObject(Container)
repeat
wait(500)
until uo.InJournal('Contains')
end sub


Sub EatingFood()
ToEat()
DropFood()
end sub

Sub ToEat()
uo.SetReceivingContainer('backpack')
Open(Chest)
uo.FindType(TypeFood,'-1',Chest)
uo.Grab('50','finditem')
wait(500)
repeat
Checklag()
uo.UseType(TypeFood)
wait(1000)
until uo.InJournal('You are simply too full to eat any more!')
uo.UnsetReceivingContainer()
end sub

Sub DropFood()
if uo.Waiting() then
uo.CancelTarget()
end if
var f,Exit
dim Food[1]
Food[0]=TypeFood
uo.SetReceivingContainer(Chest)
wait(500)
for f=0 to 0
Exit=0
repeat
uo.FindType(Food[f])
if uo.GetQuantity('finditem')>0 then
uo.Grab('0','finditem')
wait(1500)
else
Exit=1
end if
until Exit==1
next
uo.UnSetReceivingContainer(Chest)
end sub

Sub CheckLag()
if uo.Waiting()>0 then
uo.Exec('canceltarget')
end if
uo.DeleteJournal()
uo.Click('backpack')
repeat
wait(50)
until uo.InJournal('backpack')
end sub


Last edited by Leo on 2006-08-21 22:17:48, edited 2 times in total.

Top
   
 Post subject:
PostPosted: 2005-08-30 02:54:45 
Offline

Joined: 2004-06-04 22:39:18
Posts: 4
у меня вопрос по лумберу
вобщем когда чар начинает рубить, то инжект будто не видит месаг
т.е. не реагирует на There are no logs here to chop
That is too far away
и тп
в чем проблема?


Top
   
 Post subject:
PostPosted: 2005-08-30 06:54:15 
Offline

Joined: 2005-05-03 11:51:04
Posts: 108
Location: KDK Elite Group (c)
axa wrote:
у меня вопрос по лумберу
вобщем когда чар начинает рубить, то инжект будто не видит месаг
т.е. не реагирует на There are no logs here to chop
That is too far away
и тп
в чем проблема?

Скорее всего ты играешь не DRW а на шарде который юзает РанУО а там как мы знаем нет в журнале инжекта мессаг типа "That is too far away" редставлено клилоками и выглядит примерно так "cliloc# 0x654df6".

Хотя скрипт я не юзал но проблема скорее всего в этом!


Top
   
 Post subject:
PostPosted: 2005-08-30 10:57:59 
Offline

Joined: 2004-06-04 22:39:18
Posts: 4
не...
играю я на сферовском шарде, но не на дрв


Top
   
 Post subject:
PostPosted: 2005-08-30 12:00:46 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Не знаю, не я писал, я только всё лишнее для себя убрал.


Top
   
 Post subject:
PostPosted: 2005-09-11 15:20:55 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
Таминг
Запускаем скрипт, выбираем животное, потом таминг стафф.
Каждые 2 минуты кормим животное и едим сами.

Code:
var fruit='0x09D1' ##Тип еды, которой кормим животное
var food= '0x097B' ##Тип того что сами будем кушать
var Timer=UO.Timer()
var Animal, Staff

sub AnimalTaming()
#¤Leo¤#
UO.Msg('All release')

UO.Print('Выбери Животину...')
UO.Exec('addobject Animal')
   while uo.Targeting()
      wait(100)
   wend

UO.Print('Выбери Палку...')
UO.Exec('addobject Staff')
   while uo.Targeting()
      wait(100)
   wend

UO.DeleteJournal()
while not UO.InJournal('It seems') or not UO.InJournal('see the creature')
   UO.DeleteJournal()
   UO.WaitTargetObject('Animal') 
   UO.UseObject('Staff')
      repeat
         wait(100)
      until UO.InJournal('fail') or UO.InJournal('It seems') or UO.InJournal('see the creature')
   if UO.Timer()>(Timer+1200) then
      UO.SetReceivingContainer('Animal')
         wait(500)
      UO.FindType(fruit)
         if UO.GetQuantity('finditem')>0 then
            UO.Grab('5','finditem')
               wait(500)
         end if
      UO.UnSetReceivingContainer('Animal')
         wait(500)
      UO.UseType(food)
      Timer=UO.Timer()
   end if
UO.Msg('All release')
wend
end sub


Top
   
 Post subject:
PostPosted: 2005-09-21 18:13:11 
Offline

Joined: 2005-08-15 16:13:32
Posts: 5
Script na "Анти парализ" ocen palezen no on viletaet kagda protivnik vipivaet inviz potion, posli detect on mesta tavo stobi sbivat paralyz gavaryt invalid serial index. Nada zdelat magic arow na playera stobi snova sbival paralyz

Ja igraju na PVP-ALfa servere tam pyt inviz nada komandai .drink_invis mozet eta kakta vlijaet na etat makr? kak obaity etu problemu.

I iccio xotelas takoi makr gde nenada vibirat 3 druzei a serial protivnika mozna bila v mark zapisat prezdi cem iti na arenu.


Top
   
 Post subject:
PostPosted: 2005-09-22 13:56:31 
Offline

Joined: 2005-01-22 10:29:34
Posts: 140
могу сказать что на арчери немного сыроват скрипт я бы сделал по другому для прокачки двух чаров вот допустим схема дома:
Code:
          I                                                                 I
          I                                                                 I
         ГI                                                                IГ
          I_____________________________________I
        O                                                                   O
O- 2 чара
Г- 2 сундука

ну вот стоят 2 чара и стреляют друг в друга если у кого мало хп заходят за дом и лечатся там же мона поставить 2 сундука со жратвой и хавчиком ну вот вупринципе и сделать чтоб они подбирали стрелы [/quote]


Top
   
 Post subject:
PostPosted: 2005-09-22 13:59:16 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
По-моему если в меня попала стрела, мой выстрел физлится, хотя и не пробовал.


Top
   
 Post subject:
PostPosted: 2005-09-22 14:06:33 
Offline

Joined: 2005-01-22 10:29:34
Posts: 140
на дрв нет сбивания отаки когда я играл мы с друзьями проверяли


Top
   
 Post subject:
PostPosted: 2005-09-22 14:11:21 
Offline
Expert!
User avatar

Joined: 2005-01-15 19:15:05
Posts: 818
Location: Dragon World
тогда идея неплохая :D
Правда ща с боевыми туго...


Top
   
 Post subject:
PostPosted: 2005-09-22 14:13:42 
Offline

Joined: 2005-01-22 10:29:34
Posts: 140
я так хотел прокачать с другом арчери но это было не уже не вовремя :) поэтому и скрипт не стал писать


Top
   
Display posts from previous:  Sort by  
Post new topic  Reply to topic  [ 44 posts ]  Go to page 1 2 3 Next

All times are UTC+02:00


Who is online

Users browsing this forum: No registered users and 1 guest


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
Powered by phpBB® Forum Software © phpBB Limited