Yoko

All sides of Injection
It is currently 2024-03-29 01:34:40

All times are UTC+02:00




Post new topic  Reply to topic  [ 223 posts ]  Go to page Previous 1 2 3 4 5 612 Next
Author Message
 Post subject:
PostPosted: 2006-06-22 09:18:58 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Code:
sub poison() 
  var poison='0x0F0A'
  var color='0x0000'
  var msg='You apply the poison.'
  var msg2='You fail to apply a sufficient dose of poison to it.'
  var weap
  uo.Exec('addobject weap')
  while uo.targeting()
    wait(100)
  wend
  uo.FindType('poison','color','backpack')
  poison:
  uo.DeleteJournal()
  if uo.FindCount() then
    uo.poison('weap')
    repeat
      wait(100)
    until uo.InJournal(msg) or uo.InJournal(msg2)
    if uo.InJournal(msg2) then
      goto poison
    end if
  end if
end sub


Поизоним вещь. Если физл-повтор, пока не будет удачно.


Top
   
 Post subject:
PostPosted: 2006-06-22 16:17:30 
Offline

Joined: 2006-02-07 13:03:09
Posts: 27
ВСЕ ЗАРАБОТАЛО! :)
парни огромное спасибо :)
Маст дай и омич :)
итог:
Code:
sub main() 
While not uo.dead()
   uo.exec("waitmenu 'make' 'Shafts'")
   wait(500)
   UO.DeleteJournal()
   UO.findtype("0x1BDD", "-1", "0x604E2576")
   UO.Grab("1","finditem")
   UO.WaitTargetType("0x1BDD") ; ëîâóøêà íà ëîã â ïàêå
   UO.UseObject("_0x0F51")
   repeat
   wait(500)
   until uo.injournal("Failed.") or uo.injournal("Success.")
wend
endsub


Top
   
 Post subject:
PostPosted: 2006-06-22 17:27:11 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Шард Forest Wars ... Цикл скриптов пока играю там ) :

По началу игры всё что в трупе лежит, может пригодится...
Когда убиваете монстра-запускаете скрипт, он режит труп и собирает все что в нем лежит...

Code:
sub rezka()
var dagger='0x0F51'
  uo.WaitTargetObject('lastcorpse')
  uo.UseType(dagger)
  wait(500)
  uo.FindType('-1','-1','lastcorpse')
  while uo.FindCount()
    uo.FindType('-1','-1','lastcorpse')   
    uo.moveitem('finditem','-1','backpack')
    wait(500)
  wend
end sub



Раскладываем кучи Soul Stone (для шитья одежды магам) в отдельную сумку, так сказать-для удобства,а то после лута черт ногу в паке сломает...

Прицелом на сумку, и ждем пока разложит.

Code:
sub perekladka()
var soul='0x1EA7'
var symka
  uo.Exec('addobject symka')
  while uo.Targeting()
    wait(100)
  wend
  uo.FindType(soul,'-1','backpack')
  while uo.FindCount()
    uo.FindType(soul,'-1','backpack') 
    uo.moveitem('finditem','1','symka')
    wait(500)
  wend
end sub


Качаем магию хелинг и медитацию кастуя поизон + хелинг.

Code:
sub mag() 
  while not uo.Dead()
    while uo.mana > ( uo.int - 7 )
      uo.Cast( 'Poison' ,'self')
      wait(3500)
      while uo.life < 30
        uo.bandageself()
        wait(3500)
      wend
    wend
    while uo.mana < (uo.int + 7)
      uo.UseSkill('Meditation')
      wait(3000)
    wend
  wend
end sub


Раскладываем Soul of stone по мешкам,в зависимости от уровня камня.


Code:
sub rasklad()
; Первый таргет на сумку, где камни которые нужно отсортровать
var stone='0x1EA7'
var i

  uo.Exec('addobject where')
  while uo.Targeting()
    wait(100)
  wend
  uo.Exec('addobject symka1')
  while uo.Targeting()
    wait(100)
  wend
  uo.Exec('addobject symka2')
  while uo.Targeting()
    wait(100)
  wend
  uo.Exec('addobject symka3')
  while uo.Targeting()
    wait(100)
  wend
  uo.Exec('addobject symka4')
  while uo.Targeting()
    wait(100)
  wend
  uo.Exec('addobject symka5')
  while uo.Targeting()
    wait(100)
  wend 
  uo.DeleteJournal() 
  uo.FindType(stone,'-1','where')
  while uo.FindCount()
    uo.DeleteJournal()
    uo.Click('finditem')
    wait(250)
    if uo.InJournal('[1]') then
      uo.moveitem('finditem','1','symka1')
      wait(500)
    end if
    if uo.InJournal('[2]') then
      uo.moveitem('finditem','1','symka2')
      wait(500)
    end if
    if uo.InJournal('[3]') then
      uo.moveitem('finditem','1','symka3')
      wait(500)
    end if
    if uo.InJournal('[4]') then
      uo.moveitem('finditem','1','symka4')
      wait(500)
    end if   
    if uo.InJournal('[5]') then
      uo.moveitem('finditem','1','symka5')
      wait(500)
    end if     
    uo.FindType(stone,'-1','where')   
  wend
end sub


Качаем магию с добором регов + бинтов,едим, если что то кончается или умираем-закрываем окно уо.

Code:
sub mag() 
var i , a
var food='0x1608' # Еда
var hp = 85 # До скольки хелимся
var mana2= 18 # Разница макс. маны и интелекта


  DIM reg[3]

  reg[0]='0x0F88'
  reg[1]='0x0F7A'
  reg[2]='0x0E21' #Bandage
 
  uo.Exec('addobject sunduk')
  while uo.Targeting()
    wait(100)
  wend
  while not uo.Dead()
    for a = 0 to 2
      if uo.Count(reg[a]) < 5 then
        uo.FindType(reg[a],'-1','sunduk')
        if uo.FindCount() > 0 then
          uo.moveitem('finditem','100')
          wait(500)
        else
          uo.exec('terminate mag')
          uo.Close()
        end if
      end if
    next
    for i = 0 to 1
      uo.Cast( 'Bolt' ,'self')
      wait(3500)
    next
    while uo.life < hp
      uo.bandageself()
      wait(3500)
    wend
    while uo.mana < (uo.int + mana2)
      uo.UseSkill('Meditation')
      wait(3000)
    wend
    uo.UseType(food)
  wend
  uo.Close()
end sub


Last edited by Scripts Writer on 2006-06-28 14:52:26, edited 5 times in total.

Top
   
 Post subject:
PostPosted: 2006-06-28 09:43:08 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
ZWERb wrote:
Люди плиз дайте хилинг обычный(на курсе)


Code:
sub Heal() 
VAR cursa=' type of curse ' #Тут тип курсы поставь (вида 0x0000)
VAR maxHp=uo.str
  UO.UnDress()
  wait(200)
  While not UO.dead()
    UO.UseType(cursa)
    While UO.GetHP()>CharHP-1
      wait(500)
    Wend
    UO.UnDress()
    wait(200)
    UO.Bandageself()
    wait(3500)
  Wend
end sub


На коленках написан, пробуй


Top
   
 Post subject:
PostPosted: 2006-06-28 15:17:38 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Проверенный боукрафт для шарда Forest Wars

Code:
sub bowcraft()
var log='0x1BDD' ; Тип логов
var dagger='0x400097F7' ; ID дагера
var making=3000 ; Время изготовления
var shaft='0x1bd4'
 
  uo.Exec('addobject sunduk')
  while uo.Targeting()
    wait(100)
  wend
  while not uo.DeaD()
    uo.FindType(log,'-1','backpack')
    if uo.FindCOunt() then
      wait(100)
    else
      uo.FindType(log,'-1','sunduk')
      if uo.FindCount() then
        uo.moveitem('finditem','2')
        wait(500)
      else
        uo.Exec('terminate bowcraft')
      end if
    end if
    uo.WaitMenu('What','shaft')
    uo.WaitTargetType(log)
    uo.UseObject(dagger)
    wait(making)
    if uo.Count(shaft) > 100 then
      uo.FindType(shaft,'-1','backpack')
      uo.moveitem('finditem','100','sunduk')
      wait(500)
    end if
  wend
end sub


Top
   
 Post subject:
PostPosted: 2006-06-29 00:18:07 
Offline
User avatar

Joined: 2006-03-08 11:59:41
Posts: 122
You Must Die wrote:
ZWERb wrote:
Люди плиз дайте хилинг обычный(на курсе)


Code:
 


На коленках написан, пробуй


ГРЕЙТ СПС тебе за скрипт!
я его чучуть доделал =-) зацените люди!
HEALING
Code:
sub Heal()
VAR cursa='0x1EFD' #Тут тип курсы поставь (вида 0x0000)
VAR maxHp=uo.str
var i
  UO.UnDress()
  wait(200)
  While not UO.dead()
  for i = 1 to 10
  UO.UseType(cursa)
    While UO.GetHP()>maxHp-1
      wait(500)
    Wend
    UO.UnDress()
    wait(200)
    UO.Bandageself()
    wait(3500)
 next
Dopol()
Wend
end sub

sub Dopol()
var Moy ='0x40118407' ; ID Мойки
var BandBL ='0x0E20' ; Тип грязных бинтов
uo.warmode(0)
uo.useskill('Spirit Speak')
wait(1500)
UO.WaitTargetObject(Moy)
UO.UseType(BandBL)
wait(2500)
UO.UseType('0x097B')
end sub

_________________
СМЕРТЬ ФЛУДЕРАМ!


Top
   
 Post subject:
PostPosted: 2006-06-29 02:22:15 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Code:
sub Magery() 
var shade=' type of nightshade '
  uo.Exec('addobject symka')
  while uo.Targeting()
    wait(100)
  wend
  while not uo.Dead()
    if uo.Count(shade) < 10 then
      uo.FindType(shade,'-1','symka')
      if uo.FindCOunt() then
        uo.moveitem('finditem','100')
        wait(500)
      end if
    end if
    while uo.life > 75
      uo.Cast('Poison','self')
      wait(3000) ; Меняй под себя
    wend
    while uo.life < uo.str
      uo.UseSkill('Spirit Speak')
      wait(3000) ; Меняй под себя
    wend
    while uo.mana < uo.int
      uo.UseSkill('Meditation')
      wait(2000)
    wend
  wend
end sub


Пробуй

П.С. Тоже Forest Wars? =)


Top
   
 Post subject:
PostPosted: 2006-06-29 23:10:27 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Реги влево, бинты вправо, далее сами...

Code:
sub po_packy()
var i, k, a, l, ryna

  DIM leftup[9]
 
  leftup[0]='0x0F8C' ;Regs
  leftup[1]='0x0F8D' ;Regs
  leftup[2]='0x0F88' ;Regs
  leftup[3]='0x0F7B' ;Regs
  leftup[4]='0x0F85' ;Regs
  leftup[5]='0x0F84' ;Regs
  leftup[6]='0x0F7A' ;Regs
  leftup[7]='0x0F86' ;Regs
  leftup[8]='0x0EFA' ;Spell Book
 
  DIM rightup[1]
 
  rightup[0]='0x0E21' ;Bandages
  rightup[1]='0x1769' ;Key ring
 
  DIM center[1]
 
  center[0]='0x1F14' ;Rune
 
  for i = 0 to 8
    uo.FindType(leftup[i],'-1','backpack')
    if uo.FindCount() then
      uo.moveitem('finditem','all','backpack','44','68','0')
      wait(500)
      uo.Ignore('finditem')
    end if
  next
  for k = 0 to 1
    uo.FindType(rightup[k],'-1','backpack')
    if uo.FindCount() then
      uo.moveitem('finditem','all','backpack','143','67','0')
      wait(500)
      uo.Ignore('finditem')     
    end if
  next
  uo.IgnoreReset()
end sub


Top
   
 Post subject:
PostPosted: 2006-07-02 13:00:25 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Code:
;Скрипт не такой простой, как на первый взгляд поэтому
;каждое действие буду коментировать, дабы настраивать
;ты его будешь сам(или кто то другой, кому уже будет это
;проще зделать) -я лишь могу исправить ошибки если что
;то попутал.
sub Cartography()
#Задаём переменные#
var bag='type'
var blanc=' type '
var map=' type '
var OkMsg=' '
var FailMsg=' '
var blancbag , k , readybag
#3 таргета. Первый на сундук где мешки с бланками, второй
#куда складывать мешки с отработанным материалом,третий таргет на
#сундук, где брать пустые мешки.
uo.Exec('addobject syndyk')
while uo.targeting()
  wait(100)
wend
uo.Exec('addobject syndyk2')
while uo.targeting()
  wait(100)
wend
uo.Exec('addobject syndyk3')
while uo.targeting()
  wait(100)
wend
  uo.FindType(bag,'-1','syndyk')
#Пока существуют мешки в сундуке, скрипт работает
  while uo.FindCount()
    uo.FindType(bag,'-1','syndyk')
    uo.moveitem('finditem','1')
#Если мешок есть в бекпаке
    if uo.Count(bag) > 0 then
#Тогда присваиваем переменный ИД по найденному и перемещенному мешку
      blancbag = uo.GetSerial('finditem')
      uo.UseObject('finditem')
#Ищем бланки в перемещенном в пак мешке
      uo.FindType(blanc,'-1','blancbag')
#Пока они там есть, скрипт не будет брать следующий,а будет отрабатывать до конца первый мешок
      while uo.FindCount()
        k = 0
        uo.DeleteJournal()
        uo.WaitMenu()
        uo.UseSkill('Cartography')
        while not uo.InJournal(OkMsg) or not uo.InJournal(FailMsg) or (k<100)
          wait(100)
          k = k + 1
        wend
#Для работы или же прекращения цикла находим бланки в мешке
      wend   
#Как тока кол-во бланков в мешке кончилось, переходим к отработанному материалу. Ищем в паке и подсумках готовые изделия
       uo.FindType(map,'-1','my')
#Если нашли, то ищем мешок в сундуке3, чтобы переместить туда готовые мапы
       if uo.FindCount() then
         uo.FindType(bag,'-1','syndyk3')
#Если мешок найден, тогда берём его в пак, задаем в переменную его ИД, и перемещаем все карты которые есть в паке.
         if uo.FindCount() then
           uo.moveitem('finditem','1')
           wait(500)
         end if
         readybag=uo.GetSerial('finditem')
         while uo.FindCount()
           uo.FindType(map,'-1','backpack')
           uo.moveitem('finditem','1','readybag')
         wend
#Убираем мешок во 2 сундук.
        uo.moveitem('readybag','1','syndyk2')
      end if
    end if
  wend
end sub



Версия скрипта без комментариев.

Code:
;то попутал.
sub Cartography()
var bag='type' ;Тип мешков в которых карты
var blanc=' type ' ;Тип бланков
var map=' type ' ;Тип готового материала
var OkMsg=' ' ;Удачная месага
var FailMsg=' ' ;Неудачная месага
var blancbag , k , readybag
#3 таргета. Первый на сундук где мешки с бланками, второй
#куда складывать мешки с отработанным материалом,третий таргет на
#сундук, где брать пустые мешки.
uo.Exec('addobject syndyk')
while uo.targeting()
  wait(100)
wend
uo.Exec('addobject syndyk2')
while uo.targeting()
  wait(100)
wend
uo.Exec('addobject syndyk3')
while uo.targeting()
  wait(100)
wend
 uo.FindType(bag,'-1','syndyk')
 while uo.FindCount()
   uo.FindType(bag,'-1','syndyk')
   uo.moveitem('finditem','1')
   if uo.Count(bag) > 0 then
     blancbag = uo.GetSerial('finditem')
     uo.UseObject('finditem')
     uo.FindType(blanc,'-1','blancbag')
     while uo.FindCount()
       k = 0
       uo.DeleteJournal()
       uo.WaitMenu()
       uo.UseSkill('Cartography')
       while not uo.InJournal(OkMsg) or not uo.InJournal(FailMsg) or (k<100)
         wait(100)
         k = k + 1
       wend
     wend   
     uo.FindType(map,'-1','my')
     if uo.FindCount() then
       uo.FindType(bag,'-1','syndyk3')
       if uo.FindCount() then
         uo.moveitem('finditem','1')
         wait(500)
       end if
       readybag=uo.GetSerial('finditem')
       while uo.FindCount()
         uo.FindType(map,'-1','backpack')
         uo.moveitem('finditem','1','readybag')
       wend
       uo.moveitem('readybag','1','syndyk2')
     end if
   end if
 wend
end sub


***************
Еще раз опиши полный процесс крафта. Полный я сказал!
Юзаем скил, какое меню появляется, сколько крафт по времени примерно,какие сообщения,что получается,куда падает и т.д.Всё опиши, иначе чушь которая написана выше, по твоим смутным рассказам навсегда останется в этой теме не тронутой.


Top
   
 Post subject:
PostPosted: 2006-07-04 15:35:57 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Code:
sub mag() 
# 1.01 #
var i , a
var food='0x09D0' # Тип еды
var hp = 98 # До скольки хелимся
var mana2= 21 # Разница интелекта и маны

  DIM reg[5]

  reg[0]='0x0F7B'
  reg[1]='0x0F85'
  reg[2]='0x0F8C'
  reg[3]='0x0F86'
  reg[4]='0x0E21' #bandage
 
  uo.Exec('addobject sunduk')
  while uo.Targeting()
    wait(100)
  wend
  while not uo.Dead()
    for a = 0 to 4
      if uo.Count(reg[a]) < 5 then
        uo.FindType(reg[a],'-1','sunduk')
        if uo.FindCount() > 0 then
          uo.moveitem('finditem','100')
          wait(500)
        else
          uo.exec('terminate mag')
          uo.Close()
        end if
      end if
    next
    if uo.life <> hp then
      uo.bandageself()
      wait(3000)
    end if
    while uo.mana > 40
      if uo.life <> hp then
        uo.bandageself()
        wait(3000)
      end if
      uo.Cast('Earthquake')
      wait(3300)
    wend
    uo.UseSkill('Meditation')   
    while uo.mana < (uo.int + mana2)
      if uo.life <> hp then
        uo.bandageself()
        wait(3000)
      end if
      wait(100)
    wend
;    while uo.GetHp('target') <> uo.GetMaxHp('target')
;      wait(100)
;      if uo.GetHp('target') <> uo.GetMaxHp('target') then
;        uo.WaitTargetObject('target')
;        uo.UseType('0x0E21')
;        wait(3000)
;      end if
;    wend
;    uo.UseType(food)
  wend
  uo.Close()
end sub


Собственно качаем магию дальше.

Каст землетрясения , добор регов и бинтов + в случае атаки отхел на всех стадиях скрипта.



Code:

sub medit()
var i , a
while not uo.Dead()
a = 0
for a = 0 to 2
  uo.WarMode(false)
  uo.LClick(68,13) ;Координаты вкладки Умения
  wait(1000)
  uo.LClick(80,110) ;Координаты умения которое юзаем
  wait(1000)
  i = 0
  for i = 0 to 15
    uo.WarMode(false)
    uo.UseSkill('Spirit Speak')
    wait(3000)
  next
next
  uo.WarMode(false)
  uo.UseSkill('Meditation')
  while uo.mana <> uo.int + 21 ;Разница интелекта и маны
    wait(100)
  wend
wend
end sub


3 раза кликаем на умение, качаем спирит , тем самым когда сожгли 150 маны( 50 маны на одно умение) начинаем медитировать, и так по циклу.

Умение-спирит-умение-спирит-умение-спирит-медитация-умение...


Top
   
 Post subject:
PostPosted: 2006-07-07 16:20:24 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Продолжение цикла скриптов для шарда Forest Wars:

Стоим в спаринга-хелим себя и своего партнёра.

Code:
sub sparrying()
var bandage='0x0E21'
uo.Exec('addobject target')
while uo.targeting()
  wait(100)
wend
  while not uo.Dead()
    while uo.GetHp('target') > uo.GetMaxHp('target') / 2
      wait(100)
      if uo.life < 80 then
        uo.bandageself()
        wait(3000)
      end if
    wend
    while uo.GetHp('target') < uo.GetMaxHp('target')
      uo.WaitTargetObject('target')
      uo.UseType(bandage)
      wait(3000)
      if uo.life < 80 then
        uo.bandageself()
        wait(3000)
      end if
    wend
  wend
end sub
Качаем медитацию, используя абилки в умениях.

Code:
sub medit_abil_ss()
var mana = 21 # Разница интелекта и максимальной маны.
var i
while not uo.Dead()
  uo.WarMode(false)
  for i = 0 to 2 # Сколько раз юзаем абилку, перед медитацией.
    uo.Say('.UseAbility 1')
    wait(500)
    uo.WarMode(false)
    uo.Say('.DropAbility')
    wait(500)
  next
  uo.UseSkill('Meditation')
  while uo.mana <> uo.int + mana
    wait(100)
  wend
wend
end sub
Качаем Item Identification с добором инготов с пола, в пак.
Code:
sub itemident()
var ingot='0x1BEF'
var hp = 100
var i
uo.Set('finddistance','3')
  while not uo.Dead()
    for i = 0 to 50
      uo.DeleteJournal()
      uo.WaitTargetType(ingot)
      uo.UseSkill('Item Identification')
      wait(3000)
      if uo.life <> hp then
        uo.bandageself()
        wait(3000)
      end if     
      if uo.InJournal('You are not skilled') then
        uo.FindType(ingot,'-1','backpack')
        if uo.FindCOunt() then
          uo.moveitem('finditem','1','ground')
          wait(500)
        end if
      end if
    next
    uo.FindType(ingot,'-1','ground')
    if uo.FindCount() then
      uo.moveitem('finditem','1')
      wait(500)
    end if
  wend
end sub


Top
   
 Post subject:
PostPosted: 2006-07-09 13:20:00 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Переписал прокачку абилки и медитации:

Code:
sub medit_abil_ss()
var mana = 18 # Разница маны и интелекта
var hp = 118 # До сокльки хелимся
var i
while not uo.Dead()
  uo.WarMode(false)
  if uo.mana <> uo.int + mana then
  uo.UseSkill('Meditation') 
  while uo.mana <> uo.int + mana
    wait(100)
      if uo.life < hp then
        uo.bandageself()
        wait(3000)
        uo.WarMode(false)
        uo.UseSkill('Meditation')
      end if       
  wend
  end if
  for i = 0 to 2 # Сколько раз абилу юзаем
    uo.Say('.DropAbility')
    wait(700) 
    uo.Say('.UseAbility 2')
    wait(700)
    uo.WarMode(false)
      if uo.life < hp then
        uo.bandageself()
        wait(3000)
      end if   
  next
  uo.UseSkill('Meditation')
  while uo.mana <> uo.int + mana
    wait(100)
      if uo.life < hp then
        uo.bandageself()
        wait(3000)
        uo.WarMode(false)
        uo.UseSkill('Meditation')
      end if       
  wend
wend
end sub


Top
   
 Post subject:
PostPosted: 2006-07-22 20:51:26 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Шард Forest Wars- крафтим бланки.

Code:
sub Craft_Blanc()
  var paper='0x1F24'
  var blanc='0x0E34'
  var instrument='0x40029C88'
  var k , i
 
  DIM material[2]
 
  material[0]='0x175D'
  material[1]='0x1BD7'

  while not uo.Dead()
    for i = 0 to 1
      uo.FindType(material[i],'-1','backpack')
      if not uo.FindCOunt() then
        uo.FindType(material[i],'-1','ground')
        if uo.FindCount() then
          uo.moveitem('finditem','50')
          wait(750)
        end if
      end if
    next
    ## Êðàôò áóìàãè ##
    repeat
      uo.DeleteJournal()
      k = 0
      uo.WaitMenu('Carpentry','Paper')
      uo.UseObject(instrument)
      while NOT UO.InJournal('You put') AND NOT UO.InJournal('fail') AND ( k < 50 )
        k = k + 1
        wait(500)
      wend
    until uo.InJournal('You put')
    ## Êðàôò ïåðãàìåíòà ##
    repeat
      k = 0
      uo.DeleteJournal()
      uo.WaitMenu('Carpentry','Parchment')
      uo.UseObject(instrument)   
      while NOT UO.InJournal('You put') AND NOT UO.InJournal('fail') AND ( k < 50 )
        k = k + 1
        wait(500)
      wend
      wait(500)
    until uo.InJournal('You put')
    ## Êðàôò áëàíêà ##
    repeat
      k = 0
      uo.DeleteJournal()
      uo.WaitMenu('Carpentry','blank')
      uo.UseObject(instrument)
      while NOT UO.InJournal('You put') AND NOT UO.InJournal('fail') AND ( k < 50 )
        k = k + 1
        wait(500)
      wend 
    until uo.InJournal('You put')
    uo.FindType(blanc,'-1','backpack')
    if uo.FindCount() then
      uo.moveitem('finditem','all','ground')
      wait(750)
    end if
  wend
end sub


Top
   
 Post subject:
PostPosted: 2006-08-02 21:12:10 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Джесси wrote:
Помогите пожалуйста со скриптом , который бы проставлял тайлы деревьев и сохранял их в файл ... скрипты дрв не работают и скрипты под изю тоже . Шард - Форест Варз .


Читай первый пост. Скрипты под мининг и ламбер здесь не рассматриваются. Не моя специфика.


Top
   
 Post subject:
PostPosted: 2006-08-03 14:41:11 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Code:
sub Equiping()
var dagger=' type '
var sword=' type '
var shield=' type '
var halberd=' type '
var crossbow=' type '
  uo.FindType(dagger,'-1','backpack')
  if uo.ObjAtLayer('Rhand') then
    uo.Equipt('Rhand',sword)
    wait(250)
    uo.Equipt('Lhand',shield)
    wait(100)
    goto end
  end if
  uo.FindType(sword,'-1','backpack')
  if uo.ObjAtLayer('Rhand') then
    uo.Equipt('Rhand',haldberd)
    wait(250)
    goto end   
  end if
  uo.FindType(halberd,'-1','backpack')
  if uo.ObjAtLayer('Rhand') then
    uo.Equipt('Rhand',crossbow)
    wait(250)
    goto end   
  end if 
  uo.FindType(crossbow,'-1','backpack')
  if uo.ObjAtLayer('Rhand') then
    uo.Equipt('Rhand',dagger)
    wait(250)
    uo.Equipt('Lhand',shield)
    wait(100)   
    goto end   
  end if
  end:
end sub


Не тестил. Ставь типы- пробуй.


Top
   
 Post subject:
PostPosted: 2006-08-14 20:22:17 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Шринкуем дракона с земли,указывая таргетом.

Code:
sub shrink() 
  var typeshrink = ' '
  var colorshrink = ' '
  var drakonshrink = ' '
  uo.Exec('addobject drakon')
  while uo.Targeting()
    wait(100)
  wend
  uo.FindType(typeshrink,colorshrink,'backpack')
  if uo.FindCount() then
    uo.WaitTargetObject('drakon')
    uo.UseObject('finditem')
    wait(500)
  end if
  uo.FindType(drakonshrink,'-1','ground')
  if uo.FindCount() then
    uo.moveitem('finditem','all','backpack')
    wait(750)
  end if
end sub



Шринкуем дракона с земли,заранее указанного в скрипте через ID
Code:
sub shrink() 
  var typeshrink = ' '
  var colorshrink = ' '
  var drakonshrink = ' '
  var drakon= ' ID '
  uo.FindType(typeshrink,colorshrink,'backpack')
  if uo.FindCount() then
    uo.WaitTargetObject(drakon)
    uo.UseObject('finditem')
    wait(500)
  end if
  uo.FindType(drakonshrink,'-1','ground')
  if uo.FindCount() then
    uo.moveitem('finditem','all','backpack')
    wait(750)
  end if
end sub


Top
   
 Post subject:
PostPosted: 2006-09-10 08:57:18 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
ZWERb wrote:
Плиз помогите скриптом!
В нем должно быть 3 функции!
1(Скупать ткань)
2(Делать Повязки(качать тейлор)
3(контроль безопасности)
4(реконектор)

В общем чтоб чар стоял скупал ткань, и сразу крафтил повязки!


Команда uo.Buy + скрипт на Tailor + Реконектор.


Top
   
PostPosted: 2006-09-17 13:36:44 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Shax wrote:
Примерно чтобы я полуморфился хелялся потом диспел на себя и опять полуморфился и хелялся

+ еще скрипт на хелинг у кого есть чтобы прокачать с помощью курсов


А посмотреть по теме никак? Именно такие скрипты тут и есть.!


Top
   
 Post subject:
PostPosted: 2006-09-19 05:55:15 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Code:
        *** Начал заново на Dragon World ***
 Буду постепенно выкладывать отработанные скрипты ниже


Качаем Stealth.
Code:
sub Stealth()
  while not uo.Dead()
    hide:
    uo.DeleteJournal()
    uo.UseSkill('Stealth')
    while not uo.InJournal('seem') and not uo.InJournal('You have hidden')
      wait(100)
    wend
    if uo.InJournal('You have hidden') then
      while not uo.InJournal('have been')
        uo.Press(36)
        wait(1000)
        uo.Press(36)
        wait(1000)   
        if uo.InJournal('have been') then
          goto hide
        else
          uo.Press(34)
          wait(1000)
          uo.Press(34)
          wait(1000)       
        end if
      wend
    else
      goto hide
    end if
  wend
end sub


Top
   
 Post subject:
PostPosted: 2006-09-23 13:41:51 
Offline

Joined: 2005-04-19 18:00:29
Posts: 2259
Location: Московская область
Скрипт на Poisoning. Если у кого есть предложения в дополнении-пишите ниже.

Code:
################################
#                              #
#     F o r e s t   W a r s    #
#                              #
################################
#           #                  #
# Poisoning # You Must Die (c) #
#           #                  #
################################
;
; var type = Тип ваших poison бутылок, которыми будем травить
; var color = Цвет ваших poison бутылок, которыми будем травить
; var msg = Сообщение, при удачном использовании скила
; var failmsg = Сообщение, в случае физла скила
;
; 'Sunduk' = Указываем , где лежат ваши бутылки poison'a
; 'Item' = Указываем вещ, которую будем травить
;


sub Poisoning()
var type = ' ' # Poison bottle
var color = ' ' # Poison bottle
var msg='You apply'
var failmsg='You fail to apply'
var i

uo.AddObject('Sunduk')
while uo.Targeting()
  wait(100)
wend
uo.AddObject('item')
while uo.Targeting()
  wait(100)
wend

  while not uo.Dead()
    uo.DeleteJournal()
    if uo.Count(type) < 3 then
      uo.FindType(type,color,'Sunduk')
      if uo.FindCount() then
        uo.moveitem('finditem','100')
        wait(750)
      else
        uo.Print('No poison bottle')
        uo.Print('Script terminate')
        uo.Exec('terminate Poisoning')
      end if
    end if
    uo.FindType(type,color,'backpack')
    uo.WaitTargetObject('item','finditem')
    uo.UseSkill('Poisoning')
    i = 0
    while not uo.InJournal(msg) and not uo.InJournal(failmsg) and (i<40)
      i = i + 1
      wait(500)
    wend
  wend
  uo.Exec('terminate Poisoning')
  uo.CloseUo()
end sub


Last edited by Scripts Writer on 2006-09-24 07:31:33, edited 1 time in total.

Top
   
Display posts from previous:  Sort by  
Post new topic  Reply to topic  [ 223 posts ]  Go to page Previous 1 2 3 4 5 612 Next

All times are UTC+02:00


Who is online

Users browsing this forum: No registered users and 8 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Limited