Yoko

All sides of Injection
It is currently 2024-03-29 15:30:35

All times are UTC+02:00




Post new topic  Reply to topic  [ 23 posts ]  Go to page 1 2 Next
Author Message
PostPosted: 2012-11-05 01:12:18 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Нашел тут скриптец ВЕТЕРАНа:
Code:
############################################ 
### Manning / Шахтер v2.3 ###
############################################
### Шард Dragon World / www.drw.ru
############################################
### Реавтор этого скрипта: BETEP [WOD] or BETEPAH ###
############################################
###                    BETEP™
#############################
### Описание и настройка ###
#############################
###
### Чар стоит в пещере(не ВИП) и копает вокруг себя.После достижения "максимального" веса (в данном случие это 625 стоунов)
### "порталится" домой скидывает руду в сундук,после реколится обратно и продолжает копать.
### Пример: стоите копаете, дошли до придела в 625 веса сработала система рекола
### и вы "порталитесь" домой и складываете руду в сундук,после вы реколитесь обратно в пещеру.И продолжаете копать
### (Цикличность)
###
### Для тех то кто им пользуется сообщаю, переделал, доработал, отредактировал.!
###
### Нововведения:
### 1 )Руда складываются не на пол а в сундук. (BETEPAH)
### 2 )Рекол в пещеру и домой по РУНБУКЕ (а не по рункам). (BETEPAH)
###     ВНИМАНИЕ!!! В СКРИПТЕ РУНБУКИ НАСТРОЕНЫ ПОД DRW (шард)
### 3 )Система сброса руды переделана из MassMove(что в свою очередь иногда приписывалось как фаст лут)в перемещение через 
### Масив.(написана Savage, встроена BETEPAH)
### 4 )Упразнена система выбора "главных обьектов"(теперь просто указываем прицелом).(BETEPAH)
### 5 )Система реконекта (выложаная сверху),хорошо сочетается с этим скриптом. (Fox M)
###
### !!! Чтобы скрипт заработал ВНИМАТЕЛЬНО прочтите настройки.!!!!
###
###################################
### Режимы работы скрипта ###
###################################
### Режим - "Копание".###
###################################
###
### "sub maning()"
### Этот скрипт главный и отвечает за копание.
###
### Положите в суммку к себе Рунбук(с Рунами домой и в лес), Кирку (лопату),рунку к сундуку(по суте копия той что у вас
### в рунбуке).Идите в пещеру в котором вы хотите копать.Запустите Скрипт maning(),Инжект попросит вас указать кирку
### (появится прицел,прицелом на кирку которую вы с собой взяли),потом инжект попросит вас указать Рунбук(появится прицел,
### прицелом на Рунбук ) Внимание!!! В РУНБУКЕ РУНА В 1ом слоте ДОМОЙ,в 8ом В пещеру.
### ВНИМАНИЕ!!! В СКРИПТЕ НОМЕРА РУН В РУНБУКЕ НАСТРОЕНЫ ПОД DRW (шард). 
### Инжект сообщит вам что ('Прячемся..') тоесть чар уйдет в хайд. Чар автоматом возмет в руки кирку и начнет "окапаватся".
### Если выкопали Элементала то скрипт включит "серену" и встанет на паузу пока вы просто не скажите GO.(так как вы в хайде) 
### Если появился ПК то чар зареколится к сундуку (по рунке!! так как на ДРВ рекол через рунбук 8,7 сек,а по рунке 2,3 сек)
### выкинет руду в сундук и будет ждать определенное время которое вы поставите в скрипте.
###
### Чтобы все заработало !!в скрипте!! поставте свои значения:
### 1)wait(180000) -- время в секундах при ожидании пока уйдет ПК (строка 153).
### 2)if uo.weight > 814 then -- Максимальный вес при котором домой с рудой (строка 160).
###
###
##############################
### Режимы - "Супорт".###
##############################
### "loot()"
### Этот скрипт отвечает за сброс руды в сундук.
### После "рекола" домой чар при помощи этого скрипта сбросит руду в сундук (лучше в сейф).
### VAR UnloadCont='0x40557243' ; ID сундука для сброса руды <<<< поставте свой (строка 196).
### 
### "Save()"
### Скрипт "спасатель", отвечает за рекол по любой рунке у вас в паке + реги (включается если прешел ПК)
### будет пытатся реколится пока не "улетит" из пещеры (защита от физла).
###
### "pwav() и pwavw()"
### Скрипты "сирены" отвечают за проигрование Звуковых файлов (WAV) при выкапывании элема или поялении ПК
### uo.playwav("E:\UO\SOUND\sound 01.wav")<< укажите на примере этого путь к своим файлам (строчки 239 и 243).
###
### "Pause()"
### Скрипта пауза если выкопали Элема.
### Если вы выкопали Элема скрипт как бы "зависнет"(встанет на паузу) за это время вы можете убить элема,
### привратившись в Демона или привести Дракона.После просто скажите в игре GO и чар продолжит копать.
###
###################
### Патчи Вердаты: ###
###################
### Сдесь я приведу пару ссылок на патчи которые помогут вам копать:
###
### 1)cave floor (для тех кто предпочитает копать вручную, этот файл-патч отделяет тайлы в пещерах друг от друга,
### что приводит к более комфортабельному копанию)
### www.drguild.fatal.ru/files/verdata/cavefloor.exe
###
### 2)clean dungeons (в пещерах и подземельях не виден всякий мусор, как то: кости, мусор, большая паутина,
### все сталагмиты заменены на маленькие и т.д.)
### www.drguild.fatal.ru/files/verdata/cleandungeons.exe
###
### 3)ore mod (большое количество руды (больше 4 шт.) выглядит как маленькая кучка (3 шт.),
### а изображение руды в количестве одной и двух штук уменьшено)
### www.drguild.fatal.ru/files/verdata/ore.exe
###
### (все пачтчи проверены и протестены,Но скрипт работает и без них,так что ставить или нет - это ваше решение)
###
### Лично я копаю с ними.....удобно. Удачи и приятного Маннинга. ))
### ВЕТЕРАН ака BETEP [WOD]


sub maning()
#BETEP™#
DIM Other[5]
Other[0]='0x19B9' ; 4 and more ore
Other[1]='0x19B7' ; 1 ore
Other[2]='0x19BA' ; 2 ore
Other[3]='0x19B8' ; 3 ore
Other[4]='0x0EED' ; gold
var mx, my, mz, i, j, jor, ser, noto, p
Uo.exec("set norbcheck 1"); для рекола
uo.exec("set norbcalc 1"); тоже

uo.print('!!Выбери Лопату!! ')
uo.exec('addobject Shovel')
while uo.targeting()
wait(100)
wend
 
uo.print('!!Выбери Рунбук!! ')
uo.exec('addobject Runebook')
while uo.targeting()
wait(100)
wend

na4alo:
mx = UO.GetX("self")
my = UO.GetY("self")
mz = UO.GetZ("self")
UO.DeleteJournal()
for i = mx-4 to mx+4
for j = my -4 to my+4
while not UO.Hidden()
for p=0 To 4
UO.Set('finddistance',4)
uo.findtype(Other[p],-1,'ground')
if uo.findcount() then
uo.moveitem('finditem')
wait(850)
end if
next
UO.Warmode("0")
uo.print("Прячемся...")
UO.UseSkill("Hiding")
wait(4000)
wend
UO.Print("Копаем в координатах: "+str(mx-i)+" "+str(my-j))
while not UO.InJournal("no ore here") and not UO.InJournal("location") and not UO.InJournal("far away") and not UO.InJournal("in rock") and not UO.InJournal("Iron Ore") and not UO.InJournal("Copper") and not UO.InJournal("Rusty Ore")
UO.DeleteJournal()
if uo.waiting() then
uo.canceltarget()
endif
UO.Waittargettile("1341", str(i), str(j), str(mz))
UO.Useobject("Shovel")
while not UO.InJournal("You put") and not UO.InJournal("heavy") and not UO.InJournal("location") and not UO.InJournal("no ore") and not UO.InJournal("but fail") and not UO.InJournal("far away") and not UO.InJournal("in rock")
wait (500)
if uo.injournal("heavy") or uo.dead() then
pwav()                   
Pause()
invis()
Vortex()
wait(4000)
endif
for jor = 0 to 9   
ser = uo.journalserial(jor)
noto = uo.getnotoriety(ser)
if noto <> 0 and not uo.injournal("Vortex") and not uo.injournal("Elemental") and not uo.injournal("Alexy") and not uo.injournal("Blad") and not uo.injournal("Vertijok") and not uo.injournal("Longo") and not uo.injournal("Userboy") and not uo.injournal("Panfike[Ofs]") and not uo.injournal("Blood Merry") and not uo.injournal("Kefir") and not uo.injournal("Koviryalko")and not uo.injournal("Resingun") and not uo.injournal("Insulin") and not uo.injournal("Uzver") and not uo.injournal("Dark Angels") and not uo.injournal("Gray") and not uo.injournal("Marc Johnson") and not uo.injournal("Ubiica")  and not uo.injournal("Latouche") and not uo.injournal("Lat") and not uo.injournal("Mracha") and not uo.injournal("Sonya Lady") and not uo.injournal("Nagibator") and not uo.injournal("Corben Dallas") and not uo.injournal("Lets Dig") and not uo.injournal("Drmoon") and not uo.injournal("Pro Miner") and not uo.injournal("Robertino") and not uo.injournal("Mr Awik") and not uo.injournal("Blassed") and not uo.injournal("Xahopuk") and not uo.injournal("Gunter") and not uo.injournal("Pikabyy") and not uo.injournal("Tony Mantana") and not uo.injournal("Tazo") and not uo.injournal("Maxoniahson") and not uo.injournal("asd") and not uo.injournal("Mr Awik") and not uo.injournal("Terricks") and not uo.injournal("Pruha") and not uo.injournal("Lord Wendigo") and not uo.injournal("Oubotsochi") and not uo.injournal("Vas Beast") and not uo.injournal("Lord Vas Beast") and not uo.injournal("Leshka") and not uo.injournal("Gorlum") and not uo.injournal("Hatake Kakashi") and not uo.injournal("Ginger Man") and not uo.injournal("Narkoxron") then
if uo.waiting() then
uo.canceltarget()
endif
pwavw()
invis()
recoli()
wait(300000) ; время в секундах при ожидании пока уйдет ПК
goto reccal
endif
next   
wend
if uo.weight > 500 then  ; Максимальный вес при котором домой с рудой
goto end
endif
wend
UO.DeleteJournal()
next
next
goto na4alo
end:
if uo.waiting() then
uo.canceltarget()
endif
UO.WaitTargetType('0x1F16')
UO.Cast('Recall')
wait(10000)
while not UO.Hidden()
UO.Warmode("0")
uo.print("Прячемся...")
UO.UseSkill("Hiding")
wait(4000)
wend
loot()
wait(3000)
reccal:
uo.deletejournal()
if uo.waiting() then
uo.canceltarget()
endif
UO.WaitTargetType('0x1F14')
UO.Cast('Recall')
mx = UO.GetX("self")
my = UO.GetY("self")
wait(10000)
if not UO.GetX("self") <> mx and not UO.GetY("self") <> my then
goto reccal
endif
goto na4alo
end sub

sub loot()    ; перекладка руды в сундук
if uo.waiting() then
uo.canceltarget()
endif
VAR a,Exit
VAR UnloadCont='0x404BFD86' ; АЙДИ сундука для руды 
DIM Ore[5]
Ore[0]=0x19B9 ; 4 and more ore
Ore[1]=0x19B7 ; 1 ore
Ore[2]=0x19BA ; 2 ore
Ore[3]=0x19B8 ; 3 ore
UO.SetReceivingContainer(UnloadCont)
wait(500)
For a=0 to 3
Exit=0
repeat
UO.FindType(Ore[a])
if UO.GetQuantity('finditem')>0 then
UO.Grab('0','finditem')
wait(1500)
Else
Exit=1
endif
until Exit==1
Next
UO.UnSetReceivingContainer()
end sub

sub pwav() ; звук при выкапывании ЭЛЕМЕНТАЛА
UO.playwav("C:\Games\Ultima online\Injection\sc\Vacuum.wav")
endsub

sub pwavw(); звук при появлении ПК
uo.playwav("D:\enemy.wav")
endsub

sub Pause() ; Пауза скрипта если выкопали Элема (продолжить сказав GO )
cheklag()
WAIT(3000)
UO.Print("!!!СКРИПТ НА ПАУЗЕ!!!!")
end sub

sub invis()
   UO.UseType('0x0F0E','0x0631') ; inviz potion
end sub

sub Vortex()
   # убиваем элемента #
   Vortex:
   UO.WaitTargetSelf();
   UO.UseType('0x1F66');
   repeat
      wait(12000)
   until uo.injournal("fizzles") or uo.injournal("Vortex")
   if uo.injournal("fizzles") then
      goto Vortex
   else
                   wait(15000)
      vasanort:
      UO.WaitTargetSelf();
      UO.UseType('0x1F62');
      wait(7000)
      if uo.injournal("fizzles") then
         goto vasanort
      endif
# собираем руду и копаем дальше #
      UO.SetReceivingContainer('backpack')
      UO.FindType('0x19B9',-1,'ground')
      if UO.GetQuantity('finditem')>0 then
         UO.Grab('0','finditem')
         wait(2000)
      endif
      UO.FindType('0x19B7',-1,'ground')
                   if UO.GetQuantity('finditem')>0 then
               UO.Grab('0','finditem')
               wait(2000)
      endif
      UO.FindType('0x19BA',-1,'ground')
      if UO.GetQuantity('finditem')>0 then
         UO.Grab('0','finditem')
         wait(2000)
      endif
      UO.FindType('0x19B8',-1,'ground')
      if UO.GetQuantity('finditem')>0 then
         UO.Grab('0','finditem')
         wait(2000)
      endif
      UO.UnSetReceivingContainer()
   endif
endif
end sub

sub cheklag()
uo.deletejournal()
uo.click('backpack')
Repeat
wait(100)
Until UO.InJournal("backpack")
end sub

sub recoli()
if uo.waiting() then
uo.canceltarget()
endif
UO.WaitTargetType('0x1F16')
UO.Cast('Recall')
wait(10000)
while not UO.Hidden()
UO.Warmode("0")
uo.print("Прячемся...")
UO.UseSkill("Hiding")
wait(4000)
wend
loot()
wait (3000)
endsub

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-05 01:19:21 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Или вот такой вот он же Enemyвский:
Code:
# 23.11.2009 
# 1# Mining Elemental hunter by Nmy a.k.a. Dark Enemy
# Суть скрипта - мининг по рункам. Запускать надо только sub main(). Нечего другого.
# Если чар жив, при запуске надо иметь в бекпаке руну к сундуку,
# если чар мертв, тогда просто запускайте скрипт.
# После запуска скрипт ищет кирку или лопату - автоматически.
# Требования перед запуском - реги bp bm mr ns ga в сундуке,
# бланк руны в мешке BlankRunebag,
# замарченые руны в Runebag (Чем больше, тем лучше. У меня где то 59 спотов),
# руна домой Runehome, прямо у сундука,
# инвизки в сундуке для рекола от пк и фарма елемов,
# скролы на Energy Vortex для фарма елемов,
# куча кирок в сундуке.
# При запуске чар должен иметь готовую руну домой в бекпаке. Других рун в бекпаке не должно быть.
##
# Запускается скрипт у сундука и записывается руна домой.
# Скрипт берет реги, 2 инвизки, скрол вортекса, если надо, кирку и улетает.
# Начинается копка. Через каждый тайл идет проверка на елема,
# если елем выха, плут или обсид - убивает елема, Vas An Ort, лутает руду, улетает, выгружается, берет руну в следующею шахту,
# Тщательно проверяется журнал на пк, исключая ('Elemental|Scorpion King|Giant Spider|Energy Vortex').
# Улетает от пк - пьет инвизку и делает рекол по рунбуке или руне,
# открываетcя окно текста TextOpen и пишется Nick @ время @ дата, например:
# Roland @ 15:59:20 @ 9.09.18
##
# Track World Items должен быть включен.
# Reconnector - включается, он просто заходит обратно, нет гарантии что скрипт будет дальше работать,
# но шанс на успех все таки есть.
##
# Добавлен ресс в Миноке. Чар ресается, летит домой, маркает руну домой, ищет кирку в сундуке, запускает мейн скрипт.
# Добавлены переменные для хелп кнопки, т.к. папердолл у каждого может быть в разных местах.
# Undead надо включить.
##
# Чар медитирует фулл ману перед реколом в шахту.
var Pickaxe, Runehome, Blankrune, Runinetu, Nrune, flagpk
var Runebook='0x403A779E' # Для рекола домой.
var Runenr='46' # Номер руны.
var Chest='0x403DDE5C' # Я лично поставил 2 сейфа рядом - 1 для ресурсов, 2й для руды.
var Orechest='0x404BE1AE' # Сюда кидают руду.
var Dropbag='0x400F04AB' # Пустой мешок куда кидают руны после обкопа.
var Runebag='0x402C79CB' # Руны куда лететь.
var Blankrunebag='0x4006A346' # Мешок с бланк рунами.
var rune='0x1F14' # Тип руны.
var homeX=1520 # Координаты где стоит чар у сундука.
var homeY=205 # Координаты где стоит чар у сундука.
var helpX=1398 # Переменные без кавычек!
var helpY=53 # Переменные без кавычек!
var recallrunebook=0 # Улетает от пк по рунбуке или по руне. 1-рунбук, 0-руна.
var food='0x09BB' # Тип еды. Будет брать по 2 и кушать.
sub main()
   var markflag
   uo.exec('exec Reconnector')
   if not uo.getglobal('flagRes')=='1' then
      uo.exec('exec Resurrector')
      uo.setglobal('flagRes','1')
   endif
   wait(1000)   
   uo.print('Dont forget track world items!')
   uo.findtype(rune,-1,'backpack')
   if uo.findcount() then
      Runehome=uo.getserial('finditem')
   else
      uo.print('Runehome not found! Terminate.')
      uo.exec('terminate all')
   endif
   Open(Chest)
   GrabBlankRune()
   while not uo.dead()
      Open(Runebag)
      uo.findtype(rune,-1,Runebag)
      while uo.findcount()
         uo.print('Медитируем')
         meditation(uo.int)
         Nrune=uo.getserial('finditem')
         uo.moveitem(Nrune,0,Dropbag)
         checklag()
         wait(700)
         RegCheck()
         RegCheck()
         grabinvis()
         GetPickaxe()
         grabvortex()
         toeat()
         RecallRune(Nrune)
         uo.ignorereset()
         markflag=0
         flagpk=0
         checkifelem()
         if uo.injournal('is attacking you') then
            uo.warmode(0)
            invis()
         endif
         if uo.injournal('The recall rune fades completely.') then
            markflag=1
            Mark(Blankrune,0)
            Runinetu=1
         endif
         mining()
         checkifelem()
         if not flagpk==1 then
            repeat
               RecallRune(Runehome)
            until uo.getx('self')==homeX && uo.getY('self')==homeY
         endif
         if uo.injournal('The recall rune fades completely.') then
            Open(Chest)
            if Runinetu==1 then
               GrabBlankRune()
            endif
            Mark(Blankrune,1)
            GrabBlankRune()
         endif
         Open(Chest)
         if Runinetu==1 then
            GrabBlankRune()
         endif
         if markflag==1 then
            uo.moveitem(Nrune,0,Dropbag)
            checklag()
            wait(700)
         endif
         Dropore()
         if flagpk==1 then
            uo.print(' ждем 100 секунд ')
            wait(100000)
         endif
         Open(Runebag)
         uo.findtype(rune,-1,Runebag)
      wend
      DropbagCheck()
   wend
endsub
sub Resurrector()
   var oldX,oldY
   while 1
      if uo.dead() then
         uo.exec('terminate main')
         uo.exec('terminate Reconnector')
         uo.TextOpen()
         uo.TextPrint('- dead - @ '+MakeTime())
         wait(5000)
         oldX = Uo.GetX()
         oldY = Uo.GetY()
         uo.useobject('self')
         checklag()
         wait(700)
         repeat
            uo.lclick(helpX,helpY)
            checklag()
            wait(700)
            uo.lclick(264,308)
            checklag()
            wait(700)     
            uo.lclick(175,203)
            checklag()
            wait(5000)   
         until oldX<>UO.GetX() OR oldY<>UO.GetY()
         repeat
            uo.press(39)
            wait(2000)
         until UO.GetY()<534
         repeat
            uo.useobject('0x4001BDF0')
            wait(3000)
         until uo.life>0
         Open(uo.getserial('backpack'))
         wait(100000)
         oldX = Uo.GetX()
         oldY = Uo.GetY()         
         uo.recall(Runebook,Runenr)
         repeat
            wait(700)
         until oldX<>uo.getx('self') && oldY<>uo.gety('self')
         Open(Chest)
         RegCheck()
         GrabBlankRune()
         Mark(Blankrune,1)
         if uo.waiting() then
            uo.canceltarget()
         endif
         uo.exec('exec main')
      endif
      wait(5000)
   wend
endsub
sub checkifelem()
   uo.ignorereset()
   uo.findtype('0x0010',-1,'ground')
   if uo.findcount() then
      invis()
   endif
endsub
sub GetPickaxe()
   var n
   dim instrument[4]
   instrument[1]='0x0F39'
   instrument[2]='0x0F3A'
   instrument[3]='0x0E86'
   instrument[4]='0x0E85'
   if uo.count('0x0F39')==0 and uo.count('0x0F3A')==0 and uo.count('0x0E86')==0 and uo.count('0x0E85')==0 then
      for n=1 to 4
         uo.findtype(instrument[n],-1,Chest)
         if uo.findcount() then
            pickaxe=uo.getserial('finditem')
            uo.moveitem('finditem',0,'backpack')
            checklag()
            wait(700)
            return
         endif
      next
   else
      for n=1 to 4
         uo.findtype(instrument[n],-1,'my')
         if uo.findcount() then
            pickaxe=uo.getserial('finditem')
            return
         endif
      next   
   endif
   while 1
      uo.print(' pickaxe not found ')
      wait(3000)
   wend
endsub
sub Tohide()
   while not uo.Hidden()
      uo.warmode(0)
      uo.Print('Пытаемся уйти в хайд...')
      uo.UseSkill('Hiding')
      wait(4000)
   wend
end sub
sub checkelem()
   var n
   var flagvortex, Elemental, flaginvis
   Dim ore[2]
   ore[1]='0x19B8'
   ore[2]='0x19B9'
   uo.set('finddistance','3')
   uo.findtype('0x0010',-1,'ground')
   while uo.findcount()
      Elemental=uo.getserial('finditem')
      if checkcolor(Elemental)==1 then
         flagvortex=1
         if not flaginvis==1 then
            invis()
            flaginvis=1
         endif
         castvortex()
         uo.textopen()
         uo.textprint(uo.getname(Elemental)+' @ '+MakeTime())
         for n=0 to 15
            wait(1000)
            checkpk()
            if flagpk==1 then
               return
            endif
         next
      else
         uo.ignore(Elemental)
      endif
      uo.findtype('0x0010',-1,'ground')
   wend
   if flagvortex==1 then
      repeat
         checklag()
         while uo.mana<22
            wait(500)
         wend
         uo.waittargetobject('self')
         uo.cast('Mass Dispel')
         WaitForMana()
         wait(1000)
      until not uo.injournal('The spell fizzles')
      for n=1 to 2
         uo.findtype(ore[n],-1,'ground')
         while uo.findcount()
            uo.moveitem('finditem',-1,'backpack')
            checklag()
            wait(700)
            uo.findtype(ore[n],-1,'ground')
         wend
      next
      return 1
   endif
endsub
sub checkcolor(obj)
   var n, c
   Dim color[14]
   color[1]='0x09DA' ; vulcan
   color[2]='0x0060' ; aqua
   color[3]='0x0BA7' ; eldar
   color[4]='0x09E6' ; elvin
   color[5]='0x09B9' ; acid
   color[6]='0x09D3' ; steel
   color[7]='0x008F' ; sand rock
   color[8]='0x09EC' ; blood crest
   color[9]='0x09F0' ; gorgan
   color[10]='0x010F' ; krynite
   color[11]='0x09A4' ; crystaline
   color[12]='0x0085' ; dragon
   color[13]='0x08AF' ; plutonium
   color[14]='0x0028' ; obsidian
   c=uo.getcolor(obj)
   for n=1 to 14
      if c == color[n] then
         return 1
      endif
   next
endsub
sub castvortex()
   repeat
      checklag()
      uo.waittargettile('1341',str(uo.getx()),str(uo.gety()),str(uo.getz()))
      uo.resend()
      uo.findtype('0x1F66',-1,'backpack')
      if uo.findcount() then
         while uo.mana<13
            wait(500)
         wend
         uo.useobject('finditem')
      else
         while uo.mana<27
            wait(500)
         wend
         uo.cast('Energy Vortex')
      endif
      WaitForMana()
   until not uo.injournal('The spell fizzles')
endsub
sub WaitForMana()
   VAR w,m
   m=uo.mana
   for w=0 to 100
      if uo.mana<m then
         return
      endif
      if uo.injournal('is attacking you') then
         checklag()
         invis()
      endif
      wait(200)
   next
endsub
sub grabvortex()
   var kol=1, q
   uo.findtype('0x1F66',-1,'backpack')
   if uo.getquantity('finditem')<kol then
      q=kol-uo.getquantity('finditem')
      uo.print('Ищем вортекс')
      uo.findtype('0x1F66',-1,Chest)
      if uo.findcount() then
         uo.moveitem('finditem',STR(q),'backpack')
         checklag()
         wait(700)
      endif
   endif
endsub
sub toeat()
   repeat
      uo.findtype(food,-1,Chest)
      if uo.findcount() then
         uo.moveitem('finditem','2','backpack')
         checklag()
         wait(600)
         repeat
            uo.usetype(food)
            wait(500)
         until uo.injournal('full to eat') or uo.count(food)==0
      endif
   until uo.injournal('full to eat')
   uo.findtype(food,-1,'backpack')
   if uo.findcount() then
      uo.moveitem('finditem',0,Chest)
      checklag()
      wait(600)
   endif   
endsub
sub Open(what)
   uo.useobject(what)
   checklag()
   wait(700)
endsub
sub Dropore()
   var n
   Dim ore[5]
   ore[0]='0x19BA'
   ore[1]='0x19B7'
   ore[2]='0x19B8'
   ore[3]='0x19B9'
   ore[4]='0x0F10'
   uo.warmode(0)
   uo.useskill('Hiding')
   for n=0 to 4
      uo.findtype(ore[n],-1,'backpack')
      while uo.findcount()
         uo.moveitem('finditem',0,Orechest)
         checklag()
         wait(700)
         uo.findtype(ore[n],-1,'backpack')
      wend
   next
   uo.print('Dropore done.')
endsub
sub Mark(RuneID,Place)
   repeat
      meditation(33)
      checklag()
      Uo.Cast('Mark',RuneID)
      WaitForMana()
      wait(300)
   until not uo.injournal('The spell fizzles')
   if Place==0 then
      Nrune=uo.getserial(RuneID)
   else
      Runehome=uo.getserial(RuneID)
   endif
endsub
sub meditation(mn)
   uo.warmode(0)
   while uo.mana < mn
      if uo.mana==uo.int then
         return
      endif
      checklag()
      uo.Useskill('Meditation')
      waitformed(mn)
      wait(1000)
   wend
endsub
sub waitformed(mn)
   var n
   for n=0 to 100
      if uo.injournal('You lose|You are at peace') or uo.mana>=mn then
         return
      endif
      wait(500)
   next
endsub
sub RecallRune(nowrune)
   uo.Print('улетаем по руне')
   var oldX,oldY
   oldX = Uo.GetX()
   oldY = Uo.GetY()
   repeat
      meditation(20)
      checklag()
      Uo.Cast('Recall',nowrune)
      WaitForMana()
      wait(1000)
   Until oldX<>UO.GetX() AND oldY<>UO.GetY()
endsub
sub grabinvis()
   uo.findtype('0x0F0E',-1,'backpack')
   while uo.findcount()
      uo.moveitem('finditem',0,Chest)
      checklag()
      wait(700)
      uo.findtype('0x0F0E',-1,'backpack')
   wend
   uo.findtype('0x0F0E','0x0631',Chest)
   if uo.findcount() then
      uo.print('Ищем инвизку')
      uo.moveitem('finditem','2','backpack')
      checklag()
      wait(700)
   endif
endsub
sub RegCheck()
   VAR i,q
   VAR kol=9
   Dim Regs[6]
   Regs[0]='0x0F7A'      ; Black Pearl
   Regs[1]='0x0F7B'      ; Bood Moss
   Regs[2]='0x0F86'      ; Mandrake Root
   Regs[3]='0x0F88'     ; Nightshade
   Regs[4]='0x0F8C'     ; Sulfurous Ash
   Regs[5]='0x0F84'     ; Garlic
   
   for i=0 to 5
      if uo.count(Regs[i])<>kol then
         q=kol-uo.count(Regs[i])
         if q<>0 then
            if q>0 then
               uo.findtype(Regs[i],-1,Chest)
               if uo.findcount() then
                  uo.moveitem('finditem',STR(q),'backpack')
                  checklag()
                  wait(700)
                  uo.print('Берем реги для рекола...')
               else
                  uo.print('No regs')
                  return
               endif
            else
               q=q*-1           
               uo.findtype(Regs[i],-1,'my')   
               if uo.findcount() then
                  uo.moveitem('finditem',STR(q),Chest)
                  checklag()
                  wait(700)
                  uo.print('Регов больше чем надо. Кидаем лишнее в сундук')
               endif
            endif
         endif
      endif
   next
endsub
sub GrabBlankRune()
   Open(BlankRunebag)
   uo.findtype(rune,-1,BlankRunebag)
   if uo.findcount() then
      Blankrune=uo.getserial('finditem')
      uo.moveitem('finditem',0,'backpack')
      checklag()
      wait(700)
      uo.print('Взяли бланк руну')
      Runinetu=0
   else
      uo.print('Бланк рун больше нету! Скрипт остановлен.')
      uo.exec('terminate all')
   endif
endsub
sub DropbagCheck()
   uo.print('Проверяем мешок Dropbag')
   Open(Dropbag)
   uo.findtype(rune,-1,Dropbag)
   while uo.findcount()
      uo.moveitem('finditem',0,Runebag)
      checklag()
      wait(700)
      uo.print('Нашли руну. Кладем их в сумку Runebag.')
      uo.findtype(Rune,-1,Dropbag)
   wend
endsub
sub mining()
   var mx, my, mz, i, j, f
   mx = UO.GetX('self')
   my = UO.GetY('self')
   mz = UO.GetZ('self')
   for i = mx-4 to mx+4
      for j = my -4 to my+4
         repeat
            if uo.count('0x0F39')==0 and uo.count('0x0F3A')==0 and uo.count('0x0E86')==0 and uo.count('0x0E85')==0 then
               return
            endif
            if uo.injournal('You loosen some rocks but fail') then
               wait(10000)
            endif
            Tohide()
            UO.Print('Копаем в координатах: '+str(mx-i)+' '+str(my-j))
            DigAhole(i,j,mz)
            if uo.injournal('You have been revealed') then
               uo.warmode(0)
               invis()
               return
            endif
            if flagpk==1 then
               return
            endif
         until not uo.injournal('You loosen some rocks but fail')
         if checkelem()==1 then
            return
         endif
      next
   next
endsub
sub DigAhole(i,j,mz)
   var f
   for f=0 to 10
      checklag()
      uo.waittargettile('1341',i,j,mz)
      uo.useobject(pickaxe)
      if waitforore()==1 then
         return
      endif
   next
endsub
sub waitforore()
   var n
   for n=0 to 50
      checkpk()
      if uo.injournal('no ore here|location|far away|in rock|You have been revealed') or flagpk==1 then
         return 1
      endif
      if uo.injournal('You put|heavy|but fail') then
         return
      endif
      wait(500)
   next
endsub
sub checkpk()
   var n
   var ser
   var noto
   var me=uo.getserial('self')
   for n=0 to 9
      ser=uo.journalserial(n)
      noto=uo.getnotoriety(ser)
      if not ser==me then
         if noto<>0 and noto<>1 and noto<>3 and not uo.injournal('Elemental|Scorpion King|Giant Spider|Energy Vortex') then
            uo.TextOpen()
            uo.TextPrint(uo.getname(ser)+' @ '+MakeTime())
            invis()
            if recallrunebook==1 then
               gohome()
            else
               RecallRune(Runehome)
            endif
            flagpk=1
            return
         endif
      endif
   next
endsub
sub gohome()
   var oldX=uo.getx('self')
   var oldY=uo.gety('self')
   uo.recall(Runebook,Runenr)
   repeat
      wait(700)
      if uo.injournal('You have been revealed') then
         checklag()
         invis()
      endif
   until oldX<>uo.getx('self') && oldY<>uo.gety('self')
endsub
sub invis()
   uo.usetype('0x0F0E','0x0631')
endsub
sub CheckLag()
   repeat
      UO.DeleteJournal()
      UO.Click('backpack')
   until backpack()==1
endsub
sub backpack()
   var n
   for n=0 to 200
      if uo.injournal('a backpack') then
         return 1
      endif
      wait(200)
   next
endsub
sub Reconnector()
   var ReconnectTime, RFlag
   ReconnectTime = '0'
   RFlag = 1
   Repeat
      While (UO.ObjAtLayer('Bpack') == '')
         if RFlag Then
            ReconnectTime = MakeTime()
            RFlag = 0
         endif
         Wait(1000)
         UO.Say('')
         Wait(3000)
         UO.Say('')
         Wait(3000)
         UO.Say('')
         Wait(3000)
         UO.LDblClick(357,164)
         UO.LClick(616,459)
         Wait(3000)
      WEnd
      Wait(3000)
      if (RFlag == 0) and (ReconnectTime <> '0') Then
         ;UO.Exec('terminate all')
         ;UO.Exec('exec autoload')
         UO.TextOpen()
         UO.TextPrint('Disconnected & Reconnected @ '+ReconnectTime)
         RFlag = 1
         ReconnectTime = '0'
      endif
   Until false
end sub
sub MakeTime()
   VAR D, T, Ret, i
   Ret = STR(UO.Time())
   T = ""
   For i = 0 To Len(Ret)
      T = Ret[Len(Ret)-i] + T
      If (I == 2) OR (I == 4) Then
         T = ":" + T
      EndIf
   Next
   Ret = STR(UO.Date())
   D = ""
   For i = 0 To Len(Ret)
      D = Ret[Len(Ret)-i] + D
      If (I == 2) OR (I == 4) Then
         D = "." + D
      EndIf
   Next
   Ret = T + " @ " + D
   RETURN Ret
end sub


Вопрос к Миражу, какой будет легче для меня с моими ошибками и праблами? В
Вопрос ко всем остальным: какой из них новее?

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-05 07:16:31 
Offline
User avatar

Joined: 2009-05-28 09:58:28
Posts: 2802
Location: Иваново
Визуально оба нормальные но Nmy поновее.
Если правильно настроишь но периодически все равно будет падать (раз в несколько часов возможно) - виноват TWI. Но без него скрипт не работоспособен.

_________________
Image
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"
Стрелялка для олдов.


Top
   
PostPosted: 2012-11-05 09:53:07 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
А ветра скрипт плох?

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-05 12:01:14 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Был на форуме стелса, где легче писать скрипты инжект или стелс?

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-05 14:18:00 
Offline
User avatar

Joined: 2009-03-21 10:03:06
Posts: 164
Location: Одесса-Мама
Если совсем нет опыта скриптования, то лучше начинай с хорошего, т.е. стелс. На данный момент, он самый функциональный и стабильный.

_________________
Спасибо всем, у кого учился!

Меня трудно найти, легко потерять, и невозможно забыть. Я - рабочий исходник!


Top
   
PostPosted: 2012-11-05 16:37:20 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Андрюха из Одессы wrote:
Если совсем нет опыта скриптования, то лучше начинай с хорошего, т.е. стелс. На данный момент, он самый функциональный и стабильный.

буду очень рад, если меня научат хотябы его настроить по дрв)

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-05 18:05:35 
Offline

Joined: 2011-06-11 19:54:23
Posts: 820
tylllkah wrote:
буду очень рад, если меня научат хотябы его настроить по дрв)


По теме инжи - для ДРВ могу скинуть свою модификацию инжекта, заточена именно под ДРВ, по функционалу более насыщена, чем стандартная и не крашит с ТВИ. Окна по 1-2 недели без краша стоят и без глюков)
Если заинтересует - пиши в ПМ аську/скуп.


Top
   
PostPosted: 2012-11-05 20:36:52 
Offline

Joined: 2012-03-13 15:09:30
Posts: 48
То что ты ищешь тут нету, тебе нужен скрипт что бы чар сам воскрешался брал кирку, складывал в сундук и не тупил несколько дней хотя бы, я сам тут искал долго, нашел но не тут, вернее купил на ДРВ, у одного торгаша, обошелся в 10 лямов, всего, окупился за 1 неделю, непрерывной работы двух чаров, если нужно пиши помогу, есть все рабочие скрипты на добычу руды и леса....
теперь ищу хороший скрипт на продажу, куда девать 100кк инготов :)


Top
   
PostPosted: 2012-11-06 00:41:47 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Тему пжл не клозить...
Мираж, у меня ошибка не в копке, а в 2 под скриптах, мне кажется если их добавить в мининг с началом типо if uo..... then control() и тоже самое с лопатами не даст ошибки!)))
И вот такой вопрос перевел лопату на тип, когда она ломается пишет: No Found Item как зделать чтоб он реагировал на эту фразу? Она системная вроде как...

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-06 01:33:57 
Offline
User avatar

Joined: 2009-03-21 10:03:06
Posts: 164
Location: Одесса-Мама
Лопата в руки не одевается, поэтому, если использовать её по-типу(при условии, что лопат больше чем одна), сломанная лопата заменится новой. Следует лишь указать сообщение о сломе(либо использовать проверку, перед каждой копкой), в секцию промежуточных сообщений. Почитай в учебниках, про repeat\until и посмотри примеры на форуме. Тут подобных примеров больше, чем ты можешь себе представить. Лишь бери и думай о реализации.

_________________
Спасибо всем, у кого учился!

Меня трудно найти, легко потерять, и невозможно забыть. Я - рабочий исходник!


Top
   
PostPosted: 2012-11-06 04:05:13 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Ты меня не правильно понял, зачем мне читать про то, что если даже это относится к моему вопросу то очень далеко находится, суть такова, я копаю час-два-три при этом летаю выкладываю руду и тут у меня на пол пути ломается лопата, чар в ступоре... Как можно добавить если в журнале он не реагирует на надпись но фаунд итем?

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-06 07:04:58 
Offline
User avatar

Joined: 2009-05-28 09:58:28
Posts: 2802
Location: Иваново
Вот по этому я и писал уже - перенеси все вары и константы в шапку всего скрипта. Если бы так сделал то проблема решилась добавлением 1 сообщения - "сломали" (как оно выглядит на шарде) и 1 типа на другой - кирки на лопату.

Визуально надо поменять:

Code:
sub DigAhole(i,j,mz)
   var f
   for f=0 to 10
      checklag()
      uo.waittargettile('1341',i,j,mz)
      uo.usetype(pickaxe)     ;   <-------
      if waitforore()==1 then
         return
      endif
   next
endsub

и соответственно поменять типы - в доборе и в копании. Там условия - если есть в паке инструмент - копаем. Это по скрипту Ветерана.
По Nmy: щаз он придет - отругаем :twisted:
Кстати если на шарде есть элементали и не снимается щит при использовании лопаты - копать лучше лопатой (имхо). Небольшая потеря веса и времени - что для бота не так смертельно как выживание в случае атаки.

_________________
Image
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"
Стрелялка для олдов.


Top
   
PostPosted: 2012-11-06 12:34:34 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Именно так и слелал, uo.usetype(shovel) но когда лопата лом, то пишет сообщение не как на uo.useobject(shovel) и через if ou.injournal('No Found Item') не реагирует...

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-06 12:41:35 
Offline

Joined: 2011-06-11 19:54:23
Posts: 820
If uo.count(slovel) then
Uo.usetype(slovel)
Else
Сломана
Endif


Top
   
PostPosted: 2012-11-06 12:54:05 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Вот! СПС джуси тогда скрипт будет выглядишь так:
Code:
sub maning() 
#BETEP™#
DIM Other[5]
Other[0]='0x19B9' ; 4 and more ore
Other[1]='0x19B7' ; 1 ore
Other[2]='0x19BA' ; 2 ore
Other[3]='0x19B8' ; 3 ore
Other[4]='0x0EED' ; gold
var mx, my, mz, i, j, jor, ser, noto, p
Uo.exec("set norbcheck 1"); для рекола
uo.exec("set norbcalc 1"); тоже

uo.print('!!Выбери Лопату!! ')
uo.exec('addobject Shovel')
while uo.targeting()
wait(100)
wend
 
uo.print('!!Выбери Рунбук!! ')
uo.exec('addobject Runebook')
while uo.targeting()
wait(100)
wend

na4alo:
mx = UO.GetX("self")
my = UO.GetY("self")
mz = UO.GetZ("self")
UO.DeleteJournal()
for i = mx-4 to mx+4
for j = my -4 to my+4
while not UO.Hidden()
for p=0 To 4
UO.Set('finddistance',4)
uo.findtype(Other[p],-1,'ground')
if uo.findcount() then
uo.moveitem('finditem')
wait(850)
end if
next
UO.Warmode("0")
uo.print("Прячемся...")
UO.UseSkill("Hiding")
wait(4000)
wend
UO.Print("Копаем в координатах: "+str(mx-i)+" "+str(my-j))
while not UO.InJournal("no ore here") and not UO.InJournal("location") and not UO.InJournal("far away") and not UO.InJournal("in rock") and not UO.InJournal("Iron Ore") and not UO.InJournal("Copper") and not UO.InJournal("Rusty Ore")
UO.DeleteJournal()
if uo.waiting() then
uo.canceltarget()
endif
UO.Waittargettile("1341", str(i), str(j), str(mz))
If uo.count(shovel) then
uo.usetype(shovel)
else
Bejimzalopatoy()
end if
while not UO.InJournal("You put") and not UO.InJournal("heavy") and not UO.InJournal("location") and not UO.InJournal("no ore") and not UO.InJournal("but fail") and not UO.InJournal("far away") and not UO.InJournal("in rock")
wait (500)

Если я все правильно понял вставка для Ветеранского скрипта

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-06 13:06:05 
Offline

Joined: 2011-06-11 19:54:23
Posts: 820
Верно)


Top
   
PostPosted: 2012-11-06 13:34:21 
Offline

Joined: 2012-03-13 15:09:30
Posts: 48
Code:
############################################ 
### Manning / Шахтер v2.3 ###
############################################
### Шард Dragon World / www.drw.ru
############################################
### Реавтор этого скрипта: BETEP [WOD] or BETEPAH ###
############################################
### Если выкопали Элементала то скрипт включит "серену" и встанет на паузу пока вы просто не скажите GO.(так как вы в хайде) 
### Если появился ПК то чар зареколится к сундуку (по рунке!! так как на ДРВ рекол через рунбук 8,7 сек,а по рунке 2,3 сек)

я пробовал много скриптов, по маненгу,эти задержки очень мешают, если и ставить их то надо делать так что бы скрипт сам запускался без GO, или придется у компа ночевать, еще рекол по рун буку меднение, но с чаром меньше гемороя особенно когда их много, главное на мой взгляд это цикл в работе чара и простота скрипта, а потеря руды несколько раз в день при работе бригады, это пыль


Top
   
PostPosted: 2012-11-06 13:50:23 
Offline
User avatar

Joined: 2012-03-20 00:32:06
Posts: 243
Location: РФ, г. Москва
Siva wrote:
Code:
############################################ 
### Manning / Шахтер v2.3 ###
############################################
### Шард Dragon World / www.drw.ru
############################################
### Реавтор этого скрипта: BETEP [WOD] or BETEPAH ###
############################################
### Если выкопали Элементала то скрипт включит "серену" и встанет на паузу пока вы просто не скажите GO.(так как вы в хайде) 
### Если появился ПК то чар зареколится к сундуку (по рунке!! так как на ДРВ рекол через рунбук 8,7 сек,а по рунке 2,3 сек)

я пробовал много скриптов, по маненгу,эти задержки очень мешают, если и ставить их то надо делать так что бы скрипт сам запускался без GO, или придется у компа ночевать, еще рекол по рун буку меднение, но с чаром меньше гемороя особенно когда их много, главное на мой взгляд это цикл в работе чара и простота скрипта, а потеря руды несколько раз в день при работе бригады, это пыль

Сразу убрал из скрипта, чтоб чар не отвлекался, единственное что у меня чар пугался когда кто-то плавил руду, думая что это пка, но потом решил проблему иначе, при атаке, и то ни чего нет совершенного, иногда синие балуются.
Вопрос такой, как сделать чтоб он реагировал на то что если пка атакует или просто кастует парал стенку?

_________________
Не быть жадным - уже богатство, не быть расточительным – доход.
TylllKaH
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"


Top
   
PostPosted: 2012-11-06 14:26:21 
Offline
User avatar

Joined: 2009-05-28 09:58:28
Posts: 2802
Location: Иваново
Изврат конечно но лично я и еще несколько человек так баловались. Ставили рядом госта который периодически спамил
no ore here
или
attack

в первом случае диггер сходил с ума бегая по пещере. Во втором сходил с ума еще и мульт которого диггер вызывал по "911". :roll:

_________________
Image
YokoInjection CodeSweeper
Ошибка "Unhandled exception in parser"
Стрелялка для олдов.


Top
   
Display posts from previous:  Sort by  
Post new topic  Reply to topic  [ 23 posts ]  Go to page 1 2 Next

All times are UTC+02:00


Who is online

Users browsing this forum: No registered users and 23 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Limited