#####################################################################
#                           Настройка                               # 
#                                                                   #
# Все до ужаса просто, просмотрите скрипт, впишите  переменные, где #
# требуется. Скрипт только для друзей, цените это.                  #
# И не забудьте в инжекте создать список покупки с именем "list".   #
# Желательно, я настаиваю, включить TWI, так намного эффективнее    #
#                                                                   #
#                 QuestionGimFlex love you all                      #
#####################################################################

sub POGNALI()
dim book[4]
 book[1]='0x40361D1B' ; <--- тип первой рунбуки к вендорам
 book[2]='0x400FFC52' ; <--- тип второй рунбуки к вендорам
 book[3]='0x400F76CD' ; <--- тип третьей рунбуки, 1 руна домой, к сэйфам
var i,j
uo.set('buydelay','3000') ; <--- время покупки, увеличте если не скупает
while not uo.dead()
 for i=1 to 2
  for j=1 to 9
   port(j,book[i])
   uo.resend()
   bustreevseh() 
  next
 next 
 port(1,book[3])
 ToHide()
 unload1()
 unload2()
 zadergka()
wend
endsub

sub unload1()
###################################################################
# Данная функция выкладывает вещи, которые складываются в кучку.  #
# Типов предметов может быть сколько угодно, главное не забудьте  #
# поменять переменную n, она равна числу предметов, а также не    #
# забудьте добавить или удалить в массив предметов dim type[n]    #
# соответствующий предмет                                         #
###################################################################

var seif='0x4013E74C' ; <--- сундук, в который выкладываем покупку
var n=3 ; <--- число типов предметов, равно размерности массива (ниже)

dim type[30]
 type[0]='0x0E34' 
 type[1]='0x0F7B' ; <--- массив типов предметов
 type[2]='0x0F84'
 
var i
for i=0 to n-1
 uo.findtype(type[i],'-1','backpack')
 while uo.findcount()
  uo.moveitem('finditem','all',seif)
  wait(700)
  CheckLag()
  uo.findtype(type[i],'-1','backpack')
 wend
next 
end sub

sub unload2()
#####################################################################
# Данная функция выкладывает вещи, которые не складываются в кучку, #
# например бланк мэпы, заведите под это дело лучше отдельный сэйф,  #
# далее положите в него пустые мешки одного типа, штук 10 хватит,   #
# хотя можно и больше (максимум 255), но зачем.                     #
#####################################################################

var cont='0x4013E31B' ; <--- сундук, в который выкладываем покупку
var map='0x1F14' ; <--- тип предмета (например бланк мэпа)
var mesh='0x0E76' ; <--- тип мешков, лежащих в сундуке

var sm,fl=1,kol
uo.ignorereset()
uo.useobject(cont)
wait(500)
uo.findtype(map,'-1','backpack')
while uo.findcount()
   fl=1
   uo.findtype(mesh,'-1',cont)
   sm=uo.getserial('finditem')
   uo.useobject(sm)
   wait(500)
   uo.findtype(map,'-1',sm)
   while fl<>0
    uo.findtype(map,'-1','backpack')
    if not uo.findcount() then
     fl=0
    endif
    uo.findtype(map,'-1',sm)
    kol=uo.findcount()
    if kol<250 then
      uo.findtype(map,'-1','backpack')
      if uo.findcount() then
       uo.moveitem('finditem','1',sm)
       wait(700)
       CheckLag()
      endif 
     else
      fl=0
      uo.ignore(sm)
    endif
   wend 
   uo.findtype(map,'-1','backpack')
wend   
endsub 

Sub bustreevseh()
####################################################################
# Данная функция, важна только одним, - нужно правильно указать    #
# переменную radiys. Она отвечает за размер поиска вендора, если   #
# слишком большой (максимум 14), то персонаж может найти вендора   #
# за пределами магазина и тупа туда пытаться пройти, если слишком  #
# маленький радиус, то он просто не найдет вендора и улетит не     #
# закупившись, поэтому мой вам совет - это золотая середина 6-8.   #
####################################################################

var radiys='7' ; <--- радиус поиска 

var i,name,lop
dim vend[2]
 vend[0]='0x0190'
 vend[1]='0x0191'
uo.set('finddistance',radiys)
uo.ignore('self')
for i=0 to 1
 uo.resend()
 uo.findtype(vend[i],'-1','ground')
 while uo.findcount()
  uo.click('finditem')
  wait(1000)
  name=uo.getname('finditem')
  lop=0
  while lop<>1
   lop=1
   go(uo.getx('finditem'),uo.gety('finditem'))
   uo.resend()
  wend  
  uo.buy('list',name)
  uo.ignore('finditem')
  uo.resend()
  uo.findtype(vend[i],'-1','ground')
 wend
next
uo.ignorereset()
endsub

Sub zadergka()
var time=60 ; <--- сколько секунд ждать до очередного облета
var t=0
while t<time
 wait(1000)
 t=t+1
 uo.print("ostalos gdat "+str(time-t)+" secynd")
wend
endsub

########################### дальше смотреть не надо #############################

Sub ToHide()
while not UO.Hidden()
 uo.deletejournal()
 UO.UseSkill("Hiding")
 wait(4100)
wend
end sub

Sub port(n,book)
var oldX=UO.GetX()
var oldY=UO.GetY()
var time
NoTarget()
UO.UseObject(book)
FastLootCheck()
CheckLag()
UO.LClick(135, n*15+55)
time=UO.Timer()
Repeat
 wait(500)
Until oldX<>UO.GetX() OR oldY<>UO.GetY() OR time+200<UO.Timer()
end sub

Sub FastLootCheck()
UO.DeleteJournal()
wait(600)
if UO.InJournal("FastLoot") OR UO.InJournal("World save") then
 CheckLag()
endif
end sub

Sub NoTarget()
if UO.Waiting() then
 UO.CancelTarget()
endif
end sub

Sub CheckLag()
uo.DeleteJournal()
uo.Click('backpack')
repeat
 wait(50)
until UO.InJournal('backpack')
endsub

Sub go(x,y)
var myX,myY,lastX=0,lastY=0,i,halt=0,z,r=0
for i=0 to 5
 MyX=uo.getX();
 MyY=uo.getY();
 if abs(x-myX)<=1 AND abs(y-myY)<=1 then
  return
 end if
 if x<=MyX then
  if y<=MyY then
    for z=0 to 4
     uo.press(38)
    next
   else
    for z=0 to 4
     uo.press(37)
    next
  end if
 else
  if y<=MyY then
   for z=0 to 4
    uo.press(39)
   next
  else
   for z=0 to 4
    uo.press(40)
   next
  end if
 end if
 lastX=myX
 lastY=myY
 wait(100)
next
end sub

Sub abs(num)
if num>=0 then
return num
else
return num*(-1)
end if
end sub