# Версия YokoInjection: 505.18 VeNdOr
# Sphere Server : v0.55i
# Версия клиента: 2.0.3
# Автор: GAUHAR

#########################################################################
# Простой фишинг с разделкой рыбы на фишстейки.                         #
#                                                                       #
# ОПИСАНИЕ:                                                             #
# В бекпаке персонажа должна быть удочка и нож (dagger).                #
# Выбираем место для рыбалки. Запускаем скрипт FISHING().               #
# Во время рыбалки персонаж уходит в хайд и ловит рыбу в хайде, улов    #
# сразу же собирает в бекпак (собираемый улов находится в массиве).     #
# Набрав максимальный вес улова приступает к разделке рыбы на           #
# фишстейки и снова приступает к ловле.                                 #
# Рыбачит в цикле до тех пор пока не будет набран максимальный вес.     #
#-----------------------------------------------------------------------#
sub FISHING()
   DIM ULOVtype[7]
       ULOVtype[0] = '0x09CC'      #fish1
       ULOVtype[1] = '0x09CD'      #fish2
       ULOVtype[2] = '0x09CE'      #fish3
       ULOVtype[3] = '0x09CF'      #fish4
       ULOVtype[4] = '0x0DD6'      #Prize Fish
       ULOVtype[5] = '0x0DD6'      #Truly Rare Fish
       ULOVtype[6] = '0x14EB'      #Tattered Treasure map
   VAR udochka   = '0x0DBF'
   VAR nozh      = '0x0F51'
   VAR NumTile   = '6043'
   VAR MaxWeigth = UO.STR*4
   VAR i, x, y, k
   wait(500)
   UO.Equipt('Rhand', udochka)
 start:
   for x=-6 to 6
      for y=-6 to 6
         ToHide()
         UO.Print("Рыбачим в точке: " + str(x) + " " + str(y))
         UO.DeleteJournal()
         while not UO.InJournal("no fish here") and not UO.InJournal("location") and not UO.InJournal("far away") and not UO.InJournal("in water")
            k = 0
            if UO.Weight > MaxWeigth then
               goto finish
            endif
            ToHide()
            UO.DeleteJournal()
            UO.WaitTargetTile(NumTile, str(UO.GetX()+x), str(UO.GetY()+y), str(UO.GetZ()))
            UO.UseType(udochka)
            while not (UO.InJournal("in water") or UO.InJournal("far away") or UO.InJournal("but fail") or UO.InJournal("You pull") or UO.InJournal("no fish here") or UO.InJournal("location") or k==50)
               k = k + 1
               wait(200)
               if UO.InJournal("Targeting Cancelled") then
                  goto start
               endif
            wend
            #собираем улов
            if UO.InJournal("You pull") then
               for i=0 to 6
                  UO.FindType(ULOVtype[i], '-1', 'ground')
                  UO.MoveItem('finditem')
                  wait(50)
               next
            endif
         wend
      next
   next
 finish:
   UO.Print("Набран максимальный вес улова")
   wait(1000)
   #режем рыбу
   UO.Print("Режем рыбу на фиш стейки")
   for i=0 to 3
      UO.WaitTargetType(ULOVtype[i])
      UO.UseType(nozh)
      wait(1000)
   next
   if UO.Weight < MaxWeigth-5 then
      goto start
   endif
   UO.Print("Рыбалка закончилась")
endsub

SUB ToHide()
   while not UO.Hidden()
      UO.WarMode(0)
      UO.DeleteJournal()
      UO.Print("Прячемся...")
      UO.UseSkill('Hiding')
      while not (UO.InJournal("You have hidden") or UO.InJournal("You can't seem"))
         wait(100)
      wend
   wend
endsub
#-----------------------------------------------------------------------#
#########################################################################