Yoko
http://forum.yoko.com.ua/

Подскажите, в чем проблема?
http://forum.yoko.com.ua/viewtopic.php?f=20&t=3607		 Page 1 of 1
Author:  kristalla [ 2005-04-05 18:57:59 ]
Post subject:  Подскажите, в чем проблема?
Мне друг подкинул скрипт, который кует катаны, затем переплавляет их заново в инги, а когда ингов меньше 10, то берет еще инги из сундука. В сундуке много мешков (копаю и кую в ВИП шахте, людей копает много, поэтому мешков тоже много (для каждого)).
Дело в том, что он все делает, но не берет инги из мешка.
Скажите, в чем проблема?

ID сундука: 0x400BF2CC, тип сундука: 0x09AB
ID моего мешка: 0x4020D789, тип моего мешка: 0x0E76

sub BlacksmithyIM()

VAR Exit=0, LastTimer
while Exit<>1
UO.DeleteJournal()
LastTimer=UO.Timer()
UO.WaitMenu('Blacksmithing','Weapons','Weapons','Swords','Swords', 'katana') ;Что куем
UO.UseType(0x1BEF)

while NOT UO.InJournal("You put") AND NOT UO.InJournal("You have failed")
wait(500)
wend

If UO.InJournal("You have failed") then
repeat
wait(100)
until UO.Timer()>=LastTimer+100
EndIf

UO.FindType('0x13FE',-1,'backpack')
wait(500)

If UO.FindCount() > 0 then
UO.WaitTargetObject('finditem')
UO.UseObject('0x400C0EE4') ;
Endif

UO.FindType('0x1BEF',-1,'backpack')
If UO.GetQuantity('finditem')<10 then
UO.FindType('0x400BF2CC','0x4020D789','0x1BEF')
wait(1000)
UO.Grab('990','finditem')
Endif
wait(1000)
wend
end sub

Скажите, в чем ошибка?
Author:  Denton [ 2005-04-05 19:58:01 ]
Post subject:  Re: Подскажите, в чем проблема?
kristalla wrote:
UO.FindType('0x400BF2CC','0x4020D789','0x1BEF')

Мне очень не нравится эта строчка... Что-то в ней не так. Не разбирался :?
Author:  Immelstorn [ 2005-04-05 20:21:00 ]
Post subject: 
Исправь сторочку UO.FindType('0x400BF2CC','0x4020D789','0x1BEF') на
UO.FindType(0x1BEF,-1,0x400BF2CC)
Author:  Mguai [ 2005-04-05 20:24:03 ]
Post subject: 
Проблема в мозгах :twisted:
Author:  kristalla [ 2005-04-05 20:35:22 ]
Post subject: 
Immelstorn wrote:
Исправь сторочку UO.FindType('0x400BF2CC','0x4020D789','0x1BEF') на
UO.FindType(0x1BEF,-1,0x400BF2CC)


Инги все равно не берет. Пишется: invalid object: 990

Mguai: Если не можешь/не хочешь помочь - молчал бы.
Author:  Mguai [ 2005-04-05 20:55:37 ]
Post subject: 
ни надо нервнячить тебе помогут добрые Люди :D
Author:  kristalla [ 2005-04-06 16:26:16 ]
Post subject: 
Кто-нибудь, пожалуйста, скажите, в чем ошибка, почему он не берет из мешка инги?
Author:  Sfagnum [ 2005-04-06 16:31:11 ]
Post subject: 
UO.FindType('0x400BF2CC','0x4020D789','0x1BEF') - удали нах.
Author:  kristalla [ 2005-04-06 18:22:24 ]
Post subject: 
Не помогает.

Ув. Sfagnum! Пожалуйста, не могли бы вы переделать/доделать этот скрипт? Пожалуйста.
Идея, я думаю, понятна: чар кует катаны из айрона, переплавляет их в инги, когда инги заканчиваются, берет еще ингов.
Играю на ДРВ.
Все, кого спрашиваю, не знают, в чем дело, почему он не берет инги.
Author:  Sfagnum [ 2005-04-06 19:59:41 ]
Post subject: 
Code:
UO.FindType('0x1BEF',-1,'backpack')
If UO.GetQuantity('finditem')<10 then
UO.FindType('0x400BF2CC','0x4020D789','0x1BEF')
wait(1000)
UO.Grab('990','finditem')
Endif
этот кусок заменить на последующий
Code:
If UO.Count('0x1BEF','0x0000')<10 then
  UO.FindType('0x1BEF','0x0000','0x400BF2CC')
  UO.MoveItem('finditem','990','backpack')
  wait(1000)
Endif
Author:  Savage [ 2005-04-06 21:31:52 ]
Post subject: 
Подсказка верная, но работать будет только если вручную открыть сундук и мешок перед запуском скрипта. :)
Ну или в скрипт вписать вначале: uo.useobject('ид сундука') uo.useobject('ид мешка')

'ps Такого мутанта я еще не видел :) вот оригинал:
Code:
sub bs()
   VAR Exit=0, LastTimer, Forge='0x400D22C9', Cont='0x400D1BFC'
   while Exit<>1
      ToHide()
      UO.DeleteJournal()
      LastTimer=UO.Timer()
      UO.WaitMenu('Blacksmithing','Weapons','Weapons','Swords','Swords','dagger')
      UO.UseType(0x1BEF) ; iron ings

      while NOT UO.InJournal("You put") AND NOT UO.InJournal("You have failed")
            wait(500)
      wend

      If UO.InJournal("You have failed") then
         repeat
            wait(100)
         until UO.Timer()>=LastTimer+100 ;time to make a dagger
      EndIf

      UO.FindType('0x0F51',-1,'backpack')
      wait(500)

      If UO.GetQuantity('finditem') then
         UO.WaitTargetObject('finditem')
         UO.UseObject(Forge) ;forge
      Endif

      UO.FindType('0x1BEF',-1,'backpack')
      If UO.GetQuantity('finditem')<10 then
         UO.FindType('0x1BEF','0x0000',Cont)
         wait(1000)
         UO.Grab('1000','finditem')
      Endif
      wait(1000)
   wend   
   gong(2)
end sub


который можно поправить для твоих нужд так:
Code:
sub bs()
   VAR Exit=0, LastTimer, Forge='0x400C0EE4', Cont='0x4020D789'
   UO.UseObject('0x400BF2CC')
   UO.UseObject(Cont)
   while Exit<>1
      UO.DeleteJournal()
      LastTimer=UO.Timer()
      UO.WaitMenu('Blacksmithing','Weapons','Weapons','Swords','Swords', 'katana') ;Что куем 
      UO.UseType(0x1BEF) ; iron ings

      while NOT UO.InJournal("You put") AND NOT UO.InJournal("You have failed")
            wait(500)
      wend

      If UO.InJournal("You have failed") then
         repeat
            wait(100)
         until UO.Timer()>=LastTimer+100 ;time to make a dagger
      EndIf

      UO.FindType('0x13FE',-1,'backpack')
      wait(500)

      If UO.GetQuantity('finditem') then
         UO.WaitTargetObject('finditem')
         UO.UseObject(Forge) ;forge
      Endif

      UO.FindType('0x1BEF',-1,'backpack')
      If UO.GetQuantity('finditem')<10 then
         UO.FindType('0x1BEF','0x0000',Cont)
         wait(1000)
         UO.Grab('990','finditem')
      Endif
      wait(1000)
   wend   
end sub


Наслаждайся :)
Author:  kristalla [ 2005-04-07 14:40:48 ]
Post subject: 
Большое спасибо вам. Теперь все работает :)
Page 1 of 1 All times are UTC+02:00
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/