Yoko

All sides of Injection
It is currently 2024-03-28 12:17:55

All times are UTC+02:00




Post new topic  Reply to topic  [ 62 posts ]  Go to page 1 2 3 4 Next
Author Message
 Post subject: Mining Osкom Free
PostPosted: 2007-01-11 23:32:17 
Offline
Expert!
User avatar

Joined: 2005-09-14 15:31:58
Posts: 2152
Location: Latvia
Вот попросили написать скрипт- больше так небуду :lol:
Предлагали денег- невзял :roll:

Настраивать надо только руны и их кол-во...

чар открывает - закрывает калитку, там надо посмотреть типы...
хождение тоже каждому индивидуально настраивать...

Запускаем у сундука, в бекпаке руна от дома, руны в шахте в сундуке, чар летит в шахту - обкапывает 4 х 4 летит дамой, складывает, летит в другую...

Code:
###############################################################
#===---====----===---===---= Mining =---=-=-=-=-=--=-=-=-=-=-=#
;""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
;==================== Main mining script ======================
;======================= NMY (Lil Nmy) ========================
;================= http://forum.yoko.com.ua ===================
;""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
sub main()
VAR i, x

Dim rune[20]
rune[0] = 3
rune[1] = '0x416ABF80'
rune[2] = '0x401F70BB'
rune[3] = '0x415D1F41'
rune[4] = ''
rune[5] = ''
rune[6] = ''
rune[7] = ''
rune[8] = ''
rune[9] = ''
rune[10]= ''
rune[11]= ''
rune[12]= ''
rune[13]= ''
rune[14]= ''
rune[15]= ''
rune[16]= ''
rune[17]= ''
rune[18]= ''
rune[19]= ''

uo.print(' Покажы где руна дамой? ... ')
uo.exec('addobject home')
while uo.targeting()
wait(250)
wend

uo.print(' Покажы сундук куда складывать и где руны в пещеры?? ... ')
uo.exec('addobject Sunduk')
while uo.targeting()
wait(250)
wend

while 1
   for i = 1 to rune[0]

     fizz:
     if uo.mana < 12 then
      while uo.mana < 12
      uo.useskill('Meditation')
      wait(5000)
      wend
     endif

    regi()
     uo.DeleteJournal()
     uo.print(' Летим в шахту ...')
    x = uo.getx()
    uo.waittargetobject( rune[i] )
    uo.cast('Recall')

    while x == uo.getx() and not uo.InJournal('The spell fizzles')
    wait(250)
    wend

     if uo.InJournal('The spell fizzles') then
     goto fizz
     endif

    mining()
    unload()

   next
wend
end sub
;-------------------------------------------
Sub mining()
VAR mx, my, mz, i, j, jor, ser, noto, n
Dim Ore[4]
   Ore[1] = '0x19B7'
   Ore[2] = '0x19BA'
   Ore[3] = '0x19B8'
   Ore[4] = '0x19B9'

mx = UO.GetX("self")
my = UO.GetY("self")
mz = UO.GetZ("self")

uo.set('finddistance','2')
uo.findtype('0x000E', -1 ,'ground')
if uo.FindCount() then
invis()
else
while not UO.Hidden()
UO.Warmode("0")
uo.print(" Прячемся...")
UO.UseSkill("Hiding")
wait(4000)
wend
end if

for i = mx-4 to mx+4
for j = my-4 to my+4
UO.DeleteJournal()

while not UO.Hidden()
UO.Warmode("0")
uo.print(" Прячемся...")
UO.UseSkill("Hiding")
wait(4000)
wend

while not UO.InJournal("Туда Вам не дотянуться|Это слишком далеко отсюда|Тут не осталось руды|в шахте!")
UO.DeleteJournal()

UO.Waittargettile("1341", str(i), str(j), str(mz))
UO.Usetype("0x0E85")

while not UO.InJournal("Туда Вам не дотянуться|Это слишком далеко отсюда|Тут не осталось руды|в шахте!|You put|fail to find|is attacking you|You have found") and not uo.Dead()
if uo.Dead() then
uo.playwav("C:\games\ultima online\alert.wav")
uo.exec('terminate all')
endif
wait(250)
wend

if uo.InJournal('is attacking you') then
invis()
endif

for jor = 0 to 9
ser = uo.journalserial(jor)
noto = uo.getnotoriety(ser)
if noto <> 1 and noto <> 0 and not uo.getgraphic(ser)=='0x000E' and not uo.InJournal('Fireman') then
if uo.waiting() then
uo.canceltarget()
endif
invis()
return
endif
next

uo.set('finddistance','1')
for n = 1 to 4
uo.findtype( Ore[n] ,'-1','ground')
while uo.FindCount()
uo.moveitem('finditem')
checklag()
wait(1000)
uo.findtype( Ore[n] ,'-1','ground')
wend
next

if uo.weight > uo.str*4 then
return
endif

wend

next
next
uo.print(' Летим дамой ...')
end sub
;-------------------------------------------
sub unload()
VAR n, x
Dim UnLoad[4]
   UnLoad[1] = '0x19B7'
   UnLoad[2] = '0x19BA'
   UnLoad[3] = '0x19B8'
   UnLoad[4] = '0x19B9'

     fizz:
     uo.DeleteJournal()
     uo.print(' Летим дамой ...')
    x = uo.getx()
    uo.waittargetobject('home')
    uo.cast('Recall')

    while x == uo.getx() and not uo.InJournal('The spell fizzles') and uo.life >= uo.str
    wait(250)
    wend

     if uo.InJournal('The spell fizzles') then
     goto fizz
     endif

    if uo.life < uo.str then
    invis()
    heal()
    goto fizz
    endif

    check()
   open()
   walkme(2920,115,'')
   close()
   walkme(2914,110,'')

    uo.useobject("Sunduk")
    wait(250)
    CheckLag()

uo.print(' Разгружаюсь ...')
 For n = 1 to 4
  UO.FindType( UnLoad[n] )
    while UO.FindCount()
    UO.moveitem('finditem','0','Sunduk')
    CheckLag()
    wait(1000)
    UO.FindType( UnLoad[n] )
    wend
 next

uo.print(' Разгрузились ...')
end sub
;-------------------------------------------
sub invis()
uo.print(' Инвизка ...')
uo.warmode('0')
uo.usetype('0x0F09','0x0060')
end sub
;-------------------------------------------
sub heal()
uo.Print(' Лечение ... ')
uo.warmode('0')
while uo.life < uo.str
uo.bandageself()
checklag()
wait(11000)
wend
end sub
;-------------------------------------------
sub regi()
VAR r, q, n, amount = 10
Dim reg[4]
reg[1] = '0x0F7A'
reg[2] = '0x0F7B'
reg[3] = '0x0F86'
reg[4] = '0x0E21'

 For r = 1 to 4
 if uo.count( reg[r] )<>amount then
  q = amount - uo.count( reg[r] )

   if q <> 0 then
     if q > 0 then

      uo.useobject("Sunduk")
      wait(250)
      CheckLag()

      uo.findtype( reg[r] , -1 ,"Sunduk")

       If uo.findcount() == 0 then
        uo.msg('You dont have any!')
        return
       endif

      uo.moveitem('finditem', STR(q) )
      checklag()
      wait(1000)

        else

      q = q*-1
     uo.findtype( reg[r] )
     uo.moveitem('finditem', STR(q) ,"Sunduk")
     CheckLag()
     wait(1000)

     endif
   endif

 endif
 next

  While uo.Count('0x0F09','0x0060') < 2
   uo.findtype('0x0F09','0x0060',"Sunduk")
   if uo.FindCount() then
     uo.moveitem('finditem')
     checklag()
     wait(1000)
   endif
  wend

uo.print(' Взяли реги ...')
end sub
;-------------------------------------------
sub open()
uo.print(' Открываем калитку ...')
UO.Set('finddistance','2')
UO.FindType('0x0826', -1 ,'ground')
If UO.FindCount() then
UO.UseObject('finditem')
repeat
uo.findtype('0x0827', -1 ,'ground')
wait(100)
until uo.findcount()
Endif
end sub
;-------------------------------------------
sub check()
VAR m
uo.Print(' Проверяем руну ... ')
uo.deletejournal()
uo.click('home')
while not uo.injournal('jumps left')
wait(250)
wend
if uo.injournal('(0 jumps left)|(1 jumps left)') then
uo.Print(' Маркаем руну ... ')
m = uo.mana
uo.waittargetobject('home')
uo.cast('Mark')
repeat
wait(250)
until uo.mana<m
endif
end sub
;-------------------------------------------
sub close()
uo.print(' закрываем ...')
UO.Set('finddistance','2')
UO.FindType('0x0827', -1 ,'ground')
If UO.FindCount() then
UO.UseObject('finditem')
repeat
uo.findtype('0x0826', -1 ,'ground')
wait(100)
until uo.findcount()
Endif
end sub
;-------------------------------------------
sub Reconnector()
while True
while UO.IsOnline() AND NOT UO.Dead()
 wait(1000)
wend
 UO.TextOpen()
 UO.TextPrint('Disconnected at '+MakeTime())
 UO.Exec('terminate all')
connect:
wait(3000)
UO.LDblClick(616,455)
wait(3000)
UO.LDblClick(616,455)
wait(3000)
UO.LDblClick(616,455)
wait(3000)
UO.LDblClick(357,164)
if UO.IsOnline() then
 UO.Exec('exec main')
 UO.TextOpen()
 UO.TextPrint('Reconnected at '+MakeTime())
else
 goto connect
endif
wend
endsub
;-------------------------------------------
Sub MakeTime()
VAR D, T, Ret, i
Ret = STR(UO.Time())
T = ""
For i = 0 To Len(Ret)
T = Ret[Len(Ret)-i] + T
If (I == 2) OR (I == 4) Then
T = ":" + T
EndIf
Next
Ret = STR(UO.Date())
D = ""
For i = 0 To Len(Ret)
D = Ret[Len(Ret)-i] + D
If (I == 2) OR (I == 4) Then
D = "." + D
EndIf
Next
Ret = T + " @ " + D
RETURN Ret
end sub

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;; W A L K E R ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

################# W A L K E R ######################

sub WalkME(x,y,Target)
   VAR i
   VAR dir,ldir,rdir,key,olddir
   VAR dx,dy,Exit=0
   VAR CacheLimit=9,CacheIndex="Text"
   DIM CacheX[10], CacheY[10]

   CacheX[0]="Test"
   While Exit<>1
      If Target<>"" Then
         dx=UO.GetX(Target)-UO.GetX()
         dy=UO.GetY(Target)-UO.GetY()
;         UO.Print("Target locked!")
         If UO.GetDistance(Target)<2 Then
            return
         Endif
      Else
         dx=x-UO.GetX()
         dy=y-UO.GetY()
         If dx==0 AND dy==0 Then
            Exit=1
         Endif

      Endif

      If dx<>0 AND dy<>0 Then
         If dx>0 AND dy>0 Then ; GoSE
            dir=3
            ldir=2
            rdir=4
            key=40 ; DownArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==2 Then ; GoNE
                  dir=1
                  ldir=0
                  rdir=1
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=5
                  rdir=6
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif

         If dx>0 AND dy<0 Then ; GoNE
            dir=1
            ldir=0
            rdir=2
            key=39 ; RightArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==0 Then ; GoWN
                  dir=7
                  ldir=6
                  rdir=7
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSE
                  dir=3
                  ldir=3
                  rdir=4
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif

         If dx<0 AND dy>0 Then ; GoSW
            dir=5
            ldir=4
            rdir=6
            key=37 ; LeftArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==6 Then ; GoWN
                  dir=7
                  ldir=7
                  rdir=0
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSE
                  dir=3
                  ldir=2
                  rdir=3
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif

         If dx<0 AND dy<0 Then ; GoWN
            dir=7
            ldir=6
            rdir=0
            key=38 ; UpArrow
            olddir=UO.GetDir()
            If StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key) Then
               If olddir==0 Then ; GoNE
                  dir=1
                  ldir=1
                  rdir=2
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=4
                  rdir=5
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
      Endif

      If dx<>0 AND dy==0 Then
         If dx>0 Then ; GoE
            dir=2
            key=34 ; PgDown
            olddir=UO.GetDir()
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==2 Then ; GoSE
                  dir=3
                  ldir=3
                  rdir=4
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoNE
                  dir=1
                  ldir=1
                  rdir=0
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif

         If dx<0 Then ; GoW
            dir=6
            key=36 ; Home key
            olddir=UO.GetDir()
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==0 Then ; GoWN
                  dir=7
                  ldir=7
                  rdir=0
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=4
                  rdir=5
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
      Endif

      If dx==0 AND dy<>0 Then
         If dy>0 Then ; GoS
            dir=4
            key=35 ; End
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==2 Then ; GoSE
                  dir=3
                  ldir=2
                  rdir=3
                  key=40 ; DownArrow
                  While UO.GetDir()<>3
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoSW
                  dir=5
                  ldir=6
                  rdir=5
                  key=37 ; LeftArrow
                  While UO.GetDir()<>5
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif

         If dy<0 Then ;GoN
            dir=0
            key=33 ; PgUp
            olddir=UO.GetDir()
            If StepEdit(UO.GetX(),UO.GetY(),dir,key) Then
               If olddir==2 Then ; GoNE
                  dir=1
                  ldir=1
                  rdir=2
                  key=39 ; RightArrow
                  While UO.GetDir()<>1
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Else ; GoWN
                  dir=7
                  ldir=7
                  rdir=6
                  key=38 ; UpArrow
                  While UO.GetDir()<>7
                     StepArrow(UO.GetX(),UO.GetY(),dir,ldir,rdir,key)
                  Wend
               Endif
            Endif
         Endif
      Endif
   Wend
end sub


sub StepEdit(x,y,dir,key)
   VAR walkwait=100
   VAR ErrLevel=0
   If UO.GetDir()<>dir Then
         checkstam()
      UO.Press(key)
      wait(walkwait)
      If UO.GetDir()<>dir Then
         CheckLag()
      Endif
   Endif
         checkstam()
   UO.Press(key)
   wait(walkwait)
   If x==UO.GetX() AND y==UO.GetY() Then
      CheckLag()
      If x==UO.GetX() AND y==UO.GetY() Then
;zatik
         ErrLevel=1
      Endif
   Endif
   Return ErrLevel
end sub


sub StepArrow(x,y,dir,ldir,rdir,key)
   VAR walkwait=100
   VAR ErrLevel=0
   If UO.GetDir()<>dir Then
      checkstam()
      UO.Press(key)
      wait(walkwait)
      If UO.GetDir()<>dir AND UO.GetDir()<>ldir AND UO.GetDir()<>rdir Then
         CheckLag()
      Endif
   Endif

   If UO.GetX()==x AND UO.GetY()==y Then
      checkstam()
      UO.Press(key)
      wait(walkwait)
      If UO.GetDir()==dir AND UO.GetX()==x AND UO.GetY()==y Then
         CheckLag()
         If UO.GetDir()==dir AND UO.GetX()==x AND UO.GetY()==y Then
; zatik
            ErrLevel=1
         Endif
      Endif
   Endif
   Return ErrLevel
end sub

sub checkstam()
var refresh = '0x0F0B'
if uo.stamina < 10 then
   uo.findtype(refresh,-1,'backpack')
   if uo.findcount() then
      uo.usetype(refresh)
      wait(1000)
   else
      uo.print("Nety Refreshey! Stoim...")
   repeat
      wait(500)
   until uo.stamina >= 10
   endif
else
endif
endsub

Sub CHECKLAG()
   del('backpack')
   uo.click('backpack')
   repeat
   wait(200)
   until uo.injournal('backpack')
   del('backpack')
endsub

Sub DEL(msg)
   while uo.injournal(msg)
   uo.setJournalLine(uo.injournal(msg)-1,"Is Empty!")
   wend
endsub



update 22.01.2007

_________________
Уроки языка Injection
Основные команды языка Injection
Yoko Injection Code Sweeper
Drw (2009) скрипты
2017 Начал играть на Uorpg.net


Last edited by Nmy on 2007-01-24 14:02:56, edited 2 times in total.

Top
   
 Post subject:
PostPosted: 2007-01-23 23:40:12 
Offline
Expert!
User avatar

Joined: 2005-05-20 20:30:10
Posts: 548
я все еще настаиваю чтобы название оскома (Oskom) в заголовке
написали правильно :)

_________________
"плагины" для инжекта


Top
   
 Post subject:
PostPosted: 2007-01-24 08:31:58 
Offline
User avatar

Joined: 2006-12-19 09:38:27
Posts: 64
Mihail wrote:
я все еще настаиваю чтобы название оскома (Oskom) в заголовке
написали правильно :)

это пашит, гарантия.
А настраивать, в принципе там толком нечего, тайлы раставил, руны прописал и всё.


Top
   
 Post subject:
PostPosted: 2007-01-24 12:15:23 
Offline

Joined: 2006-06-15 23:42:19
Posts: 7
Ходилку как настроить?


Top
   
 Post subject:
PostPosted: 2007-01-26 03:04:57 
Offline

Joined: 2007-01-26 02:58:13
Posts: 16
помогитье не смог завестьи скрипт в начале выдает таргеты я делаю на руну домои и на дровер куда слажывать и где реги с рунами должны быть но скрипт на етом останавливается что делать и как настроить таилы или как там


Top
   
 Post subject:
PostPosted: 2007-02-12 13:36:23 
Offline

Joined: 2006-05-08 20:20:58
Posts: 7
Это вызвано ошибкой где то в донаборе регов, я пока не разобрался где, но если убрать этот скрипт то будет работать все идеально.


Top
   
 Post subject:
PostPosted: 2007-02-28 19:31:18 
Offline

Joined: 2007-02-25 20:45:56
Posts: 20
А у меня вот такая проблема пашет всё нормуль ваще отлично!!! Тока единственное что кода он домой возвращается то он наичнает маркать а у чара мало магии и поэому он стоит и пишет абилити........... Сам пробовал исправить не получается((( помогите плиз чтоб он так же вс делал улетал и т.д. тока не маркал руну плииз помогите...


Top
   
 Post subject:
PostPosted: 2007-02-28 19:49:02 
Offline
Expert!
User avatar

Joined: 2005-09-14 15:31:58
Posts: 2152
Location: Latvia
Code:
   ;check() <<--
   open()
   walkme(2920,115,'')
   close()
   walkme(2914,110,'')

_________________
Уроки языка Injection
Основные команды языка Injection
Yoko Injection Code Sweeper
Drw (2009) скрипты
2017 Начал играть на Uorpg.net


Top
   
 Post subject:
PostPosted: 2007-02-28 22:04:50 
Offline

Joined: 2007-02-25 20:45:56
Posts: 20
Воо спасибо большое дружище!! :D :D :) :o :lol: я тебе сильно благодарен спасибо))) Всё работает отлично...


Top
   
 Post subject:
PostPosted: 2007-03-01 11:43:01 
Offline

Joined: 2007-02-25 20:45:56
Posts: 20
И ещё 1 последний не большой вопросик :oops: ! как сделать когда тебя никто не атачит ты стоял в хайде рекол домой когда перед реколом домой когда всё выкопал или перевес перед тем как рекол домой чтоб пил инвиз т.к. големы мучают вообще....
Думаю кудато сюда нуно вставить подскажите плиз именно куда и
что....


fizz:
uo.DeleteJournal()
uo.print(' Летим дамой ...')
x = uo.getx()
uo.waittargetobject('home')
uo.cast('Recall')


Top
   
 Post subject:
PostPosted: 2007-03-01 12:22:11 
Offline
Expert!
User avatar

Joined: 2005-09-14 15:31:58
Posts: 2152
Location: Latvia
sory netu rus - sizhu na solaris os
on budet pit` invizku esli golem tebja udaril - mol proverka esli hp upalo - togda budet invizka - othil i rekal ...

_________________
Уроки языка Injection
Основные команды языка Injection
Yoko Injection Code Sweeper
Drw (2009) скрипты
2017 Начал играть на Uorpg.net


Top
   
 Post subject:
PostPosted: 2007-03-01 15:35:30 
Offline

Joined: 2006-03-10 00:19:11
Posts: 265
Location: http://drw.ru/
NMY wrote:
sory netu rus - sizhu na solaris os
on budet pit` invizku esli golem tebja udaril - mol proverka esli hp upalo - togda budet invizka - othil i rekal ...

Хм... не знаю как на оскоме, но на дрв если ты в хайде и атачащий тебя чар\монстр находится в притык, т.е. в соседнем тайле то он будет тебя бить не смотря на хайд... имхо лучше делать проверку по журналу и\или по типу


Top
   
 Post subject:
PostPosted: 2007-03-01 16:22:25 
Offline
Expert!
User avatar

Joined: 2005-09-14 15:31:58
Posts: 2152
Location: Latvia
прикол в том что за ноч их выкапывают больше 10 штук и скрипт работает просто игнорируя их - если успеит ударить то инвизка ... другое придумать несмог ...

_________________
Уроки языка Injection
Основные команды языка Injection
Yoko Injection Code Sweeper
Drw (2009) скрипты
2017 Начал играть на Uorpg.net


Top
   
 Post subject:
PostPosted: 2007-03-01 19:54:36 
Offline

Joined: 2006-03-10 00:19:11
Posts: 265
Location: http://drw.ru/
т.е. они просто выкапываются но не аттачат?


Top
   
 Post subject:
PostPosted: 2007-03-04 13:40:06 
Offline

Joined: 2004-05-22 16:29:37
Posts: 19
L|-OBL|-O Oskom wrote:
Воо спасибо большое дружище!! :D :D :) :o :lol: я тебе сильно благодарен спасибо))) Всё работает отлично...

работает но недолго, автор уже на каторге на 50к а минеры его забанены. Слишком уж хорошо пасет оскомовский стафф ;)


Top
   
 Post subject:
PostPosted: 2007-03-08 22:54:34 
Offline

Joined: 2007-02-25 20:45:56
Posts: 20
А мона спроосить что за объект вот этот '0x000E'?
for jor = 0 to 9
ser = uo.journalserial(jor)
noto = uo.getnotoriety(ser)
if noto <> 1 and noto <> 0 and not uo.getgraphic(ser)=='0x000E' and not uo.InJournal('Fireman') then
if uo.waiting() then
uo.canceltarget()
endif
invis()
return
endif
next


Top
   
 Post subject:
PostPosted: 2007-03-08 23:36:27 
Offline
Expert!
User avatar

Joined: 2005-09-14 15:31:58
Posts: 2152
Location: Latvia
L|-OBL|-O Oskom wrote:
А мона спроосить что за объект вот этот '0x000E'?
for jor = 0 to 9
ser = uo.journalserial(jor)
noto = uo.getnotoriety(ser)
if noto <> 1 and noto <> 0 and not uo.getgraphic(ser)=='0x000E' and not uo.InJournal('Fireman') then
if uo.waiting() then
uo.canceltarget()
endif
invis()
return
endif
next

ищет в журнале пк, игнорируя големов, надо TWI

_________________
Уроки языка Injection
Основные команды языка Injection
Yoko Injection Code Sweeper
Drw (2009) скрипты
2017 Начал играть на Uorpg.net


Top
   
 Post subject:
PostPosted: 2007-03-09 00:01:01 
Offline

Joined: 2007-02-25 20:45:56
Posts: 20
ммм блин есть проблема!:( НУМ если не сложно стукни в асю на 1 мин ждуу.. плз 1 мин! ICQ:425 658 430(инвиз)


Top
   
 Post subject:
PostPosted: 2007-03-09 09:32:29 
Offline
Expert!
User avatar

Joined: 2005-09-14 15:31:58
Posts: 2152
Location: Latvia
L|-OBL|-O Oskom wrote:
ммм блин есть проблема!:( НУМ если не сложно стукни в асю на 1 мин ждуу.. плз 1 мин! ICQ:425 658 430(инвиз)


неа я лудше посплю...

_________________
Уроки языка Injection
Основные команды языка Injection
Yoko Injection Code Sweeper
Drw (2009) скрипты
2017 Начал играть на Uorpg.net


Top
   
 Post subject:
PostPosted: 2007-03-09 14:53:57 
Offline

Joined: 2007-02-25 20:45:56
Posts: 20
Ну крч на другом шарде пробовал этот скрипт запустить не получилось! я все вот эти строчки написал типо выкопал руду плоха капунл руду т.е. сам мининг не работает не пойму почему он 1 место капнёт и всё далльше ничего как будто чтото не правильно написано! хотя всё прально написано проверял 100 РАЗ! другой минер запускал который вокруг себя всё пашет а вот это не пашет((( не пойму почему пробовал разбиратся не получалося(( подскажи плиз


Top
   
Display posts from previous:  Sort by  
Post new topic  Reply to topic  [ 62 posts ]  Go to page 1 2 3 4 Next

All times are UTC+02:00


Who is online

Users browsing this forum: No registered users and 6 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Limited