###############################################################
#===---====----===---===---= Mining =---=-=-=-=-=--=-=-=-=-=-=#
;""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
;==================== Main mining script ======================
;======================= NMY (Lil Nmy) ========================
;================= http://forum.yoko.com.ua ===================
;""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
sub main()
   VAR i, x
   
   Dim rune[20]
   rune[0] = 3
   rune[1] = '0x41504FB4'
   rune[2] = ''
   rune[3] = ''
   rune[4] = ''
   rune[5] = ''
   rune[6] = ''
   rune[7] = ''
   rune[8] = ''
   rune[9] = ''
   rune[10]= ''
   rune[11]= ''
   rune[12]= ''
   rune[13]= ''
   rune[14]= ''
   rune[15]= ''
   rune[16]= ''
   rune[17]= ''
   rune[18]= ''
   rune[19]= ''
   
   uo.print(' Покажы где руна дамой? ... ')
   uo.exec('addobject home')
   while uo.targeting()
      wait(250)
   wend
   
   uo.print(' Покажы сундук куда складывать и где руны в пещеры?? ... ')
   uo.exec('addobject Sunduk')
   while uo.targeting()
      wait(250)
   wend
   
   while 1
      for i = 1 to rune[0]
         
         fizz:
         if uo.mana < 12 then
            while uo.mana < 12
               uo.useskill('Meditation')
               wait(5000)
            wend
         endif
         
         regi()
         uo.DeleteJournal()
         uo.print(' Летим в шахту ...')
         x = uo.getx()
         uo.waittargetobject( rune[i] )
         uo.cast('Recall')
         
         while x == uo.getx() and not uo.InJournal('The spell fizzles')
            wait(250)
         wend
         
         if uo.InJournal('The spell fizzles') then
            goto fizz
         endif
         
         mining()
         unload()
         
      next
   wend
end sub
;-------------------------------------------
sub mining()
   VAR mx, my, mz, i, j, jor, ser, noto, n
   Dim Ore[4]
   Ore[1] = '0x19B7'
   Ore[2] = '0x19BA'
   Ore[3] = '0x19B8'
   Ore[4] = '0x19B9'
   
   mx = UO.GetX("self")
   my = UO.GetY("self")
   mz = UO.GetZ("self")
   
   uo.set('finddistance','2')
   uo.findtype('0x000E', -1 ,'ground')
   if uo.FindCount() then
      invis()
   else
      while not UO.Hidden()
         UO.Warmode("0")
         uo.print(" Прячемся...")
         UO.UseSkill("Hiding")
         wait(4000)
      wend
   end if
   
   for i = mx-4 to mx+4
      for j = my-4 to my+4
         UO.DeleteJournal()
         
         while not UO.Hidden()
            UO.Warmode("0")
            uo.print(" Прячемся...")
            UO.UseSkill("Hiding")
            wait(4000)
         wend
         
         while not UO.InJournal("Туда Вам не дотянуться|Это слишком далеко отсюда|Тут не осталось руды|You loosen some rocks but fail to find any useable ore.")
            UO.DeleteJournal()
            
            UO.Waittargettile("1339","1341","1343", str(i), str(j), str(mz))
            UO.Usetype("0x0E85")
            
            while not UO.InJournal("туда вам не дотянуться|это слишком далеко отсюда|тут не осталось руды|в шахте!|you put|fail to find|You loosen some rocks but fail to find any useable ore.|You have found") and not uo.Dead()
               if uo.Dead() then
                  uo.playwav("F:\Ultima Online 2D\music\alert.wav")
                  uo.exec('terminate all')
               endif
               wait(250)
            wend
            
            if uo.InJournal('is attacking you') then
               invis()
            endif
            
            for jor = 0 to 9
               ser = uo.journalserial(jor)
               noto = uo.getnotoriety(ser)
               if noto <> 1 and noto <> 0 and not uo.getgraphic(ser)=='0x000E' and not uo.InJournal('Fireman') then
                  if uo.waiting() then
                     uo.canceltarget()
                  endif
                  invis()
                  return
               endif
            next
            
            uo.set('finddistance','1')
            for n = 1 to 4
               uo.findtype( Ore[n] ,'-1','ground')
               while uo.FindCount()
                  uo.moveitem('finditem')
                  checklag()
                  wait(1000)
                  uo.findtype( Ore[n] ,'-1','ground')
               wend
            next
            
            if uo.weight > uo.str*4 then
               return
            endif
            
         wend
         
      next
   next
   uo.print(' Летим дамой ...')
end sub
;-------------------------------------------
sub unload()
   VAR n, x
   Dim UnLoad[4]
   UnLoad[1] = '0x19B7'
   UnLoad[2] = '0x19BA'
   UnLoad[3] = '0x19B8'
   UnLoad[4] = '0x19B9'
   
   fizz:
   uo.DeleteJournal()
   uo.print(' Летим дамой ...')
   x = uo.getx()
   uo.waittargetobject('home')
   uo.cast('Recall')
   
   while x == uo.getx() and not uo.InJournal('The spell fizzles') and uo.life >= uo.str
      wait(250)
   wend
   
   if uo.InJournal('The spell fizzles') then
      goto fizz
   endif
   
   if uo.life < uo.str then
      invis()
      heal()
      goto fizz
   endif
   
   check()
   open()
   walkme(2920,115,'')
   close()
   walkme(2914,110,'')
   
   uo.useobject("Sunduk")
   wait(250)
   CheckLag()
   
   uo.print(' Разгружаюсь ...')
   For n = 1 to 4
      UO.FindType( UnLoad[n] )
      while UO.FindCount()
         UO.moveitem('finditem','0','Sunduk')
         CheckLag()
         wait(1000)
         UO.FindType( UnLoad[n] )
      wend
   next
   
   uo.print(' Разгрузились ...')
end sub
;-------------------------------------------
sub invis()
   uo.print(' Инвизка ...')
   uo.warmode('0')
   uo.usetype('0x0F09','0x0060')
end sub
;-------------------------------------------
sub heal()
   uo.Print(' Лечение ... ')
   uo.warmode('0')
   while uo.life < uo.str
      uo.bandageself()
      checklag()
      wait(11000)
   wend
end sub
;-------------------------------------------
sub regi()
   VAR r, q, n, amount = 10
   Dim reg[4]
   reg[1] = '0x0F7A'
   reg[2] = '0x0F7B'
   reg[3] = '0x0F86'
   reg[4] = '0x0E21'
   
   For r = 1 to 4
      if uo.count( reg[r] )<>amount then
         q = amount - uo.count( reg[r] )
         
         if q <> 0 then
            if q > 0 then
               
               uo.useobject("Sunduk")
               wait(250)
               CheckLag()
               
               uo.findtype( reg[r] , -1 ,"Sunduk")
               
               If uo.findcount() == 0 then
                  uo.msg('You dont have any!')
                  return
               endif
               
               uo.moveitem('finditem', STR(q) )
               checklag()
               wait(1000)
               
            else
               
               q = q*-1
               uo.findtype( reg[r] )
               uo.moveitem('finditem', STR(q) ,"Sunduk")
               CheckLag()
               wait(1000)
               
            endif
         endif
         
      endif
   next
   
   While uo.Count('0x0F09','0x0060') < 2
      uo.findtype('0x0F09','0x0060',"Sunduk")
      if uo.FindCount() then
         uo.moveitem('finditem')
         checklag()
         wait(1000)
      endif
   wend
   
   uo.print(' Взяли реги ...')
end sub
;-------------------------------------------
sub open()
   uo.print(' Открываем калитку ...')
   UO.Set('finddistance','2')
   UO.FindType('0x0826', -1 ,'ground')
   If UO.FindCount() then
      UO.UseObject('finditem')
      repeat
         uo.findtype('0x0827', -1 ,'ground')
         wait(100)
      until uo.findcount()
   Endif
end sub
;-------------------------------------------
sub check()
   VAR m
   uo.Print(' Проверяем руну ... ')
   uo.deletejournal()
   uo.click('home')
   while not uo.injournal('jumps left')
      wait(250)
   wend
   if uo.injournal('(0 jumps left)|(1 jumps left)') then
      uo.Print(' Маркаем руну ... ')
      m = uo.mana
      uo.waittargetobject('home')
      uo.cast('Mark')
      repeat
         wait(250)
      until uo.mana<m
   endif
end sub
;-------------------------------------------
sub close()
   uo.print(' закрываем ...')
   UO.Set('finddistance','2')
   UO.FindType('0x0827', -1 ,'ground')
   If UO.FindCount() then
      UO.UseObject('finditem')
      repeat
         uo.findtype('0x0826', -1 ,'ground')
         wait(100)
      until uo.findcount()
   Endif
end sub
;-------------------------------------------
sub Reconnector()
   while True
      while UO.IsOnline() AND NOT UO.Dead()
         wait(1000)
      wend
      UO.TextOpen()
      UO.TextPrint('Disconnected at '+MakeTime())
      UO.Exec('terminate all')
      connect:
      wait(3000)
      UO.LDblClick(616,455)
      wait(3000)
      UO.LDblClick(616,455)
      wait(3000)
      UO.LDblClick(616,455)
      wait(3000)
      UO.LDblClick(357,164)
      if UO.IsOnline() then
         UO.Exec('exec main')
         UO.TextOpen()
         UO.TextPrint('Reconnected at '+MakeTime())
      else
         goto connect
      endif
   wend
endsub
;-------------------------------------------
sub MakeTime()
   VAR D, T, Ret, i
   Ret = STR(UO.Time())
   T = ""
   For i = 0 To Len(Ret)
      T = Ret[Len(Ret)-i] + T
      If (I == 2) OR (I == 4) Then
         T = ":" + T
      EndIf
   Next
   Ret = STR(UO.Date())
   D = ""
   For i = 0 To Len(Ret)
      D = Ret[Len(Ret)-i] + D
      If (I == 2) OR (I == 4) Then
         D = "." + D
      EndIf
   Next
   Ret = T + " @ " + D
   RETURN Ret
end sub

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;; W A L K E R ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

################# W A L K E R ######################

sub WalkME(x,y,Target)
   VAR i
   VAR dir,ldir,rdir,key,olddir
   VAR dx,dy,Exit=0
   VAR CacheLimit=9,CacheIndex="Text"
   DIM CacheX[10], CacheY[10]
   
   CacheX[0]="Test"
   While Exit<>1
      If Target<>"" Then
         dx=UO.GetX(Target)-UO.GetX()
         dy=UO.GetY(Target)-UO.GetY()
         ;         UO.Print("Target locked!")
         If UO.GetDistance(Target)<2 Then
            return
         Endif
      Else
         dx=x-UO.GetX()
         dy=y-UO.GetY()
         If dx==0 AND dy==0 Then
            Exit=1
         Endif
         
      Endif
      
      If dx<>0 AND dy<>0 Then
         If dx>0 AND dy>0 Then ; GoSE
            dir=3
            ldir=2
            rdir=4
            key=40 ; DownArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==2 Then ; GoNE
                  dir=1
                  ldir=0
                  rdir=1
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=5
                  rdir=6
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
         
         If dx>0 AND dy<0 Then ; GoNE
            dir=1
            ldir=0
            rdir=2
            key=39 ; RightArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==0 Then ; GoWN
                  dir=7
                  ldir=6
                  rdir=7
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSE
                  dir=3
                  ldir=3
                  rdir=4
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
         
         If dx<0 AND dy>0 Then ; GoSW
            dir=5
            ldir=4
            rdir=6
            key=37 ; LeftArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==6 Then ; GoWN
                  dir=7
                  ldir=7
                  rdir=0
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSE
                  dir=3
                  ldir=2
                  rdir=3
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
         
         If dx<0 AND dy<0 Then ; GoWN
            dir=7
            ldir=6
            rdir=0
            key=38 ; UpArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==0 Then ; GoNE
                  dir=1
                  ldir=1
                  rdir=2
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=4
                  rdir=5
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
      Endif
      
      If dx<>0 AND dy==0 Then
         If dx>0 Then ; GoE
            dir=2
            key=34 ; PgDown
            olddir=UO.GetDir()
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==2 Then ; GoSE
                  dir=3
                  ldir=3
                  rdir=4
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoNE
                  dir=1
                  ldir=1
                  rdir=0
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
         
         If dx<0 Then ; GoW
            dir=6
            key=36 ; Home key
            olddir=UO.GetDir()
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==0 Then ; GoWN
                  dir=7
                  ldir=7
                  rdir=0
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=4
                  rdir=5
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
      Endif
      
      If dx==0 AND dy<>0 Then
         If dy>0 Then ; GoS
            dir=4
            key=35 ; End
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==2 Then ; GoSE
                  dir=3
                  ldir=2
                  rdir=3
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=6
                  rdir=5
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
         
         If dy<0 Then ;GoN
            dir=0
            key=33 ; PgUp
            olddir=UO.GetDir()
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==2 Then ; GoNE
                  dir=1
                  ldir=1
                  rdir=2
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoWN
                  dir=7
                  ldir=7
                  rdir=6
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
      Endif
   Wend
end sub


sub StepEdit(x,y,dir,key)
   VAR walkwait=100
   VAR ErrLevel=0
   If UO.GetDir()<>dir Then
      checkstam()
      UO.Press(key)
      wait(walkwait)
      If UO.GetDir()<>dir Then
         CheckLag()
      Endif
   Endif
   checkstam()
   UO.Press(key)
   wait(walkwait)
   If x==UO.GetX() AND y==UO.GetY() Then
      CheckLag()
      If x==UO.GetX() AND y==UO.GetY() Then
         ;zatik
         ErrLevel=1
      Endif
   Endif
   Return ErrLevel
end sub


sub StepArrow(x,y,dir,ldir,rdir,key)
   VAR walkwait=100
   VAR ErrLevel=0
   If UO.GetDir()<>dir Then
      checkstam()
      UO.Press(key)
      wait(walkwait)
      If UO.GetDir()<>dir AND UO.GetDir()<>ldir AND UO.GetDir()<>rdir Then
         CheckLag()
      Endif
   Endif
   
   If UO.GetX()==x AND UO.GetY()==y Then
      checkstam()
      UO.Press(key)
      wait(walkwait)
      If UO.GetDir()==dir AND UO.GetX()==x AND UO.GetY()==y Then
         CheckLag()
         If UO.GetDir()==dir AND UO.GetX()==x AND UO.GetY()==y Then
            ; zatik
            ErrLevel=1
         Endif
      Endif
   Endif
   Return ErrLevel
end sub

sub checkstam()
   var refresh = '0x0F0B'
   if uo.stamina < 10 then
      uo.findtype(refresh,-1,'backpack')
      if uo.findcount() then
         uo.usetype(refresh)
         wait(1000)
      else
         uo.print("Nety Refreshey! Stoim...")
         repeat
            wait(500)
         until uo.stamina >= 10
      endif
   else
   endif
endsub

sub CHECKLAG()
   del('backpack')
   uo.click('backpack')
   repeat
      wait(200)
   until uo.injournal('backpack')
   del('backpack')
endsub

sub DEL(msg)
   while uo.injournal(msg)
      uo.setJournalLine(uo.injournal(msg)-1,"Is Empty!")
   wend
endsub

UO.Waittargettile("1339","1341","1343", str(i), str(j), str(mz))

UO.Waittargettile("1339", str(i), str(j), str(mz))

1343 1426 2884 0

1341 1424 2884 0

1339 1424 2883 0

1341 1424 2885 0

1341 1423 2884 0

1339 1424 2883 0

скрипт очень стар. мининг по рунам с дрв не пробовали?

язык программ какой установлен? потому что если английский, то русские сообщения не будут понятны в файле для скрипта.
в принципе он мне копал, когда изменил

Mirage wrote:

Обычно достаточно UO.WaitTargetTile("1341",STR(UO.GetX()+x),STR(UO.GetY()+Y),str(z))
Если не достаточно - ищи мининг с UO.PrivateGetTile. В моем, например, я переписал все возможные тайлы под 2.0.3 клиент (их там чуть больше чем 5 )

var bag = '0x4104B505'  ; сундук куда скидывать руду и откуда брать инструменты
var instr = '0x0E85'
var ore1 = '0x19B7'
var ore2 = '0x19BA'
var ore3 = '0x19B8'
var ore4 = '0x19B9'
var Lasttimer
sub main()
   repeat
      walker(1343, 1650, 0)
      UO.UseObject(bag)
      wait(1000)
      putore()    ; скидываем руду
      getinstr()  ; добираем инструменты
      walker(1343, 1650, 0)  ; координаты до шахты
      walker(1874, 271, 0)
      walker(1887, 271, 0)
      walker(1897, 271, 0)
      walker(1904, 271, 0)
      Mine()
      walker(1912, 273, 0)
      Mine()
      walker(1916, 281, 0)
      Mine()
      walker(1921, 276, 0)
      Mine()
      walker(1921, 269, 0)
      Mine()
      walker(1924, 264, 0)
      Mine()
      walker(1917, 271, 0)
      walker(1901, 271, 0)
      walker(1887, 271, 0)
      walker(1874, 271, 0)
      walker(1874, 267, 0)  ; координата у домика
   until UO.Dead()
end sub
sub getinstr()
   get(instr, bag, 3, 1)
   get(instr, bag, 3, 1)
   get(instr, bag, 3, 1)
endsub
sub putore()
   put(ore1,bag)
   put(ore2,bag)
   put(ore3,bag)
   put(ore4,bag)
end sub
################ Рудокоп #################
sub Mine()
   VAR Shovel1   = '0x0F39'
   VAR Shovel2   = '0x0F3A'
   VAR Pickaxe1   = '0x0E85'
   VAR Pickaxe2   = '0x0E86'
   VAR MaxRange = 5
   VAR X, Y, Z, Tiles
   VAR mX, mY, mZ
   VAR MaxVes = 610
   mX = UO.GetX('self')
   mY = UO.GetY('self')
   mZ = UO.GetZ('self')
   for Y = MaxRange - ( MaxRange * 2 ) to MaxRange
      for X = MaxRange - ( MaxRange * 2 ) to MaxRange
         Tiles = MiningTiles(mX+X, mY+Y)
         if Tiles then
            UO.DeleteJournal()
            repeat
               ############################
               #ПЕРЕГРУЗ!!!#
               ############################
               If UO.Weight > MaxVes Then
                  UO.Print('Перегруз!')
                  return
               endif
               ############################
               UO.Set('quiet','1')
               UO.DeleteJournal()
               UO.Warmode(0)
               UO.WaitTargetTile(Tiles, mX+X, mY+Y, mZ)
               UO.FindType(Shovel1,-1,'my')
               if UO.FindCount() then
                  UO.UseType(Shovel1)
               else
                  UO.FindType(Shovel2,-1,'my')
                  if UO.FindCount() then
                     UO.UseType(Shovel2)
                  else
                     UO.FindType(Pickaxe1,-1,'my')
                     if UO.FindCount() then
                        UO.UseType(Pickaxe1)
                     else
                        UO.FindType(Pickaxe2,-1,'my')
                        if UO.FindCount() then
                           UO.UseType(Pickaxe2)
                        else
                           UO.Set('quiet','0')
                           UO.Print("ERROR: Нечем копать!!!")
                           return
                        endif
                     endif
                  endif
               endif
               LastTimer=UO.Timer()
               repeat
                  wait(100)
               until UO.InJournal("%|destroyed|loosen|то слишком далеко отсюда|выкопали|0xAD00|0xA867|0xA2DE|0xAD03|0x5DE0|0x5DE1|0x5DE2|0x5DE3|0x5DE4|0x5DE5|0x5DE6|0x5DE7|Вы положили|put the|is nothing here to mine|Wthere do you|не удалось|У вас нет|have no line|ничего|Тут ничего|Попробуйте|Try mining elsewhere") || UO.Timer()>LastTimer+100 || UO.Weight > MaxVes || UO.Dead()
            until UO.InJournal("%|destroyed|0xAD00|0xA867|0xA2DE|не осталось руды.|is nothing here to mine|нет руды|У вас нет|have no line|Попробуйте|Try mining elsewhere") || UO.Timer()>LastTimer+500 || UO.Weight > MaxVes || UO.Dead()
            ############################
            #ПЕРЕГРУЗ!!!#
            ############################
            If UO.Weight > MaxVes Then
               UO.Print('Перегруз!')
               return
            endif
            ############################
         endif
      next
   next
   UO.Set('quiet','0')
   UO.Print("Все")
   UO.Sound(100)
   return 0
end sub
sub MiningTiles(X,Y)
   var i
   if UO.PrivateGetTile(X, Y, -1, 616, 618) then
      for i=616 to 618
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 1339, 1363) then
      for i=1339 to 1363
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 2272, 2282) then
      for i=2272 to 2282
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 4963, 4973) then
      for i=4963 to 4973
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 6001, 6012) then
      for i=6001 to 6012
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 13121, 13369) then
      for i=13121 to 13369
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 13446, 13455) then
      for i=13446 to 13455
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 13484, 13492) then
      for i=13484 to 13492
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   if UO.PrivateGetTile(X, Y, -1, 13625, 13628) then
      for i=13625 to 13628
         if UO.PrivateGetTile(X, Y, -1, i, i) then
            return i
         end if
      next
   end if
   return 1; No Mining Tiles
end sub
sub GET(item, cont, min, max)
   If UO.Count( item ) < min Then
      #       UO.Print("Кончилось сырье в рукзаке")
      UO.FindType( item, '-1', cont )
      if UO.FindCount() > 0 Then
         #        UO.Print('Сырья в сундуке: ' + Str( UO.FindCount( item ) ) )
         uo.moveitem('finditem', max, 'backpack')
         checklag()
      else
         #           UO.Print( 'Полностью кончилось сырье' )
         UO.CancelMenu()
         return
      endif
   Endif
end sub
sub PUT(item, cont)
   while UO.Count( item ) > 0
      UO.FindType( item, -1, -1 )
      UO.MoveItem( 'finditem', 0, cont )
      checklag()
   wend
end sub
sub DeleteJournal(msg)
   While UO.InJournal(msg)
      UO.SetJournalLine(UO.InJournal(msg) - 1,'')
   wend
endsub
sub MyTerminate()
   UO.Set('quiet','1')
   UO.CancelMenu()
   UO.IgnoreReset()
   UO.Set('quiet','0')
   UO.Exec('terminate all')
end sub
sub checklag()
   DeleteJournal("backpack")
   UO.Click("backpack")
   repeat
      wait(100)
   until UO.InJournal("backpack")
end sub
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; var Prec=3 # Как близко следует подойти к цели (Precision)
; В функции IsPass, содержиться список проходимых тайлов.
; Walker(X, Y, Prec) - идем к цели с координатами X, Y. Возвращает 1 в случае успешного достижения цели, и 0 - при невозможном обходе (путь не найден)
; Tracer(StartDir, Direction) - трассировка 1 шага. Возвращает направление по которому получилось сдвинуться с места. StartDir # -  направление последнего движения, Direction ( - 1 или  + 1) направление обхода.  - 1 - по часовой стрелке,  + 1 против часовой #стрелки. Направления скрипт использует личного формата:
; 1 - влево вниз
; 2 - вниз
; 3 - вправо вниз
; 4 - вправо
; 5 - вправо вверх
; 6 - вверх
; 7 - влево вверх
; 8 - влево
; Tracer(StartDir, Direction) - идеально подходит для рыбалки вдоль берега так как она будет обходить берег бесконечно (1 #запуск функции = 1 шаг обхода).
var MaxTraceDistance = 1 ; Максимальная длина обхода. Желательно ставить с расчета возможных препятсвий. Если ставить очень большие числа, кодилка может пойти в обход пол мира чтобы дойти к соседнему дереву.
var TraceLoopIncrease = 1 ; Увеличение MaxTraceDistance при исчерпании количества ходов.
var LimitTrace = 10 ; Сколько шагов в обе стороны от начальной точки обхода прекращают ходилку (выхода нет).
var Speed = 3 ; Сколько шагов делать за раз между проверками.
var DynamicPause = 50 ; Минимальные паузы в циклах. Чем меньше число - тем меньше рывков и тем больше нагрузка процессора.
var steptimer = 2 ; Таймер на шаг(Значение 1 = 100мс). Время за которое чар проходит 1 тайл, если за это время чар не сдвинется с места скрипт расценит это как препятствие и начнет обходить.

sub Walker(GoX, GoY, Prec)
   var LastDir
   var MoveRes
   var TracerCnt
   uo.setglobal("GlobalGoX", str(GoX))
   uo.setglobal("GlobalGoY", str(GoY))
   while not IsEnd(GoX,GoY,Prec)
      TracerCnt = MaxTraceDistance
      repeat
         LastDir=GoUntilHit(GoX,GoY,Prec)
         if IsEnd(GoX,GoY,Prec) then
            return 1
         end if
         MoveRes = FullAroundTrace(LastDir,GoX,GoY,Prec,TracerCnt)
         if TracerCnt > LimitTrace then
            return 0
         endif
         TracerCnt = TracerCnt + TraceLoopIncrease
      until MoveRes == 1
   wend
   return 1
end sub

sub FullAroundTrace(StartDir,GoX,GoY,Prec,MaxTrace)
   var LineX=UO.GetX()
   var LineY=UO.GetY()
   var CurDir=StartDir
   var Direction=CountDirection(GoX,GoY,CurDir,Prec)
   var StartX,StartY
   var MovesDone=0
   repeat
      StartX=UO.GetX()
      StartY=UO.GetY()
      CurDir=Tracer(CurDir,Direction,Prec)
      if (CurDir==GetDir(GoX,GoY,Prec)) then
         return 1
      endif
      if MovesDone>0 and PrevMoveCross(GetDirToDir(UO.GetDir(),Prec),LineX,LineY,GoX,GoY,StartX,StartY,Prec) then
         return 1
      end if
      MovesDone=MovesDone+1
      CurDir=AddToDir(CurDir,-Direction,Prec)
   until MovesDone>MaxTrace
   return 0
end sub

sub CountDirection(GoX,GoY,StartDir,Prec)
   var GoDir=GetDir(GoX,GoY,Prec)
   var MyX=UO.GetX()
   var MyY=UO.GetY()
   if GoDir<StartDir then
      return -1
   end if
   if GoDir>StartDir then
      return 1
   end if
   if Abs(MyX-GoX)>Abs(MyY-GoY) then
      if (GoDir==3) or (GoDir==7) then
         return -1
      else
         return 1
      end if
   else
      if (GoDir==1) or (GoDir==5) then
         return -1
      else
         return 1
      end if
   end if
end sub

sub PrevMoveCross(Dir,x1,y1,x2,y2,StartX,StartY,Prec)
   var x3,y3,x4,y4
   x3=StartX
   y3=StartY
   x4=StartX+(XFromDir(Dir)-StartX)*Speed
   y4=StartY+(YFromDir(Dir)-StartY)*Speed
   return LinesCrossing(x1,y1,x2,y2,x3,y3,x4,y4,Prec)
end sub

sub LinesCrossing(x1,y1,x2,y2,x3,y3,x4,y4,Prec)
   if x1==x3 and y1==y3 then
      return false
   end if
   var ua1=(x4-x3)*(y1-y3)-(y4-y3)*(x1-x3)
   var ub1=(y4-y3)*(x2-x1)-(x4-x3)*(y2-y1)
   var ua2=(x2-x1)*(y1-y3)-(y2-y1)*(x1-x3)
   var ub2=(y4-y3)*(x2-x1)-(x4-x3)*(y2-y1)
   #Check for parallel lines
   if (ub1 == 0) or (ub2 == 0) then
      return false
   end if
   var u1=ua1/ub1
   var u2=ua2/ub2
   if IsDiap(u1,0,1,0.01) and IsDiap(u2,0,1,0.01) then
      return true
   else
      return false
   end if
end sub

sub IsDiap(X,X0,X1,Prec)
   if X<=X0+Prec and X>=X1-Prec or X>=X0-Prec and X<=X1+Prec then
      return true
   end if
   return false
end sub

sub GoUntilHit(GoX,GoY,Prec)
   var LastDir
   LastDir=GetDir(GoX,GoY,Prec)
   var CouldMove
   repeat
      LastDir=GetDir(GoX,GoY,Prec)
      if LastDir<>0 and not IsEnd(GoX,GoY,Prec) then
         CouldMove=TurnAndGoDir(LastDir, Prec)
      end if
   until LastDir==0 or IsEnd(GoX,GoY,Prec) or not CouldMove
   return LastDir
end sub

sub IsEnd(GoX,GoY,Prec)
   if Abs(UO.GetX()-GoX)<=Prec and Abs(UO.GetY()-GoY)<=Prec then
      return true
   else
      return false
   end if
end sub

sub GetDir(GoX,GoY,Prec)
   var MyX=UO.GetX()
   var MyY=UO.GetY()
   var DiffX=Abs(UO.GetX()-GoX)
   var DiffY=Abs(UO.GetY()-GoY)
   var GoDir=0
   if (DiffX/(DiffY+0.1))>=2 then
      if (MyX>GoX) then
         GoDir=7
      else
         GoDir=3
      end if
   else
      if (DiffY/(DiffX+0.1))>=2 then
         if (MyY>GoY) then
            GoDir=5
         else
            GoDir=1
         end if
      else
         if (MyX>GoX) and (MyY>GoY) then
            GoDir=6
         else
            if (MyX>GoX) and (MyY<GoY) then
               GoDir=8
            else
               if (MyX<GoX) and (MyY>GoY) then
                  GoDir=4
               else
                  if (MyX<GoX) and (MyY<GoY) then
                     GoDir=2
                  end if
               end if
            end if
         end if
      end if
   end if
   return GoDir
end sub

sub Tracer(StartDir,Direction,Prec)
   var CurDir=StartDir
   var Result
   repeat
      Result=TurnAndGoDir(CurDir, Prec)
      if not Result then
         CurDir=AddToDir(CurDir,Direction,Prec)
      end if
   until Result
   return Result
end sub

sub AddToDir(Dir,Cnt,Prec)
   var NewDir=Dir
   NewDir=NewDir+Cnt
   while NewDir>8
      NewDir=NewDir-8
   wend
   while NewDir<1
      NewDir=NewDir+8
   wend
   return NewDir
end sub

sub XFromDir(Dir)
   if Dir==2 or Dir==3 or Dir==4 then
      return (UO.GetX() + 1)
   end if
   if Dir==6 or Dir==7 or Dir==8 then
      return (UO.GetX() - 1)
   end if
   return (UO.GetX())
end sub

sub YFromDir(Dir)
   if Dir==8 or Dir==1 or Dir==2 then
      return (UO.GetY() + 1)
   end if
   if Dir==4 or Dir==5 or Dir==6 then
      return (UO.GetY() - 1)
   end if
   return (UO.GetY())
end sub

sub TurnAndGoDir(Dir, Prec)
   var StartDir=GetDirToDir(UO.GetDir(), Prec), StartX=UO.GetX(), StartY=UO.GetY(), EndDir, timer
   #Start Primary test
   if GoDir(Dir, Prec) then
      return Dir
   else
      return 0
   end if
end sub

sub GetDirToDir(GotDir,Prec)
   var ChangedDir=-GotDir
   ChangedDir=AddToDir(ChangedDir,5,Prec)
   return ChangedDir
end sub

sub GoDir(Dir, Prec)
   var circle, StartDir=GetDirToDir(UO.GetDir(), Prec), StartX=UO.GetX(), StartY=UO.GetY(), EndDir, timer
   dim Dirs[9]
   Dirs[1]=35
   Dirs[2]=40
   Dirs[3]=34
   Dirs[4]=39
   Dirs[5]=33
   Dirs[6]=38
   Dirs[7]=36
   Dirs[8]=37
   var DistanceX=Abs(UO.GetX()-val(UO.GetGlobal("GlobalGoX")))
   var DistanceY=Abs(UO.GetY()-val(UO.GetGlobal("GlobalGoY")))
   var GoDistance
   if (DistanceX - Prec) < Speed and (DistanceX - Prec) > (DistanceY - Prec) then
      GoDistance=DistanceX - Prec
   else
      if (DistanceY - Prec) < Speed and (DistanceY - Prec) > (DistanceX - Prec) then
         GoDistance=DistanceY - Prec
      else
         GoDistance=Speed
      end if
   end if
   circle = 0
   repeat
      UO.Press(Dirs[Dir])
      timer = uo.timer() + steptimer
      repeat
         EndDir=GetDirToDir(UO.GetDir(), Prec)
         wait(DynamicPause)
      until StartDir<>EndDir or StartY<>UO.GetY() or StartX<>UO.GetX() or timer <= uo.timer()
      if StartDir<>EndDir then
         GoDistance = GoDistance + 1
         StartDir = EndDir
      end if
      circle = circle + 1
   until circle == GoDistance or GoDistance == 0 or timer <= uo.timer()
   if timer <= uo.timer() then
      return false
   else
      return true
   end if
end sub

sub Abs(X)
   if X>0 then
      return X
   else
      return ( - X)
   end if
end sub

sub Reconnector() 
   var ReconnectTime, RFlag 
   ReconnectTime = '0' 
   RFlag = 1 
   Repeat 
      While (UO.ObjAtLayer('Bpack') == '') 
         If RFlag Then 
            ReconnectTime = MakeTime() 
            RFlag = 0 
         endif 
         Wait(20000) # WorldSave Protection 
         UO.Say('') 
         Wait(3000) 
         UO.Say('') 
         Wait(3000) 
         UO.Say('') 
         Wait(3000) 
         UO.LDblClick(357,164) 
         UO.LClick(616,459) 
         Wait(3000)        
      Wend
      Wait(3000) 
      If (RFlag == 0) and (ReconnectTime <> '0') Then 
         
         uo.TextOpen() 
         uo.TextPrint('Disconnected & Reconnected @ '+ReconnectTime) 
         RFlag = 1 
         ReconnectTime = '0' 
      End If 
   Until false 
end sub 

sub MakeTime() 
   VAR D, T, Ret, i 
   Ret = STR(UO.Time()) 
   T = "" 
   For i = 0 To Len(Ret) 
      T = Ret[Len(Ret)-i] + T 
      If (I == 2) OR (I == 4) Then 
         T = ":" + T 
      EndIf 
   Next 
   Ret = STR(UO.Date()) 
   D = "" 
   For i = 0 To Len(Ret) 
      D = Ret[Len(Ret)-i] + D 
      If (I == 2) OR (I == 4) Then 
         D = "." + D 
      EndIf 
   Next    
   Ret = T + " @ " + D 
   RETURN Ret 
end sub

sub TerminateAll()
   uo.Exec('Terminate All')
End Sub