Yoko
http://forum.yoko.com.ua/

Скрипты для раздела Scripts. For Yoko
http://forum.yoko.com.ua/viewtopic.php?f=20&t=671		 Page 1 of 1
Author:  M0ke [ 2004-06-26 00:49:44 ]
Post subject:  Скрипты для раздела Scripts. For Yoko
Code:
#####################################################
###       BowCraf BowBolts Script v. 1.00.        ###
###                                               ###
###  Copyright & tested by cOoler on DRW Shard.   ### 
###                                               ###
### Oficial DRW Shards site - http://www.drw.ru   ###
#####################################################
##################################################### 
###   Инструкция по использованию и настройке.    ###
#####################################################
### 1. Для работы этого скрипта надо: сундук,
### перья,шафты,пила(или другой инструмент).
###
### 2. Описание подготовки к запуску скрипта.
### Берём сундук (можно и backpack),меняем в скрипте
### ID сундука на свой,кладем в него шафты,а к себе в 
### backpack перья и пилу,запускаем скрипт.
###
### 3. При использовании скрипта вам так или иначе 
### придется менять конфигурации скрипта.
### Вот как и где это НУЖНО сделать:
###
### $ Сменa ID сундука и типа шафтов.
### 1) UO.FindType('тип шафтов','0x0000','backpack')- тут вы
### указываете: тип шафтов.
### 2) UO.FindType('тип шафтов','colour сундука','ID сундука')- тут вы
### указываете: тип шафтов,его colour,ID сундука. 
#####################################################  
###               Конец инструкции.               ###
#####################################################

sub Bowcraft() 
repeat 
UO.FindType('0x1bd4','0x0000','backpack') 
put: 
If UO.GetQuantity('finditem')<1 then 
UO.FindType('0x1bd4','0x0000','0x40160062') ;Сериал сундука 
UO.Grab('1','finditem') 
wait(400) 
Endif 
UO.FindType('0x1bd4','0x0000','backpack') 
If UO.GetQuantity('finditem')<1 then 
goto put 
end if 
UO.Usetype('0x1bd4') 
UO.WaitMenu('Select arrow type','bolt') 
wait (1000) 
UO.DeleteJournal() 
while not (UO.InJournal("You put") or UO.InJournal("You fail")) 
wait(300) 
wend 
UO.UnSetReceivingContainer() 
wait(200) 
until UO.Dead() 
end sub
Author:  M0ke [ 2004-06-26 18:13:29 ]
Post subject: 
Вот Yoko я зменил и доделал а то там наколбасил )
Код:
Code:
##################################################### 
### Forensic Evaluation Script v. 1.03. ### 
### ### 
### Copyright & tested by cOoler on DRW Shard. ### 
### ### 
### Oficial DRW Shards site - http://www.drw.ru ### 
##################################################### 
##################################################### 
### Инструкция по использованию и настройке. ### 
##################################################### 
### 1. Для работы этого скрипта ничего не нужно. 
### 
### 2. Описание подготовки к запуску скрипта. 
### Запускаем скрипт и указать на мёртвое существо 
### (человек или животное) курсором. 
### 
### 3. Скрипт простой и каких либо исправлений не требует. 
##################################################### 
### Конец инструкции. ### 
##################################################### 

sub ForensicEvaluation() 
var count=0 
uo.print('Please Change Dead Creature...') 
uo.exec('addobject ForensicAnimal') 
while uo.targeting() 
wait(100) 
wend 
UO.DeleteJournal() 
repeat 
uo.waittargetobject('ForensicAnimal') 
UO.Useskill('Forensic Evaluation') 
while not UO.InJournal("unsure") and not UO.InJournal("looks") and not UO.InJournal("perform") and count<60 
wait(35) 
count=count+1 
wend 
wait(35) 
count=0 
UO.DeleteJournal() 
until UO.Dead() 
end sub
Author:  M0ke [ 2004-06-26 18:29:45 ]
Post subject: 
Code:
#####################################################
###  Blacksmitchy Script Vor Iron Metal v. 1.00.  ###
###                                               ###
###  Copyright & tested by cOoler on DRW Shard.   ### 
###                                               ###
### Oficial DRW Shards site - http://www.drw.ru   ###
#####################################################
##################################################### 
###   Инструкция по использованию и настройке.    ###
#####################################################
### 1. Для работы этого скрипта надо: молоток,    
### инги(Iron),Форж(плавилка).
###
### 2. Описание подготовки к запуску скрипта.
### Берём сундук (можно и backpack),меняем в скрипте
### ID сундука на свой,меняем ID форжи,
### кладем в сундук инги (как можно  
### больше),себе в руку молоток,запускаем скрипт.
### Он куёт даггеры и плавит их. 
###
### 3. При использовании скрипта вам так или иначе 
### придется менять конфигурации скрипта.
### Вот как и где это НУЖНО сделать:
### 
### $ Изменение продукта кования.
### UO.WaitMenu('Blacksmithing','Weapons','Weapons','Swords','Swords','dagger')- тут вы
### можете изменить - что будет ковать ваш чар.
###
### $ Смена ID форжи.
### UO.UseObject(ID форжи)- тут вы указываете: ID форжи.
###
### $ Смена типа ингов и ID сундука.
### UO.FindType('тип ингов айрона',-1,'backpack')- тут вы указываете: тип ингов айрона.
### UO.FindType('тип ингов айрона','colour сундука','ID сундука с ингами')- тут вы
### указываете: тип ингов айрона,их colour,ID сундука с ингами. 
#####################################################  
###               Конец инструкции.               ###
#####################################################


sub BlacksmithyIM() 

   VAR Exit=0, LastTimer 
   while Exit<>1 
      UO.DeleteJournal() 
      LastTimer=UO.Timer() 
      UO.WaitMenu('Blacksmithing','Weapons','Weapons','Swords','Swords','dagger') ;Что куем
      UO.UseType(0x1BEF) ;Инги айрона 

      while NOT UO.InJournal("You put") AND NOT UO.InJournal("You have failed") 
            wait(500) 
      wend 

      If UO.InJournal("You have failed") then 
         repeat 
            wait(100) 
         until UO.Timer()>=LastTimer+100 ;Время создания дагера
      EndIf 

      UO.FindType('0x0F51',-1,'backpack') 
      wait(500) 

      If UO.GetQuantity('finditem') then 
         UO.WaitTargetObject('finditem') 
         UO.UseObject(0x4012B5AC) ; Форж 
      Endif 

      UO.FindType('0x1BEF',-1,'backpack') 
      If UO.GetQuantity('finditem')<10 then 
         UO.FindType('0x1BEF','0x0000','0x4004CAE1') ;Cундук с ингами 
         wait(1000) 
         UO.Grab('1000','finditem') 
      Endif 
      wait(1000) 
   wend    
end sub
Author:  duzir [ 2004-07-22 21:18:16 ]
Post subject:  Re: Скрипты для раздела Scripts. For Yoko
M0ke wrote:
Code:
#####################################################
###       BowCraf BowBolts Script v. 1.00.        ###
###                                               ###
###  Copyright & tested by cOoler on DRW Shard.   ### 
###                                               ###
### Oficial DRW Shards site - http://www.drw.ru   ###
#####################################################
##################################################### 
###   Инструкция по использованию и настройке.    ###
#####################################################
### 1. Для работы этого скрипта надо: сундук,
### перья,шафты,пила(или другой инструмент).
###
### 2. Описание подготовки к запуску скрипта.
### Берём сундук (можно и backpack),меняем в скрипте
### ID сундука на свой,кладем в него шафты,а к себе в 
### backpack перья и пилу,запускаем скрипт.
###
### 3. При использовании скрипта вам так или иначе 
### придется менять конфигурации скрипта.
### Вот как и где это НУЖНО сделать:
###
### $ Сменa ID сундука и типа шафтов.
### 1) UO.FindType('тип шафтов','0x0000','backpack')- тут вы
### указываете: тип шафтов.
### 2) UO.FindType('тип шафтов','colour сундука','ID сундука')- тут вы
### указываете: тип шафтов,его colour,ID сундука. 
#####################################################  
###               Конец инструкции.               ###
#####################################################

sub Bowcraft() 
repeat 
UO.FindType('0x1bd4','0x0000','backpack') 
put: 
If UO.GetQuantity('finditem')<1 then 
UO.FindType('0x1bd4','0x0000','0x40160062') ;Сериал сундука 
UO.Grab('1','finditem') 
wait(400) 
Endif 
UO.FindType('0x1bd4','0x0000','backpack') 
If UO.GetQuantity('finditem')<1 then 
goto put 
end if 
UO.Usetype('0x1bd4') 
UO.WaitMenu('Select arrow type','bolt') 
wait (1000) 
UO.DeleteJournal() 
while not (UO.InJournal("You put") or UO.InJournal("You fail")) 
wait(300) 
wend 
UO.UnSetReceivingContainer() 
wait(200) 
until UO.Dead() 
end sub


что то он у меня постоянно слетает или блокируется UNSP . Может че не так делаю ?
Author:  BETEPAH [ 2004-07-28 08:28:10 ]
Post subject: 
Попробуй в всех задержках поставить не меньше 0,500. или 1 еще лучше

тоесь
Wait(200) меняем на wait(500)
Author:  BETEPAH [ 2004-07-28 13:00:33 ]
Post subject: 
### UO.FindType('тип ингов айрона','colour сундука','ID сундука с ингами')- тут вы

Кулер у тя тут ошибка ...поменяй........ :wink:
Author:  -Time- [ 2004-07-29 09:19:13 ]
Post subject: 
у меня вопрос - он по одной стреле делает или сразу всем магом пытаеться ?
Author:  BETEPAH [ 2004-07-29 10:33:22 ]
Post subject: 
По одной
Author:  -Time- [ 2004-08-11 14:27:41 ]
Post subject: 
есть у кого скрипт что бы не сразу стрелы делал а только штафы ???

дерево брал с сундука
Author:  Edred [ 2004-08-11 18:08:47 ]
Post subject: 
-Time- wrote:
есть у кого скрипт что бы не сразу стрелы делал а только штафы ???

дерево брал с сундука


Code:
#####################################################################
; Bowcraft. v.1.02b (c) Edred
;
; Чар берет из сундука логи, крафтит из них шафты
; и складывает эти шафты в этот же сундук.
; Если логи закончились - выход.
; Если даггер (или что вы там используете) сломался - 
; скрипт найдет аналогичный по типу в бэкпаке и возьмет
; в руки.
;
sub bowcraft() 
   VAR Sunduk = '0x4042B1A1'       ; Сериал сундука
   VAR Logi = '0x1BDD'          ; Тип логов
   VAR Shafts = '0x1BD4'          ; Тип шафтов
   VAR Kolvo = 10               ; Брать логов для одного крафта
   VAR k = 0, j, dagger
   dagger = UO.ObjAtLayer( 'Rhand' )
   UO.SetGlobal( 'instrtype', UO.GetGraphic( dagger ) )
   While TRUE
      UO.FindType( Logi, -1, Sunduk )   ; Ищем логи в сундуке
      If UO.FindCount() == 0 Then
         UO.Print("Logs not found, script terminated")
         return
      else
         j = UO.GetQuantity( 'finditem' )
         If j > Kolvo Then
            UO.Print( 'I can use ' + str( j ) + ' logs' )
         else
            UO.Print( "I can't use " + str( j ) + " logs" )
            return
         Endif
      Endif
      UO.Grab( Str( Kolvo ), 'finditem' )
      ; Чтобы не сблочило УНСП
      wait(500)
      ; А это - динамическая пауза на мув
      while UO.Count( Logi ) < Kolvo
         wait(100)
      wend
      ; проверка на то, что в руках по-прежнему даггер
      If CheckInstr() == 0 Then
         UO.Print("You don't have daggers!" )
         return
      Endif
      UO.DeleteJournal()
      UO.CancelMenu()
      UO.WaitMenu ('What do you want to carve', 'shaft' )
      UO.WaitTargetType( Logi )
      UO.UseObject( dagger ) 
      k = 0
      while NOT UO.InJournal('You put') AND NOT UO.InJournal('fail') AND ( k < 50 )
         k = k + 1
         wait(300)
      wend
      If UO.Count( Shafts ) > 0 then
         UO.FindType( Shafts, -1, -1 )
         UO.MoveItem( 'finditem', 0, Sunduk )
         wait(500)
         while UO.Count( Shafts ) > 0
            wait(100)
         wend
         UO.Print( 'Shafts moved' )
      Endif
   Wend
end sub

Sub CheckInstr()
   ; проверим, есть ли в правой руке инструмент того же
   ; типа, что и в глобальной переменной instrtype
   ; если нет - найдем в бэкпаке такой инструмент и
   ; возьмем в правую руку.
   VAR typ = UO.GetGlobal( 'instrtype' )
   VAR cur = UO.GetGraphic( UO.ObjAtLayer( 'Rhand' ) )
   If typ == cur Then
      return 1
   Endif
   UO.FindType( typ )
   If UO.FindCount() == 0 Then
      return 0
   Endif
   UO.Equip( 'RHand' , 'finditem' )
   wait(1000)
   return 1
endsub


Да, у нас можно только сразу по 10 шафтов делать, глюки (баги) типа "кладем 10 и 1, из 1 делаем шафт" закрыты.
Author:  -Time- [ 2004-08-13 15:22:54 ]
Post subject: 
класс, спасибо ...
а то так запарило на пол подлаживать
Page 1 of 1 All times are UTC+02:00
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/