Yoko
http://forum.yoko.com.ua/

помагите хоть раз
http://forum.yoko.com.ua/viewtopic.php?f=20&t=7460		 Page 1 of 1
Author:  The Vampire [ 2006-04-22 19:07:34 ]
Post subject:  помагите хоть раз
пару раз спрашивал недали..
помаги хоть сейчас..
я бот в макросах :) ну как бот магу только подправить готовый..
чирните пару строчек пожалуйста.. (ПОСИКОМ ПОЛЬЗОВАЛСЯ,ТАМ ТАКОГО НЕТ)
собственно принцып
в паке лежат бутылки с ядом и кортик..
чар юзает скил пойсонинг появляеться таргет,таргетом на кортик и потом на бутылку
буду очень благодарен тому кто поможет
Author:  Scripts Writer [ 2006-04-22 19:42:17 ]
Post subject: 
Code:
sub pois()
var k = 0
var dagger=' type '
var poisbottle=' type '
var msg=' удачная месага '
var msg1=' неудачная месага '
var msg3=' месага : какими бутылками травим '
  while not uo.Dead()
    uo.DeleteJournal()
    uo.UseSkill('Poisoning')
    uo.WaitTargetType(dagger)
    wait(1000)
    if uo.InJournal(msg3) then
      uo.WaitTargetType(bottle)
    end if
    while not uo.InJournal(msg) and not uo.InJournal(msg1) and (k<30)
      k = k + 1
      wait(300)
    wend
      k = 0
  wend
end sub



плохо ты поиск искал-пробуй. Ошибки есть наверняка-продолжай обсуждение скрипта( список ошибок пиши) в этом же топе
Author:  The Vampire [ 2006-04-22 21:33:28 ]
Post subject: 
спасибо!!!!
щас потестю
Author:  The Vampire [ 2006-04-22 21:41:28 ]
Post subject: 
sub pois()
var k = 0
var dagger='0x0F52'
var bottle='0x0F0A'
var msg='You apply the poison'
var msg1=' íåóäà÷íàÿ ìåñàãà '
var msg3='What poison do you want to use?'
while not uo.Dead()
uo.DeleteJournal()
uo.UseSkill('Poisoning')
uo.WaitTargetType(dagger)
wait(1000)
if uo.InJournal(msg3) then
uo.WaitTargetType(bottle)
end if
while not uo.InJournal(msg) and not uo.InJournal(msg1) and (k<30)
k = k + 1
wait(300)
wend
k = 0
wend
end sub

________________________________________________________

это то что я подправил :)
тама разногласия идут с тайпом и ботлами ну это ты просто спешил :)
а самое главное что он спрашивает какой вид пойзона испольовать.. после того как тыркнет таргетом на котркит и остонавлеваеться с открытым таргетом :)
теость невыбирает бутылку
Author:  Savage [ 2006-04-23 09:20:25 ]
Post subject: 
Вот кусок скрипта, наглядно показывает как юзать поизонинг. Даггер - объект в инже. Ищется тип бутылки с пойзоном и если находи то травит даггер. Дерзай.
Code:
         While UO.Count('0x0F0A')
            UO.DeleteJournal()
            UO.FindType('0x0F0A','0x0000','backpack')
            wait(200)
            If UO.FindCount() Then
               UO.WaitTargetObject(Dagger,'finditem')
               UO.UseSkill('Poisoning')
               Repeat
                  wait(200)
               Until UO.InJournal("fail|You apply")
            Endif
         Wend
Author:  The Vampire [ 2006-04-23 23:16:18 ]
Post subject: 
Какие вы все вредные,можно подумать я у вас скрипт на харвейстре попросил :roll:
Author:  dmitrykit [ 2006-04-23 23:21:16 ]
Post subject: 
to The Vampire:
vozmozno tebe sledujet nachat' s prostejshego? uoloop, asist, uopilot...
i vot kogda,.. ty budesh sposobenn napisat' skript na vysheperechislennyh, prinimajsj a za inject
Author:  The Vampire [ 2006-04-23 23:35:44 ]
Post subject: 
ну да,всем помогают а я левый? :shock:
Author:  DerMeister =) [ 2006-04-23 23:58:00 ]
Post subject: 
Ты не один такой =) только 10-20% прозьб доходят до ответа на вопрос или решения проблемы... остальные так и остаютя на уровне 3-4 ответов совершенно не в тему...

И проблема не в том что люди злые, а в том что очень часто помочь просто не реально т.к. недостаточно начальной информации, например такой:
Шард
Технология использования скилла (какие сообщения выдаёт клиент при физле/удачном использовании и тд и тп)
....
Author:  DerMeister =) [ 2006-04-24 00:03:02 ]
Post subject: 
Вот у меня что есть: (разбирайся в нём сам ) (писался скрипт давно и под себя, поэтому он не универсален :( )
Code:
sub main_pois()

var vesh

uo.canceltarget()
uo.deletejournal()
wait(2000)

uo.print("Укажите что пойзоним...") 
uo.addObject("vesh") 
while uo.targeting() 
wait(100) 
wend 


repeat

  repeat 

  UO.FindType('0x0F0A',-1,2)   #тип яда

  UO.WaitTargetObject('vesh','finditem')  #В оригинале было:UO.WaitTargetObject('finditem','vesh')
  UO.UseSkill('Poisoning') 
  wait(10500)
  until uo.GetHP() < 16 or UO.FindCount() < 3

  #while uo.Poisoned()
  #uo.usetype('0x0F07')    #Cure
  #wait(1000)
  #wend

#wait(9100)

  while uo.GetHP() < 40
  uo.usetype('0x0F0C')    #Heal
  wait(1000)
  wend

until UO.FindCount()<6

end sub   


ЗЫ: Оригинал скрипта под ZHRessurrection...
Author:  The Vampire [ 2006-04-24 14:49:55 ]
Post subject: 
яж писал выше :)
в паке лежат бутылки с пойзоном.. чар юзает скил пойсонинг,первый таргет оружие,второй бутылка с ядом :) и так по кругу
Author:  Scripts Writer [ 2006-04-24 16:00:29 ]
Post subject: 
The Vampire wrote:
яж писал выше :)
в паке лежат бутылки с пойзоном.. чар юзает скил пойсонинг,первый таргет оружие,второй бутылка с ядом :) и так по кругу


в скрипте выше именно такая конструкция.
Author:  The Vampire [ 2006-04-24 19:33:48 ]
Post subject: 
огромное спасибо,всё работает 8)
если ктонибудь ещё прочтёт этот топик и захочет помоч,то помогите кемпингом :)
собствеено как работает :)
чар берёт из кучки по 1 кусочку хворосто ) кидает на пол около себя и поджигает :) и так по гругу )
главное чтобы кидал во все места куда может достать по очереди :)
надеюсь добрые люди и сейчас помогут
Author:  Kynep [ 2006-04-24 19:39:00 ]
Post subject: 
The Vampire wrote:
огромное спасибо,всё работает 8)
если ктонибудь ещё прочтёт этот топик и захочет помоч,то помогите кемпингом :)
собствеено как работает :)
чар берёт из кучки по 1 кусочку хворосто ) кидает на пол около себя и поджигает :) и так по гругу )
главное чтобы кидал во все места куда может достать по очереди :)
надеюсь добрые люди и сейчас помогут


Есть такое:
Code:
#===================================================================# 
# CAMPING                                                           # 
#===================================================================# 
#   v.1.04b (с) Edred                                               # 
#===================================================================# 
; Берем в пак 200 хвороста и реги, реколлимся по руне туда где можно 
; жечь костры, врубаем медитацию, отделяем по 1 шт. хвороста, кладем их 
; вокруг чара с трех сторон, дважды щелкаем по этим кучкам хвороста 
; для их разжигания (с повторами в случае физлов). Отходим назад 
; (направление на правый нижний угол - клавиша "3" на нумпаде). 
; Повторям последнюю операцию пока чар не придет в точку FinalX. 
; Реколлимся на базу, добираем из ящика хворост и реги. И по кругу. 
; 
; Разметьте руну где-нибудь в непосещаемом городе, прогуляйтесь шагов 
; на 30-50 по диагонали по направлению цифры 3 на нумпаде, занесите 
; координату X этой точки в FinalX (для надежности и защиты от лагов 
; будет лучше если в этой точке чар упрется в стенку). На базе рядом 
; с реколлкой поставьте сундук и в него положите много хвороста (можно 
; одной "неподьъемной" кучкой и побольше регов для реколла. 
; Занесите руну в этот город в ту же рунбуку, где и руна на базу. 
; 
sub camping() 
   DIM Regs[3] 
   Regs[0] = '0x0F7A'         ; Black Pearl 
   Regs[1] = '0x0F7B'         ; Bood Moss 
   Regs[2] = '0x0F86'         ; Mandrake Root 
   VAR Hvorost = '0x0DE1' 
   VAR flag, myx, myy, myz, fin, i 
   VAR FinalX = 1350 
   VAR Sunduk = '0x40591B82' 
   VAR RuneToBase = '20' 
   VAR RuneToFire = '30' 
   ; 
   ; Стартуем стоя в начале пути. 
;      UO.SetGlobal( 'TimeProcess', str( UO.Timer() ) ) 
   UO.Exec( 'set finddistance 3' ) 
   While UO.SkillVal( 'Camping' ) < 1000 
      fin = 0 
      UO.UseSkill( 'Meditation' ) 
      UO.FindType ( Hvorost ) 
      While ( UO.FindCount() > 0 ) AND ( fin == 0 ) 
         myx = UO.GetX() 
         myy = UO.GetY() 
         myz = UO.GetZ() 
         UO.MoveItem('finditem', '1', 'ground', str(myx-1), str(myy), str(myz)) 
         wait(1000) 
         CheckLag() 
         UO.FindType ( Hvorost ) 
         UO.MoveItem('finditem', '1', 'ground', str(myx), str(myy+1), str(myz)) 
         wait(1000) 
         CheckLag() 
         UO.FindType ( Hvorost ) 
         UO.MoveItem('finditem', '1', 'ground', str(myx), str(myy-1), str(myz)) 
         wait(1000) 
         CheckLag() 
         UO.Findtype( Hvorost, -1, 1 ) 
         While UO.FindCount() > 0 AND NOT UO.InJournal( "You can't ignite several" ) 
            repeat 
               flag = 1 
               DeleteJournal( "You fail to ignite" ) 
               DeleteJournal( "You can't ignite several" ) 
               DeleteJournal( "You must wait" ) 
               UO.UseFromGround( Hvorost ) 
               wait(1000) 
               CheckLag() 
               If UO.InJournal( "You must wait" ) OR UO.InJournal( "You fail to ignite" ) Then 
                  flag = 0 
                  wait(1000) 
               Endif 
               If UO.InJournal( "You can't ignite several" ) Then 
                  UO.FindType( Hvorost, -1, 1 ) 
                  While UO.FindCount() > 0 
                     If UO.GetQuantity( 'finditem' ) > 1 Then 
                        UO.Grab( str( UO.GetQuantity( 'finditem' ) - 1 ), 'finditem' ) 
                        wait(1000) 
                        CheckLag() 
                     Endif 
                     UO.Ignore( 'finditem' ) 
                     UO.FindType( Hvorost, -1, 1 ) 
                  Wend 
                  UO.IgnoreReset() 
               Endif 
            until flag 
            UO.Findtype( Hvorost, -1, 1 ) 
         Wend 
         While ( UO.GetX() < myx + 1 ) AND ( fin == 0 ) 
            UO.Press( 34 ) 
            wait(300) 
            CheckLag() 
            If UO.GetX() == FinalX Then 
               fin = 1 
            Endif 
         Wend 
         UO.FindType ( Hvorost ) 
      Wend 
      ; достигли конца маршрута или кончился хворост 
      Recalling( 'CommonRunbook', RuneToBase ) 
      UO.UseObject( Sunduk ) 
      wait(1000) 
      CheckLag() 
      for i = 0 To 2 
         If UO.Count( Regs[i] ) < 6 Then 
            ; этого рега меньше 6 
            UO.FindType( Regs[i], '-1', Sunduk ) 
            UO.Grab( str( 6 - UO.Count( Regs[i] ) ), 'finditem' ) 
            Wait( 1000 ) 
            CheckLag() 
         Endif 
      next 
      If UO.Count( Hvorost ) < 200 Then 
         ; хвороста меньше 200 
         UO.FindType( Hvorost, '-1', Sunduk ) 
         UO.Grab( str( 200 - UO.Count( Hvorost ) ), 'finditem' ) 
         Wait( 1000 ) 
         CheckLag() 
      Endif 
;      EatChar( Sunduk, 2, 1, 60 ) 
      Recalling( 'CommonRunbook', RuneToFire ) 
   Wend 
endsub 

##################################################################### 
Sub CheckLag() 
   DeleteJournal( 'backpack' ) 
   UO.Click( 'backpack' ) 
   repeat 
      wait(100) 
   until UO.InJournal( 'backpack' ) 
   return 
end sub 

##################################################################### 
Sub DeleteJournal( string1 ) 
   VAR nom = UO.InJournal( string1 ) 
   If nom > 0 Then 
      UO.SetJournalLine( Nom - 1, 'string replaced' ) 
      DeleteJournal( string1 ) 
   Endif 
endsub 

##################################################################### 
Sub Recalling( Runbk, NRune ) 
   ; Runbk - сериал или ссылка на объект рунбуки 
   ; NRune - десятичный номер (текстом) руны для реколла 
   VAR myx = UO.GetX() 
   VAR myy = UO.GetY() 
   VAR OldMana = UO.Mana 
   VAR i = 0 
   DeleteJournal( 'fizzles' ) 
   UO.Exec("recall " + Runbk + " " + NRune) 
   repeat 
      CheckLag() 
      wait(1000) 
      i = i + 1 
   until ( i > 6 ) OR ( UO.Mana < OldMana - 8 ) OR UO.InJournal( 'fizzles' ) 
   wait(500) 
   If myx == UO.GetX() AND myy == UO.GetY() Then 
      UO.WarMode( 'flip' ) 
      wait(100) 
      UO.WarMode( 'flip' ) 
      Recalling( Runbk, NRune ) 
   Endif 
endsub


Если слишком сложно то велком в топик "Скрипты от Асканелли" или в тему "Scripts!"
Author:  The Vampire [ 2006-04-24 21:24:49 ]
Post subject: 
Cooper огромное спасибо,но скрипты такого типо я и по поиску нашол :)
но мне ненада некуда летать и тпе :) мне всеголиш нада чтоб он разбрасывал их вокруг себя и поджиХал
Author:  Kynep [ 2006-04-25 06:40:46 ]
Post subject: 
The Vampire wrote:
Cooper огромное спасибо,но скрипты такого типо я и по поиску нашол :)
но мне ненада некуда летать и тпе :) мне всеголиш нада чтоб он разбрасывал их вокруг себя и поджиХал


Я не пойму, неужели так трудно пролистать две страницы назад и найти топик "Скрипты от Askaneli"?!?!?!?!?

Code:
var sunduk='0x4005CCAF' 

sub Camping() 
var mx=uo.getx(),my=uo.gety(),x,y 
uo.set('finddistance',5) 
uo.useobject(Sunduk) 
wait(200) 
uo.DeleteJournal() 
while 1==1 
   for x=mx-2 to mx+2 
      for y=my-3 to my+3 
         cheklag() 
         if uo.count('0x0DE1','0x0000')<10 then 
            UO.FindType('0x0DE1','0x0000',Sunduk) 
            wait(200) 
            UO.Grab('100','finditem') 
            wait(200) 
         end if 
         if (uo.count('0x0DE1','0x0000')==0) or (uo.skillval('Camping',1)==1000) then 
            uo.closeuo() 
         end if 
         uo.findtype('0x0DE1','0x0000','ground') 
         wait(200) 
         if UO.FindCount()<>0 then 
            uo.useobject('finditem') 
            wait(1500)             
         else 
            uo.findtype('0x0DE1','0x0000','backpack') 
            wait(200) 
            uo.drop('1',STR(x),STR(y),STR(uo.getz()),'finditem') 
            wait(700) 
            uo.findtype('0x0DE1','0x0000','ground') 
            wait(200)             
            uo.useobject('finditem') 
            wait(1500)             
         end if 
      next 
   next 
wend 
end sub 

sub cheklag() 
uo.deletejournal() 
uo.click('backpack') 
Repeat 
wait(100) 
Until UO.InJournal("backpack") 
end sub
Page 1 of 1 All times are UTC+02:00
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/