Yoko :: Взаимодействие между несколькими инжектами

Yoko http://forum.yoko.com.ua/

Взаимодействие между несколькими инжектами http://forum.yoko.com.ua/viewtopic.php?f=3&t=2965	Page 1 of 1

Author:	JIupus [ 2005-02-03 10:55:24 ]
Post subject:	Взаимодействие между несколькими инжектами
Как можно осуществить взаимодействие двух и более инжектов в следующих ситуациях(все они запущены пока на одной машине) 1) покачака, допустим, арчери, чтобы кукла сама сообщала атакующему, что у нее мало хп, и тот прекращал стрелять. Сюда же можно еще добавить хилера 2) прокачка остальных боевых: примерно тоже самое, что в первом, но тут уже требуется сигнал от двух чаров 3) добыча ресурсов: 2-3 чара копают или рубят или рыбачат(можно все сразу), соответсвенно скрипт для каждого лежит в отдельном файле, в случае опасности(энт, элем, змейка морская) или гибели они дают сигнал 4 чару, который приходит и устраняет причину сигнала

Author:

Savage [ 2005-02-03 11:08:06 ]

Post subject:

глобальные переменные хранящиеся в реестре. Смотри команды:
UO.GetEasyUO()
UO.SetEasyUO()
Вот пример использования - два чара в спарринге:

Code:

sub sreset()
   UO.SetEasyUO(80,"1")
   UO.SetEasyUO(90,"1")
end sub


sub sparring()
   VAR Char1='0x000B170A'
   VAR Char2='0x00112A03'
   VAR Enemy, ESelf, EEnemy
   VAR Weapon, Shield, WpnType, ShldType
   VAR TazikType='0x1008',BloodBndg='0x0E20'
   VAR MinLife=60
   

   if UO.GetSerial('self')==Char1 then
      Enemy=Char2
      EEnemy=90
      ESelf=80
   else
      Enemy=Char1
      EEnemy=80
      ESelf=90
   endif

   Weapon=UO.ObjAtLayer('Rhand')
   If Weapon<>"" Then
      WpnType=UO.GetGraphic(Weapon)
   Endif

   Shield=UO.ObjAtLayer('Lhand')
   If Shield<>"" Then
      ShldType=UO.GetGraphic(Shield)
   Endif
   
   UO.SetEasyUO(ESelf,"0")

   while NOT UO.Dead()
   
      repeat
         wait(500)
      until UO.GetEasyUO(ESelf)=="0" AND UO.GetEasyUO(EEnemy)=="0" 
      
      UO.Exec("warmode 1")
      UO.Attack(Enemy)
      
      while UO.Life>=MinLife AND UO.GetEasyUO(EEnemy)=="0" 
         wait(100)
      wend

      UO.SetEasyUO(ESelf,"1")
      UO.Exec("warmode 0")
      wait(1000)
      UO.Exec("warmode 0")

      UO.FindType('0x0E21','0x0000','backpack')
      If UO.GetQuantity('finditem')<20 Then
         UO.FindType('0x0E20','0x0000','backpack')
         UO.WaitTargetType(TazikType)
         UO.UseObject('finditem')
         wait(1000)
      Endif

      while UO.Life<UO.Str
         UO.DeleteJournal()
         UO.BandageSelf()
         Repeat
            wait(500)
         Until UO.InJournal('put') OR UO.InJournal('help') OR UO.InJournal('cure')
      wend

      If Shield<>"" Then
         UO.Equipt('Lhand',ShldType)
         wait(2000)
      Endif

      If Weapon<>"" Then
         UO.Equipt('Rhand',WpnType)
         wait(2000)
      Endif
      
      UO.UseSkill('Spirit Speak')
      wait(3000)
      UO.SetEasyUO(ESelf,"0")
   wend
end sub

Author:	JIupus [ 2005-02-03 11:20:18 ]
Post subject:
Ну про реестр я уже думал, тогда может лучше ASM использовать для работы с регистром?

Author:	Goggy [ 2005-02-04 02:46:41 ]
Post subject:
JIupus wrote: Ну про реестр я уже думал, тогда может лучше ASM использовать для работы с регистром? Да нет просто переходи на мой шард тут при прокачке боевых друг друга не коцаешь ну ессно если в бронике хорошем ))

Page 1 of 1	All times are UTC+02:00
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/