Yoko

###################################################
### Script Name: DearhellEmptyBottles
###################################################
### Author: Dearhell / dearhell666@hotmail.com
###################################################
### Version: 1.0
###################################################
### Tested with: 2.03 client, Sphere 0.55i, shard VTR ( www.coliseouo.tk )
###################################################
### Description: Script for making empty bottles
###################################################
### Revision Date: 06/01/05
###################################################
### Public Release: 06/01/05 
###################################################
#How it works: The script calculates the maximum weight that you can carry on, and in order to that,
#it picks up the iron from the flour. Then, while you have iron enough, it makes the bottles and when #you have no more iron for that, it drops the bottles on a container and it pick ups again iron from #the ground. The script can be stopped saying "stop making bottles"
###################################################
### Setup Instructions: These variables must be setted up.
###################################################
sub bottles()
VAR chestID='0x4000D56E' ;The chest's ID where you want to drop the bottles
VAR tinkeringTools='0x1EBC' ;The tinkeringTools' type 
VAR iron='0x1BEF' ;The iron's type
VAR bottles='0x0F0E' ;The bottles' type
###################################################

VAR maxWeight=((UO.STR*4)-UO.Weight)/2 #it calculates the maximum weight that we can carry on
VAR stop=0

UO.Exec("set finddistance 1")
UO.CancelMenu()
UO.AutoMenu('Tinkering','Tools')
UO.AutoMenu('Tools','empty')

while stop<>1
   maxWeight=((UO.STR*4)-UO.Weight)/2 
   UO.FindType(iron,-1,'ground')
   UO.Grab(maxWeight,"finditem")
   wait(1000)
   While UO.Count(Iron)>=2 AND stop<>1
      UO.UseType(tinkeringTools)
      UO.DeleteJournal()
      repeat
         if UO.InJournal('stop making bottles') then
            stop=1
         EndIf
         wait(200)
      until UO.InJournal('You put') OR UO.InJournal('You fail')
   Wend
   UO.Findtype(bottles,-1,'backpack')
   UO.MoveItem('finditem',UO.Count(bottles),chestID)
   UO.Print('Moving '+STR(UO.Count(bottles))+' bottles into the chest')
   wait(1000)
wend
UO.CancelMenu()
UO.Exec("set finddistance 14")
end sub